
関数が解らん!
ゲームを作る他に情報系専門学校の非常勤講師もやってます。
先日、夏休み前の定期試験を終えたばかり、というわけで一学期を振り返ってみて印象に残っている事は…
とある授業中、演習に取り組んでいる学生たちの声が聞こえてきます。
「この部分は関数化した方がいいかも!」
「でも関数にするのって難しくない?」
「慣れると解りやすいけどなぁ…」
この学生たちの言っていること、
「関数にしたい派」「関数にするの難しい派」どちらも理解できます。
というわけで「関数」の基本的な部分について書いてみます。
この記事は情報関係の勉強をしている学生さんにもオススメで、且つ、コードを書くのが苦手だけど頑張ってゲームを作っている方にも役に立つ(といいな)お話です。
関数とはなんぞや?
先程から「関数」が文中に何度も出てきていますが、そもそも関数って?
この記事を読んでいる方は既に知っているとは思いますが、まずは関数について、少しまとめます。
関数を文章で表現すると
何らかの変化する値を与えて…
決められた計算を行って…
その結果を返答する仕組み
で伝わりますかね?
例えば「 y = 4x + 3 」というという数式があります。
xの値が2だったら、「 y = 8+ 3 」「 y = 11 」となりますよね。
何らかの変化する値を与えて…(xの値が2だったら)
決められた計算を行って…(4x + 3 )
その結果を返答する仕組み(y=11)
これが関数の考え方です。
関数にも種類があってな…
パソコンを使っている人にとって最も身近な関数って、こんな感じだと思うんですけど、どうでしょう?(↓)

上図Excelのスクリーンショット、セルD6は各行の小計を合算しています。
セルD6には「=SUM(D2:D5)」という関数が打たれています。
何らかの変化する値を与えて…(セルの範囲D2からD5まで)
決められた計算を行って…([SUM]指定範囲内の合計)
その結果を返答する仕組み(D6に合計額を格納)
このSUM関数はExcelを起動してセルに打ち込むと使える状況にあります。
こういった既に使用できる(準備されている)関数は「組み込み関数」または「ビルドイン関数」と呼ばれます。
わたしはここまで細かく区別していませんが…
仕様的に定められていて、リファレンスマニュアルなんかに掲載されている変数を「標準関数」といい、公式で配布しているライブラリなんかもあるので、その場合は「標準ライブラリ関数」というらしいです。
これに対し、冒頭で学生たちが言っていた「この部分は関数化した方がいいかも!」の関数はユーザー(プログラミングする人)が作る関数。
つまり「ユーザー定義関数」のことを言っています。
プログラムには同じような処理を繰り返したり、ひとまとまりにできそうな処理が幾つも含まれています。さすがに「組み込み関数」だけでは、そんな処理を網羅しきれません。
そこでユーザーが作った関数「ユーザー定義関数」が活躍するんです。
これだけ聞くと、便利な感じがします。実際に便利です。
しかしプログラミングを学び始めた頃は、関数を作る行為そのものが脳のリソースを割いてしまうことがあります。
面倒臭い、難しいと感じるのも理解できるんですよ…
関数化の練習問題!
基本情報技術者試験向けの問題集や、R7年度から大学入学共通テストで出題される「情報I」の問題集なんかを見ると、探索アルゴリズムとして「線形探索」「二分探索」が載っています。
こういった問題集にも例題は載っているのですが、配列の中に特に意味を持たない数値が格納されていて、その中から該当する数値を見つけ出すような形式です。
こういった形式はシンプルなので、アルゴリズムの理解が目的であれば最高です。しかし、プログラムを組めるようになるのが目的であれば、ちょっと物足りません。
そういった理由もあり、担当する授業ではこんな感じの問題を出してます。
・問題
以下は「とある児童向け学習塾」の消耗品データと取引先データです。
足りないものがあったら、消耗品番号を入力して取引先の住所や電話番号を表示するプログラムを作ろうと考えました。
まずは消耗品データ!
消耗品番号をsNoという配列に入れて、消耗品名をsNmという配列に入れます。取引先番号はsTrに、単価はsYnに入れます。それぞれの配列は添え字によって対応しています。

取引先データの方も業者番号はgNoという配列に、業者名はgNm配列に入れます。住所はgAdに、電話番号はgTlに入れます。
それぞれの配列は添え字によって対応しています。

なお、消耗品データにある取引先番号 sTr と、取引先データの業者番号 gNo が対応しています。
これらをExcelシートで表現すると、こんな感じです。
これを元データにしてユーザーフォームを作っていきます。

