メインコンテンツへスキップ
見出し画像

一番〇〇なデータを見つけよう!

    こんにちは「つけらっとゲームス」プログラム担当のとちです。

    ゲームを作る他に専門学校のシステム系学科で外部講師もやってます。
    今回は「一番〇〇なデータを見つける方法」について考えてみましょう。

    情報関連の勉強をしていて「学校で習ったけどよくわからん」という方や、これからプログラムを勉強しようという方にオススメの内容です。

    複数データの中から特定のモノを探す方法として、これまでお話したのが「線形探索」「二分探索」でした。その記事は以下に並べますね。

    これらの探索は、例えば「英語のテストの点数を知りたい」だったり、「顧客番号74番は誰か知りたい」という特定の条件を持ったデータを探す方法でしたよね?

    しかし、今回は一番〇〇なデータを探す方法です。
    プログラムでどうやって解決するか考えてみましょう!!


    一番高いを探す例題

    早速ですが、今回のお話では以下のデータを例として使用します。

    いま、あなたはRPGで遊んでいるとしましょう。
    旅の途中、所持金に余裕がなくなってきました。アイテム欄をみたら装備していない武器が結構ありまして、ひとつくらい売ってもいいかなっと思いました。売値は価格の半分としますね。

    画像

    持っている武器は上の表にあるように変数配列に入ってます。
    それぞれ「武器名 bName」「攻撃力 bAtk」「命中率 bHit」「価格 bGold」となっています。

    例えば達人の刀は bName[0] に入っていて、達人の刀の攻撃力は bAtk[0] に入っているものとします。つまり添字で関連付いているんです。

    さて、何を売ろうかな?
    お金がないから一番売値が高いを武器を売りたいですね。どれかな?

    人間の目だと瞬時に判断できます。黄金の短剣です。
    しかし、これをプログラムで判断するならどうなるでしょう?


    一番高いを探すアルゴリズム

    「線形探索」「二分探索」の時のように、まずは処理内容を想像します。
    わかりやすいように順序良く解決していきます。

    添字[0]データ 達人の刀  価格5000
    添字[1]データ 妖精の弓  価格4000 さっきの価格5000の方が高い
    添字[2]データ 騎士の剣  価格3000 さっきの価格5000の方が高い
    添字[3]データ きこりの斧 価格1000 さっきの価格5000の方が高い
    添字[4]データ 黄金の短剣 価格8000 こいつの価格8000の方が高い
    添字[5]データ 衛兵の槍  価格2000 さっきの価格8000の方が高い
    添字[6]データ 戦神の斧  価格6000 さっきの価格8000の方が高い
    残りデータがなくなった! ということは価格8000が一番高い!

    このやり方で行けそうです!

    最初の価格を見て、次の価格を見て……というのを繰り返します。
    価格を比較して高い方を覚えておきます。データの最後まで確認し終えたら
    覚えていた価格が一番高いことになります(よね?)


    一番高いを探すフローチャート

    では「線形探索」「二分探索」の記事と同じように、これをフローチャート(流れ図)にしてみましょう!

    想像したアルゴリズムを図で表現します。
    一気に書くのが難しければ、線形探索と似たような形になりますので、まずはグルグル回る部分を先に書いちゃってもいいと思います。

    画像


    フローチャートをみると、幾つかの変数が定義されていますね。
    変数 Mx に一番高い価格そのものを入れて比較に使っています。
    変数 ixsv には現時点で一番高い価格を見つけた時に、その時の添字を入れて持っておいているんですね。

    ちなみに…
    変数 Mx の名前の由来は Max(最大)からきてます。
    変数 ixsv の名前の由来は ix(index)を保持しておく(save)です。

    変数1個や2個なら簡単だけど、3個、4個と増えると混乱しちゃいますね。しかし、このへんは慣れです。実際にプログラムコードを書くと大量の変数を使ったりするので、いまのうちに慣れちゃいましょう!


    一番高いを探すプログラム(VBA)

    フローチャートを書いたので、次はプログラムコードにしてみます。
    まず、エクセルに例のデータを作っておきました。
    フォームを起動したときにデータを読みます。

    フォームに作ったコマンドボタン「一番高い価格の武器」をクリックしたら、メッセージボックスに「武器名」を表示します。
    例のデータですと「黄金の短剣」です。正しく動いています!

    画像

    ではプログラムコードを確認してみましょう。

    Option Explicit
    Dim wLen      As Integer                                        '【変数定義】配列長
    
    '--- 配列群「持っている武器」---
    Dim bName(20) As String                                         '【配列定義】武器名 のデータが入る配列
    Dim bAtk(20)  As Integer                                        '【配列定義】攻撃力 のデータが入る配列
    Dim bHit(20)  As Integer                                        '【配列定義】命中率 のデータが入る配列
    Dim bGold(20) As Integer                                        '【配列定義】価格  のデータが入る配列
    
    '────────────────────────────────────────────────────────────────────────────────
    '
    ' ユーザーフォームがアクティブになった時に発生する
    '
    '────────────────────────────────────────────────────────────────────────────────
    Private Sub UserForm_Activate()
        
        Dim ix As Integer                                           '【変数定義】配列にデータを入れるための添字
        
        For ix = 0 To 20                                            '■ 初期データを代入しておく
            If Sheet1.Cells(2, ix + 3).Value = "" Then Exit For     '├ 武器名がNullだったらループを抜ける
            bName(ix) = Sheet1.Cells(2, ix + 3).Value               '├ Sheet1の武器名  を配列bName に代入
            bAtk(ix) = Sheet1.Cells(3, ix + 3).Value                '├ Sheet1の攻撃力 を配列bAtk  に代入
            bHit(ix) = Sheet1.Cells(4, ix + 3).Value                '├ Sheet1の命中率 を配列bHit  に代入
            bGold(ix) = Sheet1.Cells(5, ix + 3).Value               '├ Sheet1の価格  を配列bGold に代入
            wLen = ix + 1                                           '└ 配列長(有効データカウンタ)
        Next ix
    
    End Sub
    
    '────────────────────────────────────────────────────────────────────────────────
    '
    ' 【線形探索】を利用して最も高い価格の武器を探す
    '  フォームのボタンを押された時に発生する
    '
    '────────────────────────────────────────────────────────────────────────────────
    Private Sub CommandButton1_Click()
        
        Dim bLen  As Integer                                        '【変数定義】配列長
        Dim ix    As Integer                                        '【変数定義】配列を探索するための添え字
        Dim ixsv  As Integer                                        '【変数定義】最も高い価格を覚えておく添字
        Dim Mx    As Integer                                        '【変数定義】最も高い価格を覚えておく変数
        
        bLen = wLen                                                 'フォームがアクティブになった時に数えた配列長を使う
        Do While ix < bLen                                          '■ ixが配列長(7件)になるまでループする
            If (bGold(ix) > Mx) Then                                '├◆ 価格を比較して覚えていた価格より高い場合
                Mx = bGold(ix)                                      '│├ Mx に今の価格を覚えておく
                ixsv = ix                                           '│└ ixsvに今の添字を覚えておく
            End If                                                  '│
            ix = ix + 1                                             '└ 添字ix を1ずつ増やす
        Loop
        MsgBox bName(ixsv)                                          'bName(ixsv)をメッセージボックスで表示する
    
    End Sub

    面倒臭くない?

    はい、はじまりました。
    どうしてもアルゴリズムを考えて、フローチャート書いて、コードにしてみると毎回のように思うんですが、そうなんです、面倒臭いし難しい。

    でもこの考え方さえできれば色んなことに流用できるんですね。ええ。

    例えば、金策の為に売るという前提条件だったので上記の例では最も価格の高い武器を探しましたが、道具欄が圧迫されているので、あまり役に立たない武器を売るとしましょう。攻撃力が一番低い武器はどれでしょう?


    一番低いを探すアルゴリズム

    まずはデータを再掲します。

    画像

    処理内容を想像します。前の例題は価格の高い武器ですが、さっきの逆。
    最も攻撃力の低い武器を探します。逆なだけなので簡単ですよ。

    添字[0]データ 達人の刀  攻撃力70
    添字[1]データ 妖精の弓  攻撃力10 こいつの攻撃力10の方が低い
    添字[2]データ 騎士の剣  攻撃力65 さっきの攻撃力10の方が低い
    添字[3]データ きこりの斧 攻撃力50 さっきの攻撃力50の方が低い
    添字[4]データ 黄金の短剣 攻撃力30 さっきの攻撃力10の方が低い
    添字[5]データ 衛兵の槍  攻撃力50 さっきの攻撃力10の方が低い
    添字[6]データ 戦神の斧  攻撃力80 さっきの攻撃力10の方が低い
    残りデータがなくなった! ということは攻撃力10が一番低い!


    一番低いを探すフローチャート

    さっきと逆のフローチャートを書けばいいんです。簡単です。
    なにしろ修正したのは赤文字の部分だけ!
    変数 Mn に関しては、別に Mx のままでも構いません。

    画像

    覚えておく数値を価格ではなく攻撃力に変更し、比較する際の大小記号の向きを変えるだけでいいんです。

    ただ、注意したいのは Mn に入れる初期値999です。
    最も小さいものを探すのに、ここにゼロを入れちゃうと比較で1度も引っかからないんですね。注意です!!


    一番低いを探すプログラム(VBA)

    フローチャートが逆ならば、プログラムコードも逆になります。
    エクセルのデータはさっきと同じでいいですね。フォームを起動したときにデータを読みます。

    コマンドボタンをひとつ増やしました。
    「一番低い攻撃力の武器」をクリックしたら…妖精の弓が出ましたね。
    攻撃力が一番低いのは「妖精の弓」なので正しい!

    画像
    '────────────────────────────────────────────────────────────────────────────────
    '
    ' 【線形探索】を利用して最も低い攻撃力の武器を探す
    '  フォームのボタンを押された時に発生する
    '
    '────────────────────────────────────────────────────────────────────────────────
    Private Sub CommandButton2_Click()
    
        Dim bLen  As Integer                                        '【変数定義】配列長
        Dim ix    As Integer                                        '【変数定義】配列を探索するための添え字
        Dim ixsv  As Integer                                        '【変数定義】最も低い攻撃力を覚えておく添字
        Dim Mn    As Integer                                        '【変数定義】最も低い攻撃力を覚えておく変数
        
        Mn = 999                                                    '最も低い攻撃力を覚えておく変数を初期化する (999)
        bLen = wLen                                                 'フォームがアクティブになった時に数えた配列長を使う
        Do While ix < bLen                                          '■ ixが配列長(7件)になるまでループする
            If (bAtk(ix) < Mn) Then                                 '├◆ 攻撃力を比較して覚えていた攻撃力より低い場合
                Mn = bAtk(ix)                                       '│├ Mn に今の攻撃力を覚えておく
                ixsv = ix                                           '│└ ixsvに今の添字を覚えておく
            End If                                                  '│
            ix = ix + 1                                             '└ 添字ix を1ずつ増やす
        Loop
        MsgBox bName(ixsv)                                          'bName(ixsv)をメッセージボックスで表示する
    
    End Sub
    

    コマンドボタン2の部分だけを追加しました。
    プログラムコード自体はほぼ同じですね。フローチャートの赤字部分をそのまま修正してコード化しています。


    おわりに

    ひとつ、フローチャート(プログラムコード)が作れたら、それを流用するだけで色々なモノが作れます。参照する項目を変更するだけで別の場面で使えたりします。

    慣れてきたら関数化していくと更に良い!
    似たような処理をしているんですから、もっと効率化できますが…
    とにかく慣れるまでは難しく考えず、ひとつひとつ解決していきましょう。

    今後もアルゴリズムやフローチャートといったプログラミング学習関連については記事にしていきますので、勉強したい方は一緒にがんばりましょう!

    ちなみにプログラミング学習の関連記事は以下にまとめてます!

    すごく難しそうなことを書いていますが、普段はこんなゲームを作っているサークルの人です。ご興味がございましたらご覧ください(↓)

    それでは、また別の記事でお会いできるのを楽しみにしております!

    あなたへのおすすめ