⚡ Match Highlights: language/ref/PrimePi.html - Info Live Streaming 2026

Wolfram Language & System Documentation Center

PrimePi[x]

gives the number of primes TemplateBox[{x}, PrimePi] less than or equal to x.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Symbolic Manipulation  
Options  
Method  
ProgressReporting  
Applications  
Basic Applications  
Approximations  
Number Theory  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

PrimePi

PrimePi[x]

gives the number of primes TemplateBox[{x}, PrimePi] less than or equal to x.

Details and Options

  • PrimePi is also known as prime counting function.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{x}, PrimePi] counts the prime numbers less than or equal to x.
  • TemplateBox[{x}, PrimePi] has the asymptotic expansion as .
  • The following option can be given:
  • Method Automaticmethod to use
    ProgressReporting $ProgressReportingwhether to report the progress of the computation
  • Possible settings for Method include:
  • "DelegliseRivat"use the Deléglise–Rivat algorithm
    "Legendre"use the Legendre formula
    "Lehmer"use the Lehmer formula
    "LMO"use the Lagarias–Miller–Odlyzko algorithm
    "Meissel"use the Meissel formula
    "Sieve"use the sieve of Erastosthenes

Examples

open all close all

Basic Examples  (3)

Compute the number of primes up to 15:

Wolfram Language code: PrimePi[15]

Plot the prime counting function:

Wolfram Language code: Plot[PrimePi[x], {x, 0, 50}]

Find the leading asymptotic term for PrimePi at Infinity:

Wolfram Language code: Asymptotic[PrimePi[x], x -> Infinity]

Scope  (10)

Numerical Evaluation  (5)

PrimePi works over integers:

Wolfram Language code: PrimePi[100]

Rational numbers:

Wolfram Language code: PrimePi[7 / 2]

Real numbers:

Wolfram Language code: PrimePi[15.25]

PrimePi works over large numbers:

Wolfram Language code: PrimePi[10 ^ 15]

PrimePi threads over lists:

Wolfram Language code: PrimePi[{3, 5, 17, 25}]

Symbolic Manipulation  (5)

The traditional mathematical notation for PrimePi:

Wolfram Language code: PrimePi[x]//TraditionalForm

Find a solution instance of equalities with PrimePi:

Wolfram Language code: FindInstance[PrimePi[n] == 7, n, Integers]

Evaluate an integral:

Wolfram Language code: Integrate[PrimePi[x ^ 2], {x, 0, 10}]

Recognize the PrimePi function:

Wolfram Language code: FindSequenceFunction[{0, 1, 2, 2, 3, 3, 4, 4, 4, 4}, n]

Find asymptotic relations:

Wolfram Language code: Asymptotic[PrimePi[x], x -> Infinity]

Verify asymptotic relations:

Wolfram Language code: AsymptoticEquivalent[PrimePi[x], LogIntegral[x], x -> Infinity]

Options  (6)

Method  (5)

Specify the Legendre method to be used for counting primes [MathWorld]:

Wolfram Language code: PrimePi[10 ^ 6, Method -> "Legendre"]

Compare the timing:

Wolfram Language code: BarChart[Table[{First[AbsoluteTiming[PrimePi[10 ^ n]]], First[AbsoluteTiming[PrimePi[10 ^ n, Method -> "Legendre"]]]}, {n, 7, 11, .5}], ChartLegends -> {"Automatic", "Legendre"}]

Specify the Lehmer method to be used for counting primes [MathWorld]:

Wolfram Language code: PrimePi[10 ^ 6, Method -> "Lehmer"]

Compare the timing:

Wolfram Language code: BarChart[Table[{First[AbsoluteTiming[PrimePi[10 ^ n]]], First[AbsoluteTiming[PrimePi[10 ^ n, Method -> "Lehmer"]]]}, {n, 7, 11, .5}], ChartLegends -> {"Automatic", "Lehmer"}]

Specify the Deléglise–Rivat method to be used for counting primes:

Wolfram Language code: PrimePi[10 ^ 6, Method -> "DelegliseRivat"]

Compare the timing:

Wolfram Language code: BarChart[Table[{First[AbsoluteTiming[PrimePi[10 ^ n]]], First[AbsoluteTiming[PrimePi[10 ^ n, Method -> "DelegliseRivat"]]]}, {n, 7, 11, .5}], ChartLegends -> {"Automatic", "Deleglise-Rivat"}]