VBAのコードではここまでの資料に基づいて以下のような配列を定義しました。今後もデータが増える可能性があるので少し余裕ある配列長です。
'------------------------------------------------------------
' 消耗品データ
'------------------------------------------------------------
Dim sNo(0 To 30) As Integer '【配列定義】消耗品番号
Dim sNm(0 To 30) As String '【 〃 】消耗品名
Dim sTr(0 To 30) As Integer '【 〃 】取引先番号
Dim sYn(0 To 30) As Integer '【 〃 】単価
'------------------------------------------------------------
' 取引先データ
'------------------------------------------------------------
Dim gNo(0 To 10) As Integer '【配列定義】業者番号(取引先番号)
Dim gNm(0 To 10) As String '【 〃 】業者名
Dim gAd(0 To 10) As String '【 〃 】住所
Dim gTl(0 To 10) As String '【 〃 】電話番号そして、以下のようなフォームを作りました。
消耗品番号を白枠に入力し検索ボタンを押すことで各種データが表示されるシステムを想定します。

なお、フォーム初期化の際に各配列に対してワークシートのデータを自動で格納しているものとし、消耗品番号の誤入力は発生しないものとします。
授業ではデータ準備や初期設定、エラー対応についても解説していますが、今回は関数化にテーマを絞った記事なので省略します。ご了承ください。
・関数化する前(ビフォー)
では、ここまでの設定から「消耗品番号を入力して取引先の住所や電話番号を表示する」フローチャートを書いてみましょう。

消耗品番号が入っている配列 sNo を入力された番号 iNo で線形探索します。これにより、その消耗品を普段頼んでいる業者(取引先)番号が判明します。
業者(取引先)番号が判明したので業者番号が入っている配列 gNo を線形探索します。これによって業者名、住所、電話番号がわかります。
つまり、線形探索して取得したデータを使って更に線形探索しています。
ではVBAでコード化してみましょう。
'------------------------------------------------------------
' 検索ボタンをクリックした時に動くプロシージャ
'------------------------------------------------------------
Private Sub SearchBtn_Click()
Dim iNo As Integer '【変数定義】消耗品番号の画面入力
Dim ixS As Integer '【 〃 】添え字 - 消耗品データ探索時
Dim ixT As Integer '【 〃 】添え字 - 取引先(業者)データ探索時
iNo = inNo.Text '画面から消耗品番号を取得
For ixS = 0 To UBound(sNo) '■《第1ループ》消耗品番号配列の全件ループ
If iNo = sNo(ixS) Then '├◆ 入力された消耗品番号とsNo配列の消耗品番号が同じ場合
sNmLbl.Caption = sNm(ixS) '│├[画面表示]消耗品名
sTrLbl.Caption = "[" & sTr(ixS) & "]" '│├[ 〃 ]取引先番号(業者番号)
sTrYenLbl.Caption = sYn(ixS) & " 円" '│├[ 〃 ]単価
'││
For ixT = 0 To UBound(gNo) '│├▼《第2ループ》業者番号配列の全件ループ
If sTr(ixS) = gNo(ixT) Then '││├◇消耗品データの取引先番号と業者番号が同じ場合
sTrNmLbl.Caption = gNm(ixT) '│││├[画面表示]業者名
sTrAdLbl.Caption = gAd(ixT) '│││├[ 〃 ]住所
sTrTlLbl.Caption = gTl(ixT) '│││├[ 〃 ]電話番号
Exit For '│││└ このループを終了する
End If '│││
Next ixT '││└《第2ループ終端》
'││
Exit For '│└ このループを終了する
End If '│
Next ixS '└《第1ループ終端》
End SubWorksheetFunction.Match(または Application.Match)を使う手段もありますが、ここではフローチャートの流れに近くするため、For文で線形探索を表現しています。
関数をテーマとした記事でなければ、ここまでのフローチャートおよびコードが書けていれば正解で「今日の授業はここまで」です。
しかし、今回は関数がテーマですからね、まだまだ続きます!
・関数化した後(アフター)
関数化する前のフローチャートを見直すと気になるところがあります。

画像の中にも書いていますが、青枠とオレンジ枠の処理ってほぼ同じです。
「じゃぁ、ここを関数化すればいいんじゃね?」
そうですよね…でもまぁ、落ち着いてください。
関数化に苦手意識を持っている方に向けて便利さを説明したいので、まずはオレンジ枠だけを関数化してみます。
オレンジ枠を関数化したフローチャートはこんな感じです。

