メインコンテンツへスキップ
見出し画像

Excel(VBA)でクイズゲームを作ろう!

    こんにちは「つけらっとゲームス」プログラム担当のとちです。
    今回はExcel(VBA)でクイズゲームを作りますよ!

    記事のとおりに開発を進めると、以下のようなクイズゲームができます!

    画像
    タイトル画面で「はじめる」ボタンをクリック!
    画像
    問題と選択肢ボタンが表示されるので、正解だと思うボタンをクリック!
    画像
    正解すると+10点! 100点満点を目指してね!

    問題はサンプルゲーム内でも準備しますが、皆さんも用意できるように作りますので、あなただけのクイズゲームを作ってみてくださいね!

    今回の記事ではクイズゲームの基本システムが動くところまで進めます。
    次回の記事で応用編として、よりクイズゲームを高性能にします。
    その次の記事でプログラムコードの解説をしようと考えています。

    なお、この記事のスクショについて、わたしのPCに入っているMicrosoft office Home and Business 2016でスクショを撮りました。

    ですので微妙に表示が異なる可能性がありますが、デスクトップ版のExcelであれば、開発に使用するVBA(Microsoft Visual Basic for Applications)は同じで作業内容も変わりません。Microsoft365のExcelでも動作します。

    それと、開発前に環境を整える必要があります。
    以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「Excelの準備」を参照してVBAを使えるようにしておきましょう。

    また「読むとゲームができる」記事は以下のマガジンにまとめています。


    必要な素材を準備する

    まずは必要な素材を準備します。今回のゲームはコチラのサイトからお借りしております。絵を描ける方は自分で書いたモノを使って構いません。

    いつもお世話になっているOKUMONOさん。
    やわらかく、かわいらしい素材がたくさんあります。

    DLしたのは「黒板の背景」「答案用紙に使ったフレーム」です。
    これを組み合わせた画像をゲーム内で使用する背景画像とします。

    画像
    ゲーム画面(再掲)

    答案用紙に使ったフレームは上の画像のように、全体の右下あたりに配置しておくとよいでしょう(大体の位置で構いません)
    さらにプラスひとつ、タイトル画面用に好みの画像をDLしておきましょう。

    ※記事中では黒板の背景を2枚(2つのファイル)を使ってタイトル画面とメイン画面を切り替えています。

    使用できる画像形式について

    Excel(VBA)ではpng形式を使えません。jpeg形式に変換する必要があります。Photoshop、Gimpあたりの画像編集ソフトを使用できる方はそちらで編集していただいて構いません。

    Windows付属のペイントでも十分可能ですが、やったこと無い方や、自信が無い方は「必要な素材を準備する」をご覧くださいね。

    画像サイズの目安について

    ・タイトル画像 960×540 ピクセル
    ・黒板背景 960×540 ピクセル
    ・答案用紙 135×150 ピクセル

    画像編集ソフト(ペイントなど)で上記サイズに揃えると作りやすいです。


    ユーザーフォームを作る

    Excelの開発準備と、素材が揃ったら以下の作業に進んでください。
    最初にやるべきことは「挿入」>「ユーザーフォーム」でまっさらなユーザーフォームを準備することです。

    画像
    (1)挿入 → (2)ユーザーフォーム と選択します。

    次にユーザーフォームのプロパティを変更していきます。
    下の画像を拡大して、プロパティ欄を同じように変更します。

    画像

    ◆主な変更箇所は以下の通りです。
    (オブジェクト名):QuizGame
    Caption:4択クイズ教室
    Height:429.75(430で構いません)
    Picture:黒板背景の素材を選びます
    Width:720


    メイン画面のオブジェクト配置

    引き続き、ゲームのメイン画面に必要な各種オブジェクトを配置します。

    下のスクショを見るとわかるように、ラベル8個、コマンドボタン5個のオブジェクトで構成されています。

    画像

    QuizGameをクリックしてツールボックスを表示します。
    もし表示されなかった場合は下のスクリーンショットをご覧ください。
    「表示」>「ツールボックス」を選ぶと表示されます。

    画像

    下のスクショのとおり、ツールボックスの「A」と表示されている部分を選択するとラベルを作成できるようになります。

    画像

    黒板の上部でマウスドラッグして範囲指定をするとラベルオブジェクトが配置されます。配置されたらプロパティ欄の値をスクショを参考に変更します。これがオブジェクト配置の一連の流れになります。

    フォントに関しては好みのもので構いません。

    引き続きラベルオブジェクトを配置していきましょう。

    画像
    答え表示ラベル QAnsLbl
    (※操作ミスで「NextBtn」が消えてますね…後で作り直します😿)

    答えを表示するラベルを作ります。ツールボックスの「A」を選んで、黒板下部でドラッグして範囲指定。プロパティ欄の値を変更します。

    同様に、残り問題数ラベルと、点数ラベルも作ります。

    画像
    残り問題数ラベル NokoriLbl
    画像
    点数ラベル UserPointLbl

    正解の選択肢を選んだら〇、間違いなら✕を表示するラベルを作ります。
    4つあります。違いは表示場所とオブジェクト名だけなのでコピペでいいでしょう!

    画像
    〇✕ラベル1 QAnsMB1
    画像
    〇✕ラベル2 QAnsMB2
    画像
    〇✕ラベル3 QAnsMB3
    画像
    〇✕ラベル4 QAnsMB4

    続いて、選択肢ボタンを4つ作ります。
    下のスクショのとおり、ツールボックスからコマンドボタンを選んで、ドラッグで範囲選択するとボタンが作られます。

    画像
    選択肢ボタン QSelBtn1~4

    ボタンオブジェクトも、オブジェクト名と場所が違うだけなのでコピペすると楽でしょう。上記画像では配置を解りやすくするためにCaptionも変更しています。

    オブジェクト名をQSelBtn1、QSelBtn2、QSelBtn3、QSelBtn4に変更し良い感じの場所に置きましょう。

    最後に次の問題を呼び出すボタンを配置します。

    画像
    次へボタン NextBtn

    これでメイン画面のオブジェクト配置は完了です。
    引き続き、タイトル画面を作りましょう!


    タイトル画面のオブジェクト配置

    新たに他フォームを作ってタイトル画面を作る方法もありますが、今回はイメージオブジェクトを前面にすることで、タイトル画面を表示する方法にしましょう。

    下のスクショのとおり、イメージオブジェクトをフォーム全体を覆うサイズで作ります。

    画像

    イメージオブジェクトができたらプロパティ欄を変更します。
    タイトル画面用にダウンロードした画像を選択しましょう。

    次は「タイトルラベル」と「はじめるボタン」を配置しましょう。

    画像
    タイトルラベル TitleLbl
    画像
    はじめるボタン StartBtn

    表示順がおかしくなっちゃった!?

    複数あるオブジェクトの重ね合わせでゲーム画面を構成しているので、開発中に足りないオブジェクトに気づいたり、追加したりすると必要なボタンやラベルがイメージの裏側に隠れてしまうことがあります。

    画像
    タイトル画像の位置をズラすと、その奥側にメイン画面の背景が見えますね!

    表示順がおかしくなっても慌てない。大丈夫。
    表示順を変更したいオブジェクトを選択して、次のスクリーンショットのように操作しましょう。表示順を変えることができます。

    画像
    (1)書式 → (2)順序 → (3)移動させたい場所 を選択しましょう!

    プログラムコードをコピペしよう!

    オブジェクト配置をしても、現時点ではそのオブジェクトは何していいか決まっていない状態だったりします。

    各オブジェクトに役割を持たせるべくプログラムコードを書きます。今回の記事ではコードの中身までは説明しません。とりあえずクイズゲームのシステム部分を動かせるようにコードをコピペする画面を表示します。

    とりあえず「はじめるボタン」をダブルクリックしましょう。

    画像
    「はじめるボタン」をダブルクリック!

    すると、こんな画面が表示されるハズです。
    一番広いところに「Private Sub StartBtn_Click()」とか書いてますけど、この2行を一旦全て消しちゃってください。

    画像
    コード入力する画面

    まっさらになったら、以下のコードを全て一番広いところにコピペします。

    
    Option Explicit
    Dim QuizNo        As Integer                                '【変数定義】現在出題されているクイズIndex
    Dim QuizAns       As Integer                                '【  〃  】現在出題されているクイズの答え
    Dim UserPoint     As Integer                                '【  〃  】プレイヤーの点数
    Dim DtSt          As String                                 '【  〃  】クイズデータのワークシート名
    
    '----------------------------------------------------------------
    ' UserForm 初期化
    '----------------------------------------------------------------
    Sub UserForm_Initialize()                                   '
                                                                '
        DtSt = "QuizData"                                       ' クイズデータが格納されているワークシート名
        TitleImage.Top = 0                                      ' タイトル画像を左上隅に移動させる
        TitleImage.Left = 0                                     '       〃
        TitleLbl.Top = 72                                       ' タイトルラベルを所定の場所に移動させる
        TitleLbl.Left = 60                                      '       〃
                                                                '
    End Sub                                                     '
    
    '----------------------------------------------------------------
    ' はじめるボタンをクリック
    '----------------------------------------------------------------
    Sub StartBtn_Click()                                        '
                                                                '
        QuizNo = 1                                              '[初期化]出題されるクイズIndex
        QuizAns = 0                                             '[初期化]出題されたクイズの答え
        UserPoint = 0                                           '[初期化]プレイヤーの点数
                                                                '
        UserPointLbl.Caption = UserPoint & "点"                 ' 答案用紙の点数表示
        Nokoribl.Caption = "残り10問"                           ' 問題残り数の表示
                                                                '
        TitleImage.Visible = False                              ' タイトル画像 非表示化
        TitleLbl.Visible = False                                ' タイトルラベル非表示化
        StartBtn.Visible = False                                ' はじめるボタン非表示化
        QuizDataGet                                             ' クイズデータを取得
                                                                '
    End Sub                                                     '
    
    '----------------------------------------------------------------
    ' 次へボタンをクリック
    '----------------------------------------------------------------
    Sub NextBtn_Click()                                         '
                                                                '
        If QuizNo >= 11 Then                                    '■出題されるクイズIndexが11以上の場合 終了処理
            Dim KekaTx As String                                '├【変数定義】結果テキスト
            TitleImage.Visible = True                           '├ タイトル画像  表示
            TitleLbl.Visible = True                             '├ タイトルラベル表示
            StartBtn.Visible = True                             '├ はじめるボタン表示
            KekaTx = "難しかったかな?"                         '├[初期化]結果テキスト
            If UserPoint >= 30 Then KekaTx = "ちょっと残念..."  '├◆点数が 30点以上のテキストを結果テキストへ代入
            If UserPoint >= 60 Then KekaTx = "まぁまぁかな?"   '├◆点数が 60点以上    〃     〃
            If UserPoint >= 80 Then KekaTx = "惜しい!"         '├◆点数が 80点以上    〃     〃
            If UserPoint >= 100 Then KekaTx = "満点おめでとう!" '├◆点数が100点以上    〃     〃
            TitleLbl.Caption = KekaTx                           '├ 結果テキストの画面反映
            StartBtn.Caption = "もう1回!"                     '├ はじめるボタンのキャプション変更
        Else                                                    '■出題されるクイズIndexが11以上ではない場合
            QuizDataGet                                         '└ 次のクイズデータを取得
        End If                                                  '
                                                                '
    End Sub                                                     '
    
    '----------------------------------------------------------------
    ' 選択肢ボタン1~4をクリック
    '----------------------------------------------------------------
    Sub QSelBtn1_Click()                                        '
        If QuizAns = 1 Then UserPoint = UserPoint + 10          '■クイズの答えが「1」の場合 >> 点数+10
        QAnsMB1.Visible = True                                  'マルバツラベル1を表示
        QuizAnsSelectAfter                                      '解答後の処理
    End Sub                                                     '
    Sub QSelBtn2_Click()                                        '
        If QuizAns = 2 Then UserPoint = UserPoint + 10          '■クイズの答えが「2」の場合 >> 点数+10
        QAnsMB2.Visible = True                                  'マルバツラベル2を表示
        QuizAnsSelectAfter                                      '解答後の処理
    End Sub                                                     '
    Sub QSelBtn3_Click()                                        '
        If QuizAns = 3 Then UserPoint = UserPoint + 10          '■クイズの答えが「3」の場合 >> 点数+10
        QAnsMB3.Visible = True                                  'マルバツラベル3を表示
        QuizAnsSelectAfter                                      '解答後の処理
    End Sub                                                     '
    Sub QSelBtn4_Click()                                        '
        If QuizAns = 4 Then UserPoint = UserPoint + 10          '■クイズの答えが「4」の場合 >> 点数+10
        QAnsMB4.Visible = True                                  'マルバツラベル4を表示
        QuizAnsSelectAfter                                      '解答後の処理
    End Sub                                                     '
    
    '----------------------------------------------------------------
    ' 解答後の処理
    '----------------------------------------------------------------
    Sub QuizAnsSelectAfter()                                    '
                                                                '
        QSelBtn1.Enabled = False                                ' 選択肢ボタン1 クリック不可
        QSelBtn2.Enabled = False                                '   〃   2    〃
        QSelBtn3.Enabled = False                                '   〃   3    〃
        QSelBtn4.Enabled = False                                '   〃   4    〃
                                                                '
        QAnsLbl.Visible = True                                  '答えラベル 表示
        NextBtn.Visible = True                                  '次へボタン 表示
        QuizNo = QuizNo + 1                                     'クイズIndex +1
        UserPointLbl.Caption = UserPoint & "点"                 '点数の更新
        Nokoribl.Caption = "残り" & (11 - QuizNo) & "問"        '残り問題数の更新
        NextBtn.SetFocus                                        '次へボタンにフォーカスを移す
        If QuizNo >= 11 Then NextBtn.Caption = "結果発表"       '■クイズIndexが11以上の場合 >> 次へボタンのキャプションを結果発表にする
                                                                '
    End Sub                                                     '
    '----------------------------------------------------------------
    ' 問題文と正解を取得し、画面表示する
    '----------------------------------------------------------------
    Sub QuizDataGet()                                           '
                                                                '
        NextBtn.Visible = False                                 ' 次へボタン   非表示化
        QAnsLbl.Visible = False                                 ' 答えラベル    〃
        QAnsMB1.Visible = False                                 ' マルバツラベル1  〃
        QAnsMB2.Visible = False                                 ' マルバツラベル2  〃
        QAnsMB3.Visible = False                                 ' マルバツラベル3  〃
        QAnsMB4.Visible = False                                 ' マルバツラベル4  〃
        QSelBtn1.Enabled = True                                 ' 選択肢ボタン1 クリック可
        QSelBtn2.Enabled = True                                 ' 選択肢ボタン2    〃
        QSelBtn3.Enabled = True                                 ' 選択肢ボタン3    〃
        QSelBtn4.Enabled = True                                 ' 選択肢ボタン4    〃
                                                                '
        QuizTxLbl.Caption = Worksheets(DtSt).Cells(QuizNo, 1)   ' 問題  データ取得
        QSelBtn1.Caption = Worksheets(DtSt).Cells(QuizNo, 2)    ' 選択肢1     〃
        QSelBtn2.Caption = Worksheets(DtSt).Cells(QuizNo, 3)    ' 選択肢2     〃
        QSelBtn3.Caption = Worksheets(DtSt).Cells(QuizNo, 4)    ' 選択肢3     〃
        QSelBtn4.Caption = Worksheets(DtSt).Cells(QuizNo, 5)    ' 選択肢4     〃
        QuizAns = Val(Worksheets(DtSt).Cells(QuizNo, 6))        ' 答え        〃
        
        '答えラベルに表示するテキストを編集
        QAnsLbl.Caption = "答:" & Worksheets(DtSt).Cells(QuizNo, QuizAns + 1)
        
        QAnsMB1.Caption = "×"                                  ' マルバツラベルの初期化
        QAnsMB2.Caption = "×"                                  '          〃
        QAnsMB3.Caption = "×"                                  '          〃
        QAnsMB4.Caption = "×"                                  '          〃
        If QuizAns = 1 Then QAnsMB1.Caption = "〇"              '■答えが「1」の場合 >> マルバツラベル1を〇にする
        If QuizAns = 2 Then QAnsMB2.Caption = "〇"              '■答えが「2」の場合 >> マルバツラベル2を〇にする
        If QuizAns = 3 Then QAnsMB3.Caption = "〇"              '■答えが「3」の場合 >> マルバツラベル3を〇にする
        If QuizAns = 4 Then QAnsMB4.Caption = "〇"              '■答えが「4」の場合 >> マルバツラベル4を〇にする
    End Sub  

    サンプル問題をコピペしよう!

    フォームとプログラムコードができました。
    あと必要なのは…クイズの問題文ですよね…

    クイズを考えるのも大変なので、とりあえずサンプル問題を用意しました。
    以下のクイズゲーム.csvをDLして中身を開いてください。

    上のCSVファイルを開くと、こんな感じの画面が表示されると思います。

    画像
    こちらはCSVファイル

    これをゲーム用のファイルにコピペします。

    画像
    こちらはゲーム用のファイル

    データの中身を軽く解説しますと…

    ・A列 問題文
    ・B列 選択肢1
    ・C列 選択肢2
    ・D列 選択肢3
    ・E列 選択肢4
    ・F列 答え

    なので「問題文」「選択肢」「答え」を用意できればオリジナルのクイズゲームが作れるんですね。自分の得意な雑学を10個ならべて世界に1つのゲームにしましょう!


    ゲームを動かしてみよう!

    先程の問題をコピペし終わったら実際にゲームを動かしてみましょう。スクショの通りユーザーフォームの名前の部分をダブルクリックすると、ユーザーフォームが表示されます。

    画像

    再生ボタンを押すとプログラムが動き始めます。

    上手く動かない場合は、以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「動かないんだけど!?(怒)」を参考に原因を探ってみましょう。落ち着いて確認してみてください。

    エラー原因の9割はオブジェクト名が間違っていると思います…


    続きます!

    これで簡単ではありますが、クイズゲームそのものは動いているハズです。
    現時点での仕様は10問のクイズデータを順に表示しているだけです。
    同テーマの次記事、2月12日公開(予定)ではもう少し改良しようと思っています。

    改良内容としては、
    (1)10問以上の問題から、10個の問題をランダムに出題する。
    (2)選択肢が2つ、または3つの問題にも対応する。
    (3)Excelファイルを起動した時点でクイズゲームを動かす。

    長い記事を読んでくださりありがとうございます。
    そして実作業された方はお疲れ様でした!
    また次回の記事でお会いできるのを楽しみにしております!

    あなたへのおすすめ