
ゲームのスコア表示をカラカラカラ~っと演出する
いきなりですが次の画像をご覧ください。右上に「スコア」があります。
現在1750点。次に倒した敵機の点数が100点なら1850点になります。

この表示「1750」から「1850」にパッと変わるのもアリなんですけど、ゲームや場面においては徐々に1850点に近づいていく表示の仕方もあります。
例えばこんな場面…
ステージクリア時のシールド残量がボーナス点として加算されます。
シールド残量1メモリにつき〇〇点が画面中央とスコア欄に加算されます。

今回はこの「カラカラ加算」演出について記事にまとめました。
この記事で言う「カラカラ加算」とは、スコアが一気に表示されるのではなく、小刻みに積みあがっていく演出のことです。
例えば680点を獲得した時に680点と一気に表示するのではなく、カラカラ等の効果音と共に徐々に680点に迫っていきます。プレイヤーは「まだ増えてるぞ」という快感を味わえる…そんなやつです。
パッと表示されるのが悪いワケじゃないですよ。
ただ、カラカラ加算がハマるシーンがあるんです。
こんなの作りました!
「カラカラ加算」の快感を楽しむ(?)ために、Excel(VBA)でこんなの作ってみました。サクッと作れるのがVBAの良いところですね。

Option Explicit
Dim TagScore As Long '【変数定義】目標となる点数
Dim CreScore As Long '【 〃 】処理中の表示点数
Dim WaitCt As Integer '【 〃 】点数表示切替ミリ秒
Dim myDir As String '【 〃 】効果音のフォルダパス
'--------------------------------------------------------------------
' フォーム初期化時
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub UserForm_Initialize()
Call ResetProc ' リセット処理
End Sub
'--------------------------------------------------------------------
' リセットボタンのクリック時
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Btn_Reset_Click()
Call ResetProc ' リセット処理
End Sub
'--------------------------------------------------------------------
' リセット処理
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub ResetProc()
TagScore = 0 ' 初期化:目標となる点数
CreScore = 0 ' 初期化:処理中の表示点数
WaitCt = 100 ' 初期化:点数表示切替ミリ秒
Lbl_score.Caption = 0 ' 初期化:ユーザーフォームのLbl_score
myDir = ActiveWorkbook.Path & "\Sound\se01.mp3" ' 効果音ファイルのパスを取得
End Sub
'--------------------------------------------------------------------
' 効果音再生サブルーチン
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub SEPlay()
WMP1.Controls.stop ' 停止
WMP1.Url = myDir ' 再生する音楽ファイルを指定
WMP1.Controls.Play ' 再生
End Sub
'--------------------------------------------------------------------
' 指定ミリ秒待機サブルーチン
'
' 引数 待機したいミリ秒
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub WaitMSecond(ms As Integer)
Dim ReStartTime As Single '【変数定義】処理再開時間
ReStartTime = Timer + ms / 1000 ' 午前0時からの経過秒 + 引数(ミリ秒)
Do While Timer < ReStartTime ' ■ ループ始端(午前0時からの経過秒が処理再開時間より小さい間/繰り返し)
DoEvents ' ├ 制御をシステムに譲渡
Loop ' └ ループ終端
End Sub
Btn_Add_1、Btn_Add_2、Btn_Add_3をクリックした時に動作するイベントプロシージャについては後述します。
パターン1:固定値のカウントアップ
では、0から10までカラカラ加算してみます。
ここではAdd[1]ボタンをクリックします。