「あれ? なんか面倒になっているような気がする…」
確かにフローチャートを見るとステップ数が増えています。が、メインルーチンだけを見ると少しシンプルな流れになっていますよね?
コードで表現するとこんな感じになります。
'------------------------------------------------------------
' 検索ボタンをクリックした時に動くプロシージャ
'------------------------------------------------------------
Private Sub SearchBtn_Click()
'
Dim iNo As Integer '【変数定義】消耗品番号の画面入力
Dim ixS As Integer '【 〃 】添え字 - 消耗品データ探索時
Dim ixT As Integer '【 〃 】添え字 - 取引先(業者)データ探索時
iNo = inNo.Text ' 画面から消耗品番号を取得
For ixS = 0 To UBound(sNo) '■消耗品番号配列の全件ループ
If iNo = sNo(ixS) Then '├◆ 入力された消耗品番号とsNo配列の消耗品番号が同じ場合
ixT = get_index(sTr(ixS)) '│├ 業者データを線形探索して該当データの添え字を取得する
sNmLbl.Caption = sNm(ixS) '│├[画面表示]消耗品名
sTrLbl.Caption = "[" & sTr(ixS) & "]" '│├[ 〃 ]取引先番号(業者番号)
sTrYenLbl.Caption = sYn(ixS) & " 円" '│├[ 〃 ]単価
sTrNmLbl.Caption = gNm(ixT) '│├[ 〃 ]業者名
sTrAdLbl.Caption = gAd(ixT) '│├[ 〃 ]住所
sTrTlLbl.Caption = gTl(ixT) '│├[ 〃 ]電話番号
Exit For '│└ このループを終了する
End If '│
Next ixS '└ループ終端
End Sub
'------------------------------------------------------------
' 業者データを線形探索するファンクション
'
' 引数:取引先番号(業者番号)
' 戻値:該当データの添え字
'
'------------------------------------------------------------
Private Function get_index(iNo As Integer) As Integer
Dim ix As Integer '【変数定義】添え字
For ix = 0 To UBound(gNo) '■業者番号配列の全件ループ
If iNo = gNo(ix) Then Exit For '├◇消耗品データの取引先番号と業者番号が同じ場合 >> ループを抜ける
Next ix '└ループ終端
get_index = ix ' 添え字を戻値として返答
End Function「うわ、やっぱり長くなってる!」
確かにコードは長くなりましたが、SearchBtn_Click()プロシージャだけを見ると、かなりシンプルになりました。
ただ、これだけでは関数化の効果を実感できないかもしれません。
というわけで、青枠も関数化します!
・更に関数化!(アフターアフター)
下図のフローチャートをご覧ください。
すっごいスッキリしました。

