メインコンテンツへスキップ
見出し画像

Excel(VBA)のゲームでBGMを流したい

    こんにちは「つけらっとゲームス」プログラム担当のとちです。

    これまで何度かExcel(VBA)で動く簡単なゲームの作り方を記事にしていますが、皆さんのお役に立っているでしょうか?

    上記のマガジンにまとめているExcel(VBA)のゲームは、なるべくデフォルト状態で動くように作っていました。Excelを開いて手軽に作れて前準備の少ないモノです。

    なのでゲームとしては物足りないかもしれません。
    やっぱりBGMがないと寂しいんですよね…

    そこで今回はExcel(VBA)でBGMを流す方法です!
    やり方は複数あるんですけど、導入も運用もなるべく簡単にできるものを選んでみました。

    なお、この記事のスクショ等について、わたしのPCに入っているMicrosoft office Home and Business 2016でスクショを撮りました。

    ですので微妙に表示が異なる可能性がありますが、デスクトップ版のExcelであれば、開発に使用するVBA(Microsoft Visual Basic for Applications)は同じで作業内容も変わりません。Microsoft365のExcelでも動作します。


    こんなのを作ります!

    とりあえず大きなユーザーフォームを作りました。
    そのフォーム上に複数のボタンと黒四角が2つあります。黒四角は「Windows Media Player」っぽいですね。

    画像

    テスト用にBGMを2つ、SE(サウンドエフェクト)を2つ用意しています。
    ボタンを押すことによってBGMまたはSEが鳴るようになっています。

    「++ボタン」を押下すると音量に+10、「+ボタン」なら+1です。
    同様に「--ボタン」だと-10、「-ボタン」だと-1されます。

    メディアプレイヤーのボタンを使わずに、BGMとSEを好きなタイミングかつ好きな音量で再生(または停止)できるようになればゲームに反映させるのは簡単です。メディアプレイヤーは最後に非表示にすればいいでしょう。

    ということで、一緒に作ってみましょう。

    まず作業に入る前にExcelの環境を確認しましょう。
    以下の記事の「Excelの準備」をご覧ください。

    「.xlsm形式」のファイルにできましたか?
    メニューバーに「開発」が表示されるようになっていますか?

    次はテスト用にBGMとSEを、それぞれ2つ用意します。
    いつもお世話になっている魔王魂さんなら、どちらも揃うのでありがたいです。もちろん皆さんが使いたい音楽ファイルでも構いません。

    ただし、今回はmp3形式をご用意ください。
    wavでもいいのですがこの記事のコードではmp3にしています。コードを改造できそうな方はwavでもいいです。

    wma、aac、midiでも大丈夫みたいですが、わたしの方で試していないので余裕がある方は試してみてね!

    作った「.xlsm形式」のファイル名を下のスクショと同じにしてください。

    画像

    同じようにSoundフォルダも作っておきましょう。
    んで、その中身は下のスクショ!

    画像

    用意したBGMとSEのファイルをSoundフォルダに入れておきます。
    ファイル名もスクショに揃えてくださいね。


    ユーザーフォームを作る

    Excelの開発準備と、素材が揃ったら最初にやるべきことはこれ!
    「挿入」>「ユーザーフォーム」でユーザーフォームを準備します。

    画像

    画面にユーザーフォームが表示されたら下のスクショのように、右下の白い四角をドラッグして適当なサイズに拡大してあげてください。

    画像

    コントロールの追加

    次の作業として、ユーザーフォームに各オブジェクトを配置していくのですが「Windows Media Player」をフォームに配置するためには、ちょっとした前準備が必要となります。

    「ツール」>「その他のコントロール」を選びます。

    画像

    または、ツールボックスの上で右クリックをすると以下のようにメニューが表示されるので「その他のコントロール」を選んでください。

    画像

    「コントロールの追加」というサブウィンドウが表示されます。
    この中から「Windows Media Player」を探してチェックマークを入れてください。

    画像

    すると、ツールボックスがこんな感じに変化します。

    画像

    各オブジェクトの配置

    次は各オブジェクトを配置していきます。
    ツールボックスで作成したいオブジェクトのアイコンを選んで、フォーム上でドラッグします。

    オブジェクトのサイズ・位置・設定等は、この次に調整します。
    なので、あんまり気にしなくていいです。
    とりあえず大体の位置に対応するオブジェクトを配置していきましょう。

    画像

    各オブジェクトのプロパティ修正

    てきとーに配置したボタンが、綺麗に並んでいないと気になる方もいると思いますので、そろそろプロパティを修正していきます。

    フォームに配置したオブジェクトをクリックすると、左下のプロパティ欄にクリックしたオブジェクトのプロパティが表示されます。

    画像

    ここで大事なのがオブジェクト名です。
    以下、各オブジェクトのプロパティ欄を並べますのでオブジェクト名だけは同じモノに揃えて作業しましょう。

    オブジェクトの大きさは Height・Width の値で表されています。
    位置は Top・Left です。

    このあたりの値を揃えると各オブジェクトが綺麗に並ぶでしょう。
    ちなみにボタンに表示されている「BGM 1 Play」は Caption です。
    Font などのプロパティはお好みで大丈夫です!

    では、コマンドボタンのプロパティ欄を並べていきますよ。
    どうしてもスクショが小さくなっちゃうので拡大してご覧ください。

    画像
    BGM1Play / BGM2Play
    画像
    BGMVolpp / BGMVolp / BGMVolm / BGMVolmm
    画像
    BGMStop / SE1Play / SE2Play
    画像
    SEVolpp / SEVolp / SEVolm / SEVolmm

    以下はコマンドボタン以外のオブジェクトなので表示が異なります。
    BGMVolLbl と SEVolLbl は音量を数字で表しているラベルです。
    WMP1 と WMP2 はメディアプレイヤーです。

    画像
    BGMVolLbl / SEVolLbl / WMP1 / WMP2

    WMP1 と WMP2 の Visible を True にするとプログラムを実行した時にメディアプレイヤーが表示されます。ゲームに使用する時は False にすると遊んでいる人には見えないようにできます。

    次のスクショはユーザーフォームのプロパティです。
    特に変更する場所はありませんが、念のために貼っておきますね。

    画像
    UserForm1

    それぞれのオブジェクトのプロパティを設定したら次の作業に移ります!


    プログラムコードをコピペ

    オブジェクト配置をしてプロパティを設定しましたが、現時点ではそのオブジェクトは何していいか決まっていない状態です。

    各オブジェクトに役割を持たせるべくプログラムコードを書きます。まずは何も考えずに準備したコードをコピペします。

    ではコードを入力する画面を表示します。
    「BGM 1 Play」ボタンをダブルクリックします。

    画像

    すると、以下のような画面が表示されると思います。
    いま表示されている2行のコードは一旦消しちゃってください。

    画像

    コードを入力する部分が綺麗になったら以下をコピペします。

    Option Explicit
    Dim myDir As String                                                             '【変数定義】ファイルパス
    Dim wmp1V As Integer                                                            '【  〃  】WindowsMediaPlayer1 音量
    Dim wmp2V As Integer                                                            '【  〃  】WindowsMediaPlayer2 音量
    Dim StpSW As Integer                                                            '【  〃  】BGMループスイッチ [0]Loopしない [1]する
    
    '===========================================================
    '
    '   ユーザーフォーム 初期化時
    '
    '===========================================================
    Private Sub UserForm_Initialize()
    
        myDir = ActiveWorkbook.Path                                                 ' ファイルパスを取得
        myDir = myDir & "\Sound\"                                                   ' ファイルパスに音楽データが入っているフォルダ名を追加
        wmp1V = WMP1.settings.volume                                                ' WindowsMediaPlayer1 音量を取得
        wmp2V = WMP2.settings.volume                                                ' WindowsMediaPlayer2 音量を取得
        VolUpdate                                                                   ' 音量変更時 総合処理
        
        StpSW = 0                                                                   ' BGM Stop を押下した場合はBGMループさせない
    
    End Sub
    
    '===========================================================
    '
    '   ユーザーフォーム 終了時
    '
    '===========================================================
    Private Sub UserForm_Terminate()
    
        StpSW = 0                                                                   ' BGMループさせない
        WMP1.Controls.stop                                                          ' WindowsMediaPlayer1 停止
        WMP2.Controls.stop                                                          ' WindowsMediaPlayer2 停止
    
    End Sub
    
    '===========================================================
    '
    '   BGM1 Play ボタンを押下
    '
    '===========================================================
    Private Sub BGM1Play_Click()
        
        WMP1.Controls.stop                                                          ' WindowsMediaPlayer1 停止
        WMP1.Url = myDir & "BGM1.mp3"                                               ' WindowsMediaPlayer1 に BGM1のファイルパスを入れる
        WMP1.Controls.Play                                                          ' WindowsMediaPlayer1 再生
        
        StpSW = 1                                                                   ' BGMをループさせる
    
    End Sub
    
    '===========================================================
    '
    '   BGM2 Play ボタンを押下
    '
    '===========================================================
    Private Sub BGM2Play_Click()
        
        WMP1.Controls.stop                                                          ' WindowsMediaPlayer1 停止
        WMP1.Url = myDir & "BGM2.mp3"                                               ' WindowsMediaPlayer1 に BGM2のファイルパスを入れる
        WMP1.Controls.Play                                                          ' WindowsMediaPlayer1 再生
        
        StpSW = 1                                                                   ' BGMをループさせる
    
    End Sub
    
    '===========================================================
    '
    '   BGM Stop ボタンを押下
    '
    '===========================================================
    Private Sub BGMStop_Click()
        
        StpSW = 0                                                                   ' BGM Stop を押下した場合はBGMループさせない
        WMP1.Controls.stop                                                          ' WindowsMediaPlayer1 停止
        
    End Sub
    
    '===========================================================
    '
    '   BGM 音量++ ボタンを押下
    '
    '===========================================================
    Private Sub BGMVolpp_Click()
    
        wmp1V = wmp1V + 10                                                          ' WindowsMediaPlayer1 音量+10
        VolUpdate                                                                   ' 音量変更時 総合処理
    
    End Sub
    
    '===========================================================
    '
    '   BGM 音量+ ボタンを押下
    '
    '===========================================================
    Private Sub BGMVolp_Click()
    
        wmp1V = wmp1V + 1                                                           ' WindowsMediaPlayer1 音量+1
        VolUpdate                                                                   ' 音量変更時 総合処理
    
    End Sub
    
    '===========================================================
    '
    '   BGM 音量-- ボタンを押下
    '
    '===========================================================
    Private Sub BGMVolmm_Click()
    
        wmp1V = wmp1V - 10                                                          ' WindowsMediaPlayer1 音量-10
        VolUpdate                                                                   ' 音量変更時 総合処理
    
    End Sub
    
    '===========================================================
    '
    '   BGM 音量- ボタンを押下
    '
    '===========================================================
    Private Sub BGMVolm_Click()
    
        wmp1V = wmp1V - 1                                                           ' WindowsMediaPlayer1 音量-1
        VolUpdate                                                                   ' 音量変更時 総合処理
    
    End Sub
    
    '===========================================================
    '
    '   SE1 Play ボタンを押下
    '
    '===========================================================
    Private Sub SE1Play_Click()
    
        WMP2.Controls.stop                                                          ' WindowsMediaPlayer2 停止
        WMP2.Url = myDir & "SE1.mp3"                                                ' WindowsMediaPlayer2 に SE1 のファイルパスを入れる
        WMP2.Controls.Play                                                          ' WindowsMediaPlayer2 再生
    
    End Sub
    
    '===========================================================
    '
    '   SE2 Play ボタンを押下
    '
    '===========================================================
    Private Sub SE2Play_Click()
    
        WMP2.Controls.stop                                                          ' WindowsMediaPlayer2 停止
        WMP2.Url = myDir & "SE2.mp3"                                                ' WindowsMediaPlayer2 に SE2 のファイルパスを入れる
        WMP2.Controls.Play                                                          ' WindowsMediaPlayer2 再生
    
    End Sub
    
    '===========================================================
    '
    '   SE 音量++ ボタンを押下
    '
    '===========================================================
    Private Sub SEVolpp_Click()
    
        wmp2V = wmp2V + 10                                                          ' WindowsMediaPlayer2 音量+10
        VolUpdate                                                                   ' 音量変更時 総合処理
       
    
    End Sub
    
    '===========================================================
    '
    '   SE 音量+ ボタンを押下
    '
    '===========================================================
    Private Sub SEVolp_Click()
    
        wmp2V = wmp2V + 1                                                           ' WindowsMediaPlayer2 音量+1
        VolUpdate                                                                   ' 音量変更時 総合処理
    
    End Sub
    
    '===========================================================
    '
    '   SE 音量-- ボタンを押下
    '
    '===========================================================
    Private Sub SEVolmm_Click()
    
        wmp2V = wmp2V - 10                                                          ' WindowsMediaPlayer2 音量-10
        VolUpdate                                                                   ' 音量変更時 総合処理
    
    End Sub
    
    '===========================================================
    '
    '   SE 音量- ボタンを押下
    '
    '===========================================================
    Private Sub SEVolm_Click()
    
        wmp2V = wmp2V - 1                                                           ' WindowsMediaPlayer2 音量-1
        VolUpdate                                                                   ' 音量変更時 総合処理
    
    End Sub
    
    '===========================================================
    '
    '   音量変更時 総合処理
    '
    '===========================================================
    Private Sub VolUpdate()
    
        If wmp1V > 100 Then wmp1V = 100                                             ' WindowsMediaPlayer1 音量が100を上回っている場合 >> 100 にする
        If wmp1V < 0 Then wmp1V = 0                                                 '    〃      音量が  0を下回っている場合 >>   0 にする
     
        If wmp2V > 100 Then wmp2V = 100                                             ' WindowsMediaPlayer2 音量が100を上回っている場合 >> 100 にする
        If wmp2V < 0 Then wmp2V = 0                                                 '    〃           音量が  0を下回っている場合 >>   0 にする
      
        WMP1.settings.volume = wmp1V                                                ' WindowsMediaPlayer1 音量変更
        WMP2.settings.volume = wmp2V                                                ' WindowsMediaPlayer2 音量変更
    
        BGMVolLbl = "" & wmp1V                                                      ' BGM音量ラベルの表示変更
        SEVolLbl = "" & wmp2V                                                       '  SE音量ラベルの表示変更
    
    End Sub
    
    '===========================================================
    '
    '   WindowsMediaPlayer WMP1 再生状態の変化時
    '
    '===========================================================
    Private Sub WMP1_PlayStateChange(ByVal NewState As Long)
    
        If StpSW = 0 Then Exit Sub                                                  ' StpSWが0の場合 >> このサブルーチンを抜ける
        If NewState = 1 Or NewState = 8 Then WMP1.Controls.Play                     ' 再生状態の変化による戻値が 1(停止) or 8(音楽終了) の場合 >> 再び再生する
    
    End Sub
    
    画像

    コピペが終わったら、上のスクショのようにUserForm1をダブルクリックします。するとユーザーフォームが表示されます。

    ユーザーフォームが表示されたら画面上の再生ボタンを押しましょう。
    これでプログラムが動き始めます。

    上手く動かない場合は、以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「動かないんだけど!?(怒)」を参考に原因を探ってみましょう。落ち着いて確認してみてください。

    エラー原因は多分オブジェクトかファイル名が間違っていると思います…

    ※ 以下のメッセージボックスが表示されたら?
    Windows Media Player を使用すると、このような警告が表示されますが、今回は自分で追加したものですから「OK」をクリックして大丈夫です。

    画像

    「BGM 1 Play」ボタンをクリックすると音楽が再生されますよね?
    「BGM 2 Play」ボタンをクリックすると別な音楽が再生されますよね?
    「SE 1 Play」や「SE 2 Play」をクリックすると効果音が鳴りますよね?

    これでExcel(VBA)で作ったゲームに音楽を流せるようになりますよ!


    おわりに

    長い記事を読んで、更に作業も一緒にされた方は本当にお疲れ様です。
    ある程度プログラムに慣れ親しんだ方はコード内のコメントを見ていただければ何をしているか理解できると思います。

    が、まだ慣れていない方にとっては難しいかもしれません。
    なので、次回予告!

    次回はコードの中身の解説をしたいと思います。
    更に、せっかく音楽を流せるようになったので以前作った「神経衰弱」に実装してみようと思います。


    以降はオススメ記事の紹介です。
    「読むとゲームができる」記事は、このマガジンにまとめています。

    情報関連の勉強をしている方、復習したい方にはコチラ!
    基本情報技術者試験のアルゴリズムとか苦手!って方にもオススメです。



    あなたへのおすすめ