
Excel(VBA)でメチャクチャ簡単に「あみだくじ」を作る
こんにちは「つけらっとゲームス」プログラム担当のとちです。
今回はExcel(VBA)であみだくじを作ります!
ここ最近「Excel(VBA)で〇〇を作る」シリーズの記事がくっそ長くなっていて、とてもじゃないが初心者向けとは言えません…よね?
一緒に作ってみようと言われても面倒臭い!
ということで、ほんの少しの作業で動くあみだくじを作ります!
ちなみに完成すると、こんな感じに動きます。

もうちょっと綺麗な動画を見たい方はコチラからどうぞ!
いつもよりシンプルなので一緒に作ってみてね!
プログラム担当がnote用に、少しだけ作業すると動く「あみだくじ」をExcel(VBA)で作っているようです✨
— つけらっとゲームス (@tsukerat) August 9, 2025
次の水曜日に公開予定...お盆休みに作ってみませんか?
お楽しみに🐱🐭 pic.twitter.com/cSsyoJOsdb
いつものようにユーザーフォームを挿入、各オブジェクトを作っていき最後にソースを丸ごとコピーする流れで作成していきます。と言っても今回はオブジェクト1つ作ればOKです。簡単!
なお、この記事のスクショについて、わたしのPCに入っているMicrosoft office Home and Business 2016でスクショを撮りました。
なので表示が微妙に異なる可能性があります。しかしデスクトップ版のExcelであれば、開発に使用するVBA(Microsoft Visual Basic for Applications)は同じで作業内容も変わりません。Microsoft365のExcelでも動作します。
それと、開発前に環境を整える必要があります。
以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「Excelの準備」を参照してVBAを使えるようにしておきましょう。
また「Excel(VBA)で〇〇を作る」記事は以下のマガジンにまとめています。
他のゲームの解説もあるので、マガジンの中からお好みのゲームを探してくださいね!
開発環境を準備する
「Excelの準備」を参照してVBAを使えるようにできましたか?
それでは拡張子が「xlsm」のExcelファイルを作りましょう。

上のスクショでは「あみだくじ.xlsm」という名前で作っていますが、名前は他のモノでも構いません。
気をつける点は1つ、拡張子は「xlsm」にする必要があります。
ユーザーフォームを作る
最初にやるべきことは「挿入」>「ユーザーフォーム」でまっさらなユーザーフォームを準備することです。

(1)挿入→(2)ユーザーフォーム と選択すると UserForm1 が作られます。
(3)作られたUserForm1のどこかをシングルクリックすると、(4)プロパティ欄にクリックされたコントロール(オブジェクト)の内容が表示されます。
今回はユーザーフォームをクリックしたので、ユーザーフォームのプロパティが表示されます。

Heightの値を432、Widthの値を360に変更します。
テキストボックスを設置する
次にテキストボックスを配置します。
ツールボックスからテキストボックスを選択しフォーム上に適当に配置してください。
テキストボックスのオブジェクト名は「TextBox1」です。
あとは大きさも位置も気にしなくて大丈夫です。

このテキストボックスは、ゲーム中のキー入力を制御するダミーのオブジェクトです。ゲーム中は見えないオブジェクトなので小さくて構いません。
(ゲーム中は画面の上方に移動しプレイヤーからは見えないようにします)
作るオブジェクトは以上となります。
え!? 少なくない!?
ソースコードをコピペ!
いつもよりオブジェクトが少ない、だけど、これで良いのです。
何故ならほとんどのオブジェクトはコードの中で生成しているので!
以下の記事はUnityについて書いていますが、これは他でも同じ!
作業量を減らすためコードでオブジェクト生成しています。
では作業再開!
どこでもいいので、フォームをダブルクリックします。

すると、コードを入力できるエディタ画面に切り替わります。
既にコードが表示されていますが、一旦全て消してください。

そこに以下のコードを全部コピペします。
Option Explicit
'
Const BaseSz As Integer = 30 '【定数定義】マス目の基本サイズ 30x30
Const BaseXX As Integer = 30 '【 〃 】マス目の作成開始x位置 30
Const BaseYY As Integer = 72 '【 〃 】マス目の作成開始y位置 72
Const GridSz As Integer = 28 '【 〃 】マス目の作成開始y位置 72
Const WaitCt As Integer = 100 '【 〃 】待機ミリ秒 100ミリ秒
Const CtrlNm As String = "Forms.Label.1" '【 〃 】作成コントロール種 Label
'
Dim GrMasu(1 To 10, 1 To 10) As Object '【配列定義】あみだくじの線オブジェクト
Dim RnMasu(1 To 20) As Object '【 〃 】辿り線(赤線)オブジェクト
Dim SelOBJ As Object '【変数定義】選択用オブジェクト(▼)
Dim SelPos As Integer '【 〃 】選択位置
Dim GolOBJ As Object '【 〃 】Goal用オブジェクト
Dim GolPos As Integer '【 〃 】Goal位置
Dim MsgOBJ As Object '【 〃 】メッセージ用ラベルオブジェクト
Dim Msg(4) As String '【 〃 】メッセージ内容
Dim CtrlSW As Integer '【 〃 】ゲーム制御スイッチ [1]スタート位置選択 [2]再プレイ選択
'--------------------------------------------------------------------
' フォーム初期化時
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub UserForm_Initialize()
Randomize '[ 初期化 ]乱数
SelPos = 1 '[ 〃 ]選択位置
CtrlSW = 1 '[ 〃 ]ゲーム制御スイッチ
UserForm1.Caption = "あみだくじ" '[ 〃 ]フォームタイトル
Msg(0) = "←・→でスタート地点を決めてね!" '[ 〃 ]メッセージ (0-1)
Msg(0) = Msg(0) & Chr(13) & "↓ボタンでスタートするよ!" '[ 〃 ] 〃 (0-2)
Msg(1) = Chr(13) & "Spaceキーを押すともう1回あそべるよ!" '[ 〃 ] 〃 (1)
Msg(2) = "残念でした..." '[ 〃 ] 〃 (2)
Msg(3) = "正解おめでとう!" '[ 〃 ] 〃 (3)
Set MsgOBJ = Controls.Add(CtrlNm) '[OBJ作成 ]メッセージ用ラベル
Call LabelSetting(MsgOBJ, -3, 0) '[OBJ設定 ]メッセージ用ラベル
Set SelOBJ = Controls.Add(CtrlNm) '[OBJ作成 ]選択用ラベル
Call LabelSetting(SelOBJ, -1, 0) '[OBJ設定 ]選択用ラベル
Call Create_Amida ' あみだくじの線を作成する
TextBox1.SetFocus ' ダミーテキストボックスにフォーカスをセット(キー入力制御用)
TextBox1.Top = -50 ' ダミーテキストボックスを画面外に移動 ( 見えなくする )
End Sub
'--------------------------------------------------------------------
' キー入力制御 (TextBox1のキーダウンイベントを利用)
'
' 引数 KeyCode
'
' 戻値 なし
'
' 備考 229は全角時にspaceを押すと返答される...
' IMEModeを3-fmIMEModeDisable にしていれば回避できる
'
'--------------------------------------------------------------------
Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
Select Case CtrlSW ' ■ゲーム制御スイッチで分岐
Case 1 ' ├◆ゲーム制御スイッチが 1 の場合
If KeyCode = 39 Then SelPos = SelPos + 1 ' │├□ 右キーが押下された場合 (39 は vbKeyRight でもよい)>> 選択位置+1
If KeyCode = 37 Then SelPos = SelPos - 1 ' │├□ 左キーが押下された場合 (37 は vbKeyLeft でもよい)>> 選択位置-1
If SelPos < 1 Then SelPos = 10 ' │├□ 選択位置が1未満になった場合 >> 選択位置を10にする
If SelPos > 10 Then SelPos = 1 ' │├□ 選択位置が10超 になった場合 >> 選択位置を 1にする
SelOBJ.Left = BaseXX + (SelPos - 1) * 28 ' │├ 選択位置から▼のx座標を算出して画面反映する
If KeyCode = 40 Then ' │└□ 下キーが押下された場合 (40 は vbKeyDown でもよい)
Call Run_Amida ' │ ├ あみだくじの線を辿る
CtrlSW = 2 ' │ └ ゲーム制御スイッチ を [2]再プレイ選択 にする
End If ' │
Case 2 ' ├◆ゲーム制御スイッチが 2 の場合
If KeyCode = 32 Or KeyCode = 229 Then ' │└□ Spaceが押下された場合 (32 は vbKeySpace でもよい)※備考参照
Call Del_Amida ' │ ├ あみだくじの線を全て削除する
Call Create_Amida ' │ ├ あみだくじの線を作成する
MsgOBJ.Caption = Msg(0) ' │ ├ メッセージ変更
CtrlSW = 1 ' │ └ ゲーム制御スイッチ を [1]スタート位置選択 にする
End If ' │
End Select ' └ゲーム制御スイッチで分岐終了
End Sub
'--------------------------------------------------------------------
' あみだくじの線を作成する
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Create_Amida()
Dim XX As Integer '【変数定義】マス目横軸x カウンタ
Dim YY As Integer '【 〃 】マス目縦軸y カウンタ
For YY = 1 To 10 ' ■ マス目縦軸yが1から10の間ループする
For XX = 1 To 10 ' ├◆ マス目縦軸xが1から10の間ループする
Set GrMasu(XX, YY) = Controls.Add(CtrlNm) ' │├ マス目(あみだくじの線)を生成する
Call LabelSetting(GrMasu(XX, YY), XX, YY) ' │├ ラベルコントロールの設定
Next XX ' │└ ループ終端
Next YY ' └ ループ終端
If Not GolOBJ Is Nothing Then ' ■ Goal用オブジェクトに何か入っていた場合
Me.Controls.Remove GolOBJ.Name ' └ Goal用オブジェクトを削除
End If '
Set GolOBJ = Controls.Add(CtrlNm) ' Goal用オブジェクトを生成する
GolPos = fRandom(10, 1) ' Goal位置をランダム取得
Call LabelSetting(GolOBJ, -2, 0) ' Goal用オブジェクト(ラベルコントロール)の設定
End Sub
'--------------------------------------------------------------------
' あみだくじの線を辿る
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Run_Amida()
Dim XX As Integer '【変数定義】マス目横軸x 辿り線の位置
Dim YY As Integer '【 〃 】マス目縦軸y カウンタ
Dim Sn As String '【 〃 】あみだくじの線
Dim Nx As String '【 〃 】あみだくじの線の次の線
Dim St As Integer '【 〃 】辿り線カウンタ
St = 0 '[ 初期化 ]辿り線カウンタを0にする
XX = SelPos '[ 〃 ]辿り線の位置を選択位置から取得
For YY = 1 To 10 ' ■ マス目縦軸yが1から10の間ループする
St = St + 1 ' ├ 辿り線カウンタ +1
Sn = GrMasu(XX, YY).Caption ' ├ あみだくじの線の内容をマス目から取得
Set RnMasu(St) = Controls.Add(CtrlNm, "wRun") ' ├ 辿り線オブジェクトを生成し wRun と命名する
Call LabelSetting(RnMasu(St), XX, YY) ' ├ 辿り線オブジェクト(ラベルコントロール)の設定
If Sn = "┃" Then ' ├◆あみだくじの線が "┃" の場合
RnMasu(St).Caption = Sn ' │├辿り線に "┃" を格納する
Else ' │◆あみだくじの線が "┃" 以外の場合
If Sn = "┣" Then ' │├□あみだくじの線が "┣" の場合
RnMasu(St).Caption = "┗" ' ││├ 辿り線に "┗" を格納する
Nx = "┓" ' ││├ 次の線に "┓" を格納する
XX = XX + 1 ' ││└ 辿り線の位置 +1
End If ' ││
If Sn = "┫" Then ' │├□あみだくじの線が "┫" の場合
RnMasu(St).Caption = "┛" ' ││├ 辿り線に "┛" を格納する
Nx = "┏" ' ││├ 次の線に "┏" を格納する
XX = XX - 1 ' ││└ 辿り線の位置 -1
End If ' ││
Call WaitMSecond(WaitCt) ' │├ 指定ミリ秒待機
St = St + 1 ' │├ 辿り線カウンタ +1
Set RnMasu(St) = Controls.Add(CtrlNm, "wRun") ' │├ 辿り線オブジェクトを生成し wRun と命名する
Call LabelSetting(RnMasu(St), XX, YY) ' │├ 辿り線オブジェクト(ラベルコントロール)の設定
RnMasu(St).Caption = Nx ' │└ 辿り線に次の線の文字を格納する
End If ' │
Call WaitMSecond(WaitCt) ' ├ 指定ミリ秒待機
Next YY ' └ ループ終端
MsgOBJ.Caption = Msg(2) & Msg(1) ' 正解に辿り着けなかった場合のメッセージ
If GolPos = XX Then MsgOBJ.Caption = Msg(3) & Msg(1) ' 正解に辿り着けた場合のメッセージ
End Sub
'--------------------------------------------------------------------
' あみだくじの線を全て削除する
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Del_Amida()
Dim XX As Integer '【変数定義】マス目横軸x カウンタ (辿り線カウンタ)
Dim YY As Integer '【 〃 】マス目縦軸y カウンタ
For YY = 1 To 10 ' ■ マス目縦軸yが1から10の間ループする
For XX = 1 To 10 ' ├◆ マス目縦軸xが1から10の間ループする
If Not GrMasu(XX, YY) Is Nothing Then ' │├□ あみだくじの線オブジェクトが存在している場合
Me.Controls.Remove GrMasu(XX, YY).Name ' ││└ あみだくじの線オブジェクトを削除する
End If ' ││
Next XX ' │└ ループ終端
Next YY ' └ ループ終端
For XX = 1 To 20 ' ■ 辿り線カウンタが1から20の間ループする
If Not RnMasu(XX) Is Nothing Then ' ├◆ 辿り線オブジェクトが存在している場合
Me.Controls.Remove RnMasu(XX).Name ' │└ 辿り線オブジェクトを削除する
End If ' │
Next XX ' └ ループ終端
Erase GrMasu ' あみだくじの線オブジェクト配列の消去
Erase RnMasu ' 辿り線(赤線)オブジェクト配列の消去
End Sub
'--------------------------------------------------------------------
' ラベルコントロールの設定
'
' 引数 wOBJ : 設定するラベルオブジェクト
' XX : [1以上] グリッド位置
' [-1] 選択(▼)
' [-2] 正解(〇)
' [-3] メッセージ
' YY : [1以上] グリッド位置
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub LabelSetting(wOBJ As Object, XX As Integer, YY As Integer)
Dim ProcSW As String '【変数定義】処理スイッチ
Dim Sn As String '【 〃 】あみだくじの線
ProcSW = "" '[ 初期化 ]処理スイッチ
If wOBJ.Name = "wRun" Then ProcSW = "_run" ' ■引数のwOBJのオブジェクト名が wRun だった場合 >> 処理スイッチに _run を入れる
With wOBJ ' ■With始端 : 以降のプロパティはwOBJを対象とする
'----------------------------------------------- ' │
' グリッド あみだくじの線 or 辿り線 ' │
'----------------------------------------------- ' │
If XX >= 1 Then ' ├◆引数XXが1以上(グリッド位置)の場合
.Name = "Label_" & XX & "_" & YY & ProcSW ' │├ wOBJ のオブジェクト名
.Top = BaseYY + (YY - 1) * 28 ' │├ wOBJ のオブジェクトy位置
.Left = BaseXX + (XX - 1) * 28 ' │├ wOBJ のオブジェクトx位置
If ProcSW = "" Then ' │└□ 処理スイッチが空文字の場合
.Caption = "┃" ' │ ├ wOBJ に "┃" を格納
If XX <= 9 Then ' │ ├◇ グリッド位置が9以下の場合(右端ではない)
If fRandom(2, 1) = 1 Then .Caption = "┣" ' │ │└▼ 取得乱数が1だった場合 >> wOBJ に "┃" を格納
End If ' │ │
If XX >= 2 Then ' │ ├◇ グリッド位置が2以上の場合(左端ではない)
If GrMasu(XX - 1, YY).Caption = "┣" Then ' │ │└▼ 左隣が "┣" だった場合
.Caption = "┫" ' │ │ └ wOBJ に "┫" を格納
End If ' │ │
End If ' │ │
Else ' │ □ 処理スイッチが空文字以外の場合(何かが入っている)
.ForeColor = RGB(255, 0, 0) ' │ └ wOBJ のForeColorを赤にする (vbRed)と表記しても良い
End If ' │
End If ' │
'----------------------------------------------- ' │
' メッセージ ' │
'----------------------------------------------- ' │
If XX = -3 Then ' ├◆引数XXが-3(メッセージ)の場合
.BorderStyle = 1 ' │├ wOBJ の枠線あり
.Name = "Label_Msg" ' │├ wOBJ のオブジェクト名
.Top = 9 ' │├ wOBJ のオブジェクトy位置
.Left = 6 ' │├ wOBJ のオブジェクトx位置
.Height = 30 ' │├ wOBJ の縦幅
.Width = 336 ' │├ wOBJ の横幅
.TextAlign = 2 ' │├ wOBJ のキャプションを中央揃え
.Font.Name = "MS Pゴシック" ' │├ wOBJ のフォント変更
.Font.Size = 11 ' │├ wOBJ のフォントサイズ
.SpecialEffect = 3 ' │├ wOBJ の枠線演出
.Caption = Msg(0) ' │├ wOBJ の表示メッセージ
Exit Sub ' │└ この処理を抜ける
End If ' │
'----------------------------------------------- ' │
' 選択(▼) ' │
'----------------------------------------------- ' │
If XX = -1 Then ' ├◆引数XXが-1(選択)の場合
.Name = "Label_Select" ' │├ wOBJ のオブジェクト名
.Caption = "▼" ' │├ wOBJ に "▼" を格納
.Top = 42 ' │├ wOBJ のオブジェクトy位置
.Left = BaseXX + (SelPos - 1) * 28 ' │└ wOBJ のオブジェクトx位置
End If ' │
'----------------------------------------------- ' │
' 正解(〇) ゴール ' │
'----------------------------------------------- ' │
If XX = -2 Then ' ├◆引数XXが-2(正解)の場合
.Name = "Label_Goal" ' │├ wOBJ のオブジェクト名
.Caption = "〇" ' │├ wOBJ に "〇" を格納
.Top = 354 ' │├ wOBJ のオブジェクトy位置
.Left = BaseXX + (GolPos - 1) * 28 ' │└ wOBJ のオブジェクトx位置
End If ' │
'----------------------------------------------- ' │
' ラベル共通処理(メッセージ以外適用) ' │
'----------------------------------------------- ' │
.BackStyle = 0 ' ├ wOBJ の背景透明化
.Height = BaseSz ' ├ wOBJ の縦幅
.Width = BaseSz ' ├ wOBJ の横幅
.Font.Name = "MS UI Gothic" ' ├ wOBJ のフォント変更
.Font.Size = 28 ' ├ wOBJ のフォントサイズ
.Font.Bold = True ' ├ wOBJ の太字設定
End With ' └ With終端
End Sub
'--------------------------------------------------------------------
' 指定ミリ秒待機サブルーチン
'
' 引数 待機したいミリ秒
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub WaitMSecond(ms As Integer)
Dim ReStartTime As Single '【変数定義】処理再開時間
ReStartTime = Timer + ms / 1000 ' 午前0時からの経過秒 + 引数(ミリ秒)
Do While Timer < ReStartTime ' ■ ループ始端(午前0時からの経過秒が処理再開時間より小さい間/繰り返し)
DoEvents ' ├ 制御をシステムに譲渡
Loop ' └ ループ終端
End Sub
'--------------------------------------------------------------------
' 最大値と最小値を指定した乱数取得ファンクション
'
' 引数 dMax : 取得乱数の最大値
' dMin : 取得乱数の最小値
'
' 戻値 乱数
'
'--------------------------------------------------------------------
Private Function fRandom(dMax As Integer, dMin As Integer)
fRandom = Int((dMax - dMin + 1) * Rnd + dMin) ' 最小~最大値の間の値を乱数を用いて返答する
End Function
いつもよりコードも短い気がする…
コメントが長いだけで消したらかなり短いと思います。
(2025/09/04 乱数取得を変更、以前のソースのコピペでミスってました!)
ゲームを動かしてみよう!
コードをコピペし終わったら実際にゲームを動かしてみましょう。
(1)プロジェクトウィンドウの「UserForm1」をダブルクリックします。するとフォームが表示されます。
(2)再生ボタンをクリックするとゲームが動くハズです!

上手く動かない場合は、同テーマの過去記事「Excel(VBA)で簡単なゲームを作る」の「動かないんだけど!?(怒)」を参考に原因を探ってみましょう。落ち着いて確認してみてください。
おわりに
これでゲームそのものは動くハズですが…操作方法の説明を忘れてました。
再生ボタンを押してフォームが表示されたら、キーボードの矢印キーの左右でスタート地点を選択します。
矢印キーの下を押すと線をたどってゴールに向かっていきます。
〇記号を目指しましょう!
スペースキーを押すとリトライできます。
で、次回以降のお話…
今回は作業量を減らすために、画像ではなく文字で線を描き、オブジェクトの生成をほとんどコード内で行いました。そのため、オブジェクトの設定(プロパティの設定)の分だけコードが長くなっています。
コードの長さの割に難易度はそこまで高くないですが、どちらかといえば考え方(アルゴリズム)が大事なコードになっています。また、これまでとは違った構文が幾つか登場しています。
ですので、解説記事ではそのへんを含めて記事化できたらいいなと思っています。というわけで、また次の機会にお会いできればうれしいです!
ここからはオススメ記事の紹介です。
システム系の勉強したいなーって方にはコチラがオススメです。
関連記事を以下にまとめてます!(↓)
「読むとゲームができるマガジン」もオススメです。
Unityのお話もありますが、Excelである程度のゲームは作れますよ(↓)