コードの方はこんな感じになります。
'------------------------------------------------------------
' 検索ボタンをクリックした時に動くプロシージャ
'------------------------------------------------------------
Private Sub SearchBtn_Click()
'
Dim iNo As Integer '【変数定義】消耗品番号の画面入力
Dim ixS As Integer '【 〃 】添え字 - 消耗品データ探索時
Dim ixT As Integer '【 〃 】添え字 - 取引先(業者)データ探索時
iNo = inNo.Text ' 画面から消耗品番号を取得
ixS = get_index(sNo, iNo) ' 業者データ を線形探索して該当データの添え字を取得する
ixT = get_index(gNo, sTr(ixS)) ' 消耗品データを線形探索して該当データの添え字を取得する
sNmLbl.Caption = sNm(ixS) '[画面表示]消耗品名
sTrLbl.Caption = "[" & sTr(ixS) & "]" '[ 〃 ]取引先番号(業者番号)
sTrYenLbl.Caption = sYn(ixS) & " 円" '[ 〃 ]単価
sTrNmLbl.Caption = gNm(ixT) '[ 〃 ]業者名
sTrAdLbl.Caption = gAd(ixT) '[ 〃 ]住所
sTrTlLbl.Caption = gTl(ixT) '[ 〃 ]電話番号
End Sub
'------------------------------------------------------------
' 一次元配列を線形探索するファンクション
'
' 引数:探索する配列 , 対象の番号
' 戻値:該当データの添え字
'
'------------------------------------------------------------
Private Function get_index(TBL() As Integer, iNo As Integer) As Integer
Dim ix As Integer '【変数定義】添え字
For ix = 0 To UBound(TBL) '■配列の全件ループ
If iNo = TBL(ix) Then Exit For '├◇指定番号と同じ番号の場合 >> このループを抜ける
Next ix '└ループ終端
get_index = ix ' 添え字を戻値として返答
End Function「いや、やっぱり長いよ!?」と感じるかもしれませんが、SearchBtn_Click()プロシージャだけを改めて貼り付けると…
'------------------------------------------------------------
' 検索ボタンをクリックした時に動くプロシージャ
'------------------------------------------------------------
Private Sub SearchBtn_Click()
'
Dim iNo As Integer '【変数定義】消耗品番号の画面入力
Dim ixS As Integer '【 〃 】添え字 - 消耗品データ探索時
Dim ixT As Integer '【 〃 】添え字 - 取引先(業者)データ探索時
iNo = inNo.Text ' 画面から消耗品番号を取得
ixS = get_index(sNo, iNo) ' 業者データ を線形探索して該当データの添え字を取得する
ixT = get_index(gNo, sTr(ixS)) ' 消耗品データを線形探索して該当データの添え字を取得する
sNmLbl.Caption = sNm(ixS) '[画面表示]消耗品名
sTrLbl.Caption = "[" & sTr(ixS) & "]" '[ 〃 ]取引先番号(業者番号)
sTrYenLbl.Caption = sYn(ixS) & " 円" '[ 〃 ]単価
sTrNmLbl.Caption = gNm(ixT) '[ 〃 ]業者名
sTrAdLbl.Caption = gAd(ixT) '[ 〃 ]住所
sTrTlLbl.Caption = gTl(ixT) '[ 〃 ]電話番号
End Subループしていません。
ただ単純に上から下に向けて淡々と処理をしているように見えます。
凄くわかりやすいですよね。
線形探索のループをしている部分は全て関数の方にあります。
関数化した Get_index() の方だけを貼り付けると、
…コメント部分で長く感じるかも、なのでコメントも消します。
Private Function get_index(TBL() As Integer, iNo As Integer) As Integer
Dim ix As Integer '【変数定義】添え字
For ix = 0 To UBound(TBL) '■配列の全件ループ
If iNo = TBL(ix) Then Exit For '├◇指定番号と同じ番号の場合 >> このループを抜ける
Next ix '└ループ終端
get_index = ix ' 添え字を戻値として返答
End Functionたったこれだけです。
そして、この関数を作ったことで、他の一次元配列であっても線形探索が可能となります。例えば引数に価格が格納されている配列 sYn と、手入力した値を入れることで、価格による探索が可能となります。
これが関数化の良いところです!
おまけ
前述したApplication.Match(または WorksheetFunction.Match)を使う手段だと以下のような感じになります。今回の記事では線形探索をフローチャート、コードとして意識するためにFor文を使用しました。
'------------------------------------------------------------
' 検索ボタンをクリックした時に動くプロシージャ
'------------------------------------------------------------
Private Sub SearchBtn_Click()
'
Dim iNo As Integer '【変数定義】消耗品番号の画面入力
Dim ixS As Integer '【 〃 】添え字 - 消耗品データ探索時
Dim ixT As Integer '【 〃 】添え字 - 取引先(業者)データ探索時
iNo = inNo.Text ' 画面から消耗品番号を取得
ixS = Application.Match(iNo, sNo, 0) - 1 ' 業者データ を線形探索して該当データの添え字を取得する
ixT = Application.Match(sTr(ixS), gNo, 0) - 1 ' 消耗品データを線形探索して該当データの添え字を取得する
'ixS = WorksheetFunction.Match(iNo, sNo, 0) - 1 ' ※ エラーに対する対応等が違う...けど、上記とほぼ同じ
'ixT = WorksheetFunction.Match(sTr(ixS), gNo, 0) - 1 ' └ https://learn.microsoft.com/ja-jp/office/vba/api/excel.worksheetfunction.match
sNmLbl.Caption = sNm(ixS) '[画面表示]消耗品名
sTrLbl.Caption = "[" & sTr(ixS) & "]" '[ 〃 ]取引先番号(業者番号)
sTrYenLbl.Caption = sYn(ixS) & " 円" '[ 〃 ]単価
sTrNmLbl.Caption = gNm(ixT) '[ 〃 ]業者名
sTrAdLbl.Caption = gAd(ixT) '[ 〃 ]住所
sTrTlLbl.Caption = gTl(ixT) '[ 〃 ]電話番号
End Subおわりに
いかがでしたでしょうか?
関数、特に「ユーザー定義関数」は理解できたでしょうか?
「理解はできても苦手…」という方もいらっしゃると思います。
これに関しては必要に迫られて、いつの間にか使えるようになるものだと思います。
情報系の学習をする際に使用する問題集や解説書では、アルゴリズム(考え方)を理解しやすいようにシンプルな例示が多く、関数化するメリットを感じられないことがあります。
となると、必要に迫られて独学でゲームを作っている人は関数に対してそこまで苦手意識がないかもしれません。
こういった勉強って、例が適切なら理解しやすいのですが、不十分な例だと混乱しますよね…いま学習の真っ最中の方は焦らず、長いコードを扱うようになるまで関数化を急がなくていいと思いますよ。
今回はここまでです。
それでは、また別の記事でお会いできるのを楽しみにしております。
ここからはオススメ記事の紹介です。
もうちょっと勉強したいなーって方にはコチラがオススメです。
これらの勉強に使えそうな関連記事は以下にまとめてます!(↓)
「読むとゲームができるマガジン」もオススメです。
まずは身近なソフトで作ってみるのもアリかも!
Excelでもある程度のゲームは作れますよ(↓)