Specify the Meissel method to be used for counting primes [MathWorld]:

Wolfram Language code: PrimePi[10 ^ 6, Method -> "Meissel"]

Compare the timing:

Wolfram Language code: BarChart[Table[{First[AbsoluteTiming[PrimePi[10 ^ n]]], First[AbsoluteTiming[PrimePi[10 ^ n, Method -> "Meissel"]]]}, {n, 7, 11, .5}], ChartLegends -> {"Automatic", "Meissel"}]

Specify the Lagarias–Miller–Odlyzko (LMO) to be used for counting primes:

Wolfram Language code: PrimePi[10 ^ 6, Method -> "LMO"]

Compare the timing:

Wolfram Language code: BarChart[Table[{First[AbsoluteTiming[PrimePi[10 ^ n]]], First[AbsoluteTiming[PrimePi[10 ^ n, Method -> "LMO"]]]}, {n, 7, 11, .5}], ChartLegends -> {"Automatic", "Lagarias-Miller-Odlyzko"}]

ProgressReporting  (1)

By default, PrimePi does not report progress:

Wolfram Language code: PrimePi[10 ^ 17 + 1]

With the setting ProgressReporting->True, PrimePi shows the progress of the computation:

Wolfram Language code: PrimePi[10 ^ 17 + 1, ProgressReporting -> True]

Applications  (22)

Basic Applications  (7)

Visualize the PrimePi function:

Wolfram Language code: Grid[Prepend[Table[{"10" ^ n, PrimePi[10 ^ n]}, {n, 1, 10}], {"x", "π(x)"}], ...]

Spiral of PrimePi:

Wolfram Language code: ListPolarPlot[Table[{Mod[π / 2 - n 4π / 50, 2π], PrimePi[n]}, {n, 50}], ...]

Hexagonal prime spiral:

Wolfram Language code: hexagonalSpiral[n_] := {Re[#], Im[#]}& /@ Fold[Join[#1, Last[#1] + Exp[I Pi / 3] ^ #2Range[#2 / 2]]&, {0}, Range[n]]
Wolfram Language code: spiral = hexagonalSpiral[25];
Wolfram Language code: primes = spiral[[Prime[Range[PrimePi[Length[spiral]]]]]];
Wolfram Language code: ListPlot[spiral, ...]

ContourPlot of the PrimePi function:

Wolfram Language code: ListContourPlot[Table[{x = n, y = PrimePi[n]}, {n, 1, 25}]]

Plot the difference between RiemannR and the PrimePi function:

Wolfram Language code: r = 0;c = -1;ListPolarPlot[{Table[{i * Pi / 8, x = RiemannR[i] - PrimePi[i];If[x > c, c = x;r = r + 1];PrimePi[i] * r / i}, {i, 1000}]}, Rule[...]]

Find all prime numbers less than or equal to 100:

Wolfram Language code: Prime[Range[PrimePi[100]]]

Count the number of primes in an interval:

Wolfram Language code: primecount[{x_, y_}] := PrimePi[y + 1] - PrimePi[x - 1]
Wolfram Language code: primecount[{5, 15}]

Approximations  (7)

Approximations to PrimePi:

Wolfram Language code: PrimePi[5000]
Wolfram Language code: 5000 / Log[5000.]
Wolfram Language code: LogIntegral[5000.]
Wolfram Language code: RiemannR[5000.]

Plot PrimePi compared with estimates:

Wolfram Language code: Plot[{PrimePi[x], x / Log[x], LogIntegral[x], RiemannR[x]}, {x, 1.5, 100}, Rule[...]]

TemplateBox[{x}, PrimePi] is bounded below by and is bounded above by for greater than 3:

Wolfram Language code: Plot[{x / Log[x], PrimePi[x], x / (Log[x] - 1.112)}, {x, 3, 100}, Rule[...]]

is within of TemplateBox[{x}, PrimePi] for :

Wolfram Language code: Plot[{(x/HarmonicNumber[x] - 3 / 2), PrimePi[x]}, {x, 50, 200}, Rule[...]]

TemplateBox[{{TemplateBox[{x}, PrimePi], -, TemplateBox[{x}, LogIntegral]}}, Abs]<(sqrt(x) log(x))/(8 pi) for if the Riemann hypothesis is true:

Wolfram Language code: Plot[{Abs[PrimePi[x] - LogIntegral[x]], Sqrt[x]Log[x] / (8 * Pi)}, {x, 2657, 3000}, PlotLegends -> "Expressions"]

Count the prime numbers using EulerPhi:

Wolfram Language code: primecount[x_] := Underoverscript[∑, k = 2, ⌊x⌋]⌊(EulerPhi[k]/k - 1)⌋
Wolfram Language code: Table[primecount[n], {n, 0, 10}]
Wolfram Language code: Table[PrimePi[n], {n, 0, 10}]

Compute PrimePi based on the Hardy–Wright formula:

Wolfram Language code: primecount[x_] := Sum[Mod[(j - 2)!, j], {j, 4, x}]
Wolfram Language code: Table[primecount[n], {n, 5, 10}]
Wolfram Language code: Table[PrimePi[n], {n, 5, 10}]

Compute PrimePi using Accumulate:

Wolfram Language code: Accumulate[Table[Boole[PrimeQ[n]], {n, 1, 10}]]
Wolfram Language code: Table[PrimePi[n], {n, 1, 10}]

Number Theory  (8)

Find twin primes up to , i.e. pairs of primes of the form :

Wolfram Language code: TwinPrimes[n_] := Pick[#, PrimeQ[# + 2]]&[Prime[Range[PrimePi[n]]]]
Wolfram Language code: TwinPrimes[100]
Wolfram Language code: TwinPrimePi[n_] := Length[Pick[#, PrimeQ[# + 2]]]&[Prime[Range[PrimePi[n]]]]

Plot the sequence of twin primes and PrimePi:

Wolfram Language code: ListStepPlot[{Table[TwinPrimePi[n], {n, 1, 100}], Table[PrimePi[n], {n, 1, 100}]}]

The ^(th) Ramanujan prime is the smallest number such that for all :

Wolfram Language code: list = Table[PrimePi[n] - PrimePi[n / 2], {n, 10 ^ 4}];
Wolfram Language code: ramanujanPrime = 1 + Last[Position[list, #]][[1]]& /@ Range[0, 50];
Wolfram Language code: ramanujanPrimePi[n_] := Count[ramanujanPrime, _ ? (# ≤ n&)]

Plot the sequence of Ramanujan primes:

Wolfram Language code: Plot[ramanujanPrimePi[n], {n, 0, 100}]

Compare the count of Ramanujan primes to PrimePi:

Wolfram Language code: Plot[{ramanujanPrimePi[n], PrimePi[n]}, {n, 0, 100}]

Calculate the primorial up to the ^(th) prime, i.e. a function that multiplies successive primes, similar to the factorial:

Wolfram Language code: primorial[0] := 1 primorial[1] := 2 primorial[n_] := Times@@Prime@Range[n];
Wolfram Language code: primorial[5]

Compare the primorial to the factorial up to :

Wolfram Language code: DiscretePlot[{Log[n!], Log[Times@@Prime[Range[PrimePi[n]]]]}, {n, 1, 50}]

Plot the differences between the factorial and the primorial up to :

Wolfram Language code: ListLinePlot[If[True, Differences, Identity][Table[Log[(n!/Times@@Prime[Range[PrimePi[n]]])], {n, 1, 100, 1}]], Filling -> Axis]

Plot the Chebyshev theta function:

Wolfram Language code: chebyshevTheta[n_] := Log[primorial[PrimePi[n]]];
Wolfram Language code: Plot[chebyshevTheta[n], {n, 1, 100}]
Wolfram Language code: DiscretePlot[{chebyshevTheta[n], PrimePi[n]}, {n, 1, 100}]

Calculate the prime powers up to :

Wolfram Language code: primePowers[n_] := Union@@Table[Prime[Range[PrimePi[n ^ (1 / x)]]] ^ x, {x, Log2[n]}]
Wolfram Language code: primePowers[10]
Wolfram Language code: PrimePowerQ[%]

Count all the prime powers up to :

Wolfram Language code: primePowerPi[n_] := PrimePi[n] + Sum[Floor@Log[Prime[k], n] - 1, {k, PrimePi[Sqrt[n]//Floor]}]
Wolfram Language code: primePowerPi[10]

Graph the count of prime powers:

Wolfram Language code: DiscretePlot[primePowerPi[n], {n, 1, 100}]

Compare the count of prime powers to PrimePi:

Wolfram Language code: DiscretePlot[{primePowerPi[n], PrimePi[n]}, {n, 1, 100}]

Visualize the second Hardy–Littlewood conjecture, which states that for :

Wolfram Language code: ArrayPlot[((Outer[Plus, #, #]&)[PrimePi[Range[2, 20]]] - Outer[PrimePi[+##1]&, #, #]&)[Range[2, 20]], Rule[...]]

Plot Brocard's conjecture, which states that if and are consecutive primes greater than 2, then between and there are at least four prime numbers:

Wolfram Language code: ListStepPlot[-Subtract@@@Partition[PrimePi[Prime[Range[100]] ^ 2], 2, 1], Rule[...]]

Find Goldbach partitions, i.e. pairs of primes (, ) such that :

Wolfram Language code: goldbachPartitions[n_] := IntegerPartitions[2n, {2}, Prime[Range[PrimePi[2n]]]]
Wolfram Language code: goldbachPartitions[50]

Graph Goldbach's conjecture/comet:

Wolfram Language code: ListPlot[Transpose[{Range[4, 1000, 2], Length /@ Table[IntegerPartitions[i, 2, Table[Prime[n], {n, PrimePi[i]}]], {i, 4, 1000, 2}]}], Rule[...]]

The only 8 solutions of TemplateBox[{x}, PrimePi]=TemplateBox[{x}, EulerPhi]:

Wolfram Language code: Cases[Range[100], n_ /; PrimePi[n] == EulerPhi[n]]
Wolfram Language code: DiscretePlot[{PrimePi[n], EulerPhi[n]}, {n, 1, 22}, Rule[...]]

Properties & Relations  (5)

The largest domain of definitions of PrimePi:

Wolfram Language code: FunctionDomain[PrimePi[x], x, Complexes]

PrimePi is asymptotically equivalent to as :

Wolfram Language code: AsymptoticEquivalent[PrimePi[x], x / Log[x], x -> Infinity]

And to LogIntegral:

Wolfram Language code: AsymptoticEquivalent[PrimePi[x], LogIntegral[x], x -> Infinity]

PrimePi is the inverse of Prime:

Wolfram Language code: PrimePi[Prime[100]]

Use PrimeQ to count prime numbers:

Wolfram Language code: Count[Table[PrimeQ[n], {n, 1, 1000}], True]
Wolfram Language code: PrimePi[1000]

Mathematical function entity:

Wolfram Language code: Entity["MathematicalFunction", "PrimePi"]

An integral representation of PrimePi:

Wolfram Language code: Entity["MathematicalFunction", "PrimePi"]["IntegralRepresentations"]

Possible Issues  (1)

Evaluation time increases exponentially:

Wolfram Language code: ListLinePlot[Table[First[AbsoluteTiming[PrimePi[10 ^ n]]], {n, 14, 19, .5}], ...]

Neat Examples  (3)

Ulam spiral colored based on the difference in PrimePi values:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n]
Wolfram Language code: ArrayPlot[PrimePi[ulam[101] + 10] - PrimePi[ulam[101]], Rule[...]]

Generate a path based on the PrimePi function:

Wolfram Language code: Graphics[Line[AnglePath[Table[PrimePi[n], {n, 1, 1000}]], Rule[...]]]

Construct polyhedra using directed graphs generated by primes less than :

Wolfram Language code: vertexcoords[p_] := GraphEmbedding[Graph3D[Flatten[Table[i -> Mod[i * q, p], {i, 1, p - 1}, {q, Prime[Range[PrimePi[p] - 1]]}]]]]
Wolfram Language code: Table[ConvexHullMesh[vertexcoords[p], Rule[...]], {p, Prime[Range[4, 7]]}]
Wolfram Research (1991), PrimePi, Wolfram Language function, https://reference.wolfram.com/language/ref/PrimePi.html (updated 2021).

Text

Wolfram Research (1991), PrimePi, Wolfram Language function, https://reference.wolfram.com/language/ref/PrimePi.html (updated 2021).

CMS

Wolfram Language. 1991. "PrimePi." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/PrimePi.html.

APA

Wolfram Language. (1991). PrimePi. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PrimePi.html

BibTeX

@misc{reference.wolfram_2026_primepi, author="Wolfram Research", title="{PrimePi}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/PrimePi.html}", note=[Accessed: 25-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_primepi, organization={Wolfram Research}, title={PrimePi}, year={2021}, url={https://reference.wolfram.com/language/ref/PrimePi.html}, note=[Accessed: 25-October-2026]}