良い感じですね。
いきなり10と表示されるのではなくカウントアップしていきます。
冒頭で例に挙げたシールド残量ボーナスの考え方と同じですね。
コードはこんな感じです。
'--------------------------------------------------------------------
' 加算ボタンのクリック時 (パターン1)
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Btn_Add_1_Click()
CreScore = Lbl_score.Caption ' 現在の表示点数を取得
TagScore = TagScore + InpScore.Value ' 目標となる点数にユーザーフォームのInpScoreを加算
'
Do While True ' ■ ループ
CreScore = CreScore + 1 ' ├ 処理中の表示点数 +1
Lbl_score.Caption = CreScore ' ├ 処理中の表示点数をユーザーフォームに表示
Call SEPlay ' ├ 効果音を再生
' │
If CreScore < TagScore Then ' ├◆ 処理中の表示点数が目標となる点数より少ない場合
Call WaitMSecond(WaitCt) ' │├ 点数表示切替ミリ秒まで待機
Else ' │◆ 処理中の表示点数が目標となる点数以上の場合
Lbl_score.Caption = TagScore ' │├ 目標となる点数をユーザーフォームに表示
Exit Do ' │└ このループを抜ける
End If ' │
Loop ' └ ループ終端
End Sub画面表示されている点数が目標値(画面表示されている点数と入力された点数の合計)になるまでループします。1回ループする度に画面表示されている点数+1のカウントアップを行います。
しかし、10回とか20回なら固定値をカウントアップでいいのですが、これが100回とか200回になると時間が掛かります。数字が増えて行く快感より待ち時間の長さが気になります。
パターン2:桁を見て加算値を変更!
487を表示する場合を考えてみます。
先程の考え方では487回もカウントアップします。
時間かかりそう、待ってられません。
そこでAdd[2]ボタンをクリックします。

最初は100の位の+100を4回、次に10の位が+50の1回した後に+10を3回、最後に1の位の+1を7回処理しています。
(1の位も+5をひとつ挟んだ方が良さそうですね…)
'--------------------------------------------------------------------
' 加算ボタンのクリック時 (パターン2)
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Btn_Add_2_Click()
Dim wVal As Long '【変数定義】ループ中に加算する点数
Dim wScr As Long '【変数定義】表示されている点数と目標となる点数の差
CreScore = Lbl_score.Caption ' 現在の表示点数を取得
TagScore = TagScore + InpScore.Value ' 目標となる点数にユーザーフォームのInpScoreを加算
'
Do While True ' ■ ループ
wScr = TagScore - CreScore ' ├ 表示されている点数と目標となる点数の差を算出
If wScr >= 100 Then ' ├◆ 差が100以上の場合
wVal = 100 ' │├ 加算する点数を100にする
ElseIf wScr >= 50 Then ' │◆ 差が50以上の場合
wVal = 50 ' │├ 加算する点数を50にする
ElseIf wScr >= 10 Then ' │◆ 差が10以上の場合
wVal = 10 ' │├ 加算する点数を10にする
ElseIf wScr >= 1 Then ' │◆ 差が1以上の場合
wVal = 1 ' │├ 加算する点数を1にする
Else ' │◆ それ以外の場合
wVal = 0 ' │└ 加算する点数を0にする
End If ' │
' │
CreScore = CreScore + wVal ' ├ 表示されている点数にループ中に加算する点数を加える
Lbl_score.Caption = CreScore ' ├ 目標となる点数をユーザーフォームに表示
Call SEPlay ' ├ 効果音を再生
' │
If CreScore < TagScore Then ' ├◆ 処理中の表示点数が目標となる点数より少ない場合
Call WaitMSecond(WaitCt) ' │├ 点数表示切替ミリ秒まで待機
Else ' │◆ 処理中の表示点数が目標となる点数以上の場合
Lbl_score.Caption = TagScore ' │├ 目標となる点数をユーザーフォームに表示
Exit Do ' │└ このループを抜ける
End If ' │
Loop ' └ ループ終端
End Subパターン1とやってることはほぼ同じですが、画面表示されている点数と目標値を比較して100以上の差があれば+100を、50以上の差があれば+50をしています。
これなら待ち時間が減りますね。やりたいことができました!
ということで、いかがでしたでしょうか…と終わると思った?
このパターンだと寂しいことが起こったりするんですよ…
例えば500が加算される場合はどうなるでしょう?

切りのいい数字だと少し寂しいな…
パターン3:桁見て演出加算
パターン2のコードを実行すると500という切りのいい数字だと+100の5回だけで終わってしまいます。
例えば、ゲームセンター等のコインゲームや、カジノのあるRPGで大当たりをした時、切りのいい数字の大当たりだと一瞬でカラカラ加算が終わっちゃうのは寂しいです。
ということでAdd[3]ボタンをクリックします。

切りのいい数字でも1の桁が回っているのが見えます。
コードはこんな感じです。
'--------------------------------------------------------------------
' 加算ボタンのクリック時 (パターン3)
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Btn_Add_3_Click()
Dim wVal As Long '【変数定義】ループ中に加算する点数
Dim wScr As Long '【変数定義】表示されている点数と目標となる点数の差
CreScore = Lbl_score.Caption ' 現在の表示点数を取得
TagScore = TagScore + InpScore.Value ' 目標となる点数にユーザーフォームのInpScoreを加算
Do While True ' ■ ループ
wScr = TagScore - CreScore ' ├ 表示されている点数と目標となる点数の差を算出
If wScr >= 200 Then ' ├◆ 差が200以上の場合
wVal = 100 ' │├ 加算する点数を100にする
ElseIf wScr >= 100 Then ' │◆ 差が100以上の場合
wVal = 50 ' │├ 加算する点数を50にする
ElseIf wScr >= 20 Then ' │◆ 差が20以上の場合
wVal = 10 ' │├ 加算する点数を10にする
ElseIf wScr >= 10 Then ' │◆ 差が10以上の場合
wVal = 5 ' │├ 加算する点数を5にする
ElseIf wScr >= 1 Then ' │◆ 差が1以上の場合
wVal = 1 ' │├ 加算する点数を1にする
Else ' │◆ それ以外の場合
wVal = 0 ' │└ 加算する点数を0にする
End If ' │
' │
CreScore = CreScore + wVal ' ├ 表示されている点数にループ中に加算する点数を加える
Lbl_score.Caption = CreScore ' ├ 目標となる点数をユーザーフォームに表示
Call SEPlay ' ├ 効果音を再生
' │
If CreScore < TagScore Then ' ├◆ 処理中の表示点数が目標となる点数より少ない場合
Call WaitMSecond(WaitCt) ' │├ 点数表示切替ミリ秒まで待機
Else ' │◆ 処理中の表示点数が目標となる点数以上の場合
Lbl_score.Caption = TagScore ' │├ 目標となる点数をユーザーフォームに表示
Exit Do ' │└ このループを抜ける
End If ' │
Loop ' └ ループ終端
End Subコードの中身を詳しく見るとわかるのですが、画面表示されている点数と目標値を比較して200以上の差があれば+100を、100以上の差があれば+50…といった様に差と加算する点数に「あそび」(ゆとり、余裕)があるんです。
この「あそび」に関してはお好みのバランス調整をすると良いでしょう。
効果音も堪能したい!
記事中はGIFなので効果音が鳴っていません。
これだと快感も半減、効果音ありでご覧になりたい場合はyoutubeでご覧ください!
おわりに
いかがでしたでしょうか?
場面によってはパッと変更した方がスッキリしますが、スコア表示に演出を加えるならこんな手段があるよ!というお話でした。
コードの中で変数WaitCtは100になっています。これは100ミリ秒で数字が切り替わるようになっているという意味です。この値の調整も場面や好みにあわせることができます。
もう少し工夫をするなら最初はWaitCtを小さめにし、徐々にWaitCtを大きくしていくことでスコアがどこまで増えるかのドキドキ感を演出することも可能です。
たかが点数表示、されど点数表示。サンプルのコードはVBAですが、他のプログラム言語であっても考え方は同じです。
ちょっとした演出で雰囲気が変わるのでお試しあれ!
また次の記事でお会いできると嬉しいです。
ここからはオススメ記事の紹介です。
もうちょっと勉強したいなーって方にはコチラがオススメです。
これらの勉強に使えそうな関連記事は以下にまとめてます!(↓)
「読むとゲームができるマガジン」もオススメです。
まずは身近なソフトで作ってみるのもアリかも!
Excelでもある程度のゲームは作れますよ(↓)