
二重ループを覚えて欲しい!
つけらっとゲームスは青森でインディーゲームを作っているサークル。この時期になると雪の便りが届いたりします。寒くなりましたね。
これまでも何度か記事にしているのでご存知の方もいらっしゃると思いますが、ゲームを作る以外にも専門学校で非常勤講師をやっています。
春から教え始めた今年度の学生も、今ではごく普通に使っているループ処理(繰り返し処理)ですが、ループの中にループがある二重ループになった途端に苦手だな~と感じる学生が多く見られます。
苦手だとしても使うことで理解が進み、慣れていくものではあるんですが、理解の最初で躓くと投げ出したくなります。
ここで投げ出してしまうのはもったいない。
というわけで、今回は二重ループについてお話したいと思います。
二重ループ苦手民にオススメの記事になっていると思います。
ゲームを作っている方、これから作りたい方も二重ループ(もっと重なっている多重ループ)はプログラムを組む上でよく使うので、復習として読んでくださいね。
九九(掛け算)の表をつくる
情報科の教科書や問題集なんかによく出てくる例題が九九です。
もしかしたら見たことある方もいらっしゃるでしょう。二重ループを説明するにはちょうどいい例題なんですよね。
Excelのワークシート「九九」に1×1=1 から 9 × 9 = 81 を表示するプログラムを作成します。

ユーザーフォームにボタンを1つ用意しました。これを押すとプログラムが動き始めます。

ボタンを押すと九九の式と答えが表示されました。
Excelのシートなのでセルに対して順番に文字を入力しても同じことはできるんですが、これを81個も入力するのは手間がかかります。
まずはアルゴリズム
システムを作る上でまず最初にやることは、目的を達成するためには、どんな考え方でアプローチするかを思い描くことです。
慣れてくると無意識でやっちゃう部分ですが、慣れないうちは段階を追った方がいいでしょう。
というわけでアルゴリズム(問題解決の手順)を考えます。
九九は「かけられる数」と「かける数」が存在します。
「かけられる数」は算数の時間だと「〇〇の段」と言われたりしますよね。
この「〇〇の段」に「かける数」である1~9を順番に乗算します。
乗算が9までの終わったら「〇〇の段」は1つ増えます。
「〇〇の段」が9まで終わったら九九の表ができます。
ここまでの文章で9まで終わったらが2度出てきてますね。
別の言い方をすると9まで繰り返すです。これが2重ループです。
文章にするとこんな感じですが、文章だと回りくどい、難しい。
なので図表で表しましょう。
次にフローチャート
次の画像はアルゴリズムをフローチャートにしたものです。
9まで繰り返す分岐が2つあるのがわかります。
…が矢印と線がごちゃごちゃして面倒臭そうに見えますね。

そこで、ループ記号を用いた場合のフローチャートにします。

ループ記号を使うと二重ループしているのがよくわかりますね。
第1ループではかけられる数(〇〇の段)を、第2ループではかける数をカウントアップしています。
処理の順番としては第2ループ内が9まで処理をしたら、第1ループが1つ進むといった感じですね。
いよいよコード化
今度はこれをVBAのコードにします。
躓くところは人によって違っていて、アルゴリズム(考え方)→フローチャート(流れ図)まではできたのに、コード化が苦手という学生もいます。
わたし個人でいうとコードを先に書いちゃったりするので、このへんの感覚を説明するのが難しいのですが…フローチャートからコードにするときは以下のようにすると、ある程度できちゃうので参考になるといいなぁ~。

上の画像のように1つの記号をそれぞれコード化して順番に置いていくと自動的にコードになります。点線枠の中身をそのまま使ってみましょう。
Private Sub CommandButton1_Click()
Dim XX As Integer '【 〃 】横(列)カウンタ
Dim YY As Integer '【 〃 】縦(行)カウンタ
Dim Ans As Integer '【 〃 】乗算結果
Dim wTxt As String '【 〃 】文字列編集用の変数
For XX = 1 To 9 ' ■[第1ループ]横(列)方向のループ
For YY = 1 To 9 ' ├ ◆[第2ループ]縦(行)方向のループ
Ans = XX * YY ' │ ├ Ansの乗算
wTxt = XX & "×" & YY & "=" & Ans ' │ ├ YYとXXを使用して掛け算の式を文字列化
Sheets("九九").Cells(XX, YY).Value = wTxt ' │ ├ ワークシート"九九"に式を格納する
Next YY ' │ └[第2ループ]終端
Next XX ' └[第1ループ]終端
End Sub計算結果を格納するワークシートが"九九"なので、その部分を追記。
あとはテキストをセルに格納する前に文字列変数に入れてますが、それ以外は点線枠のものをそのまま使っています。
こうするとアルゴリズム→フローチャート→コード化がスムーズ!
資格試験対策の問題集なんかだと、ここで説明が終わっちゃうんですけど、もう1つ工夫して二重ループの便利さを感じましょう。
というわけで、For文の条件式をすこし変更してみましょう…
Private Sub CommandButton1_Click()
Dim XX As Integer '【 〃 】横(列)カウンタ
Dim YY As Integer '【 〃 】縦(行)カウンタ
Dim Ans As Integer '【 〃 】乗算結果
Dim wTxt As String '【 〃 】文字列編集用の変数
For XX = 1 To 12 ' ■[第1ループ]横(列)方向のループ
For YY = 1 To 12 ' ├ ◆[第2ループ]縦(行)方向のループ
Ans = XX * YY ' │ ├ Ansの乗算
wTxt = XX & "×" & YY & "=" & Ans ' │ ├ YYとXXを使用して掛け算の式を文字列化
Sheets("九九").Cells(XX, YY).Value = wTxt ' │ ├ ワークシート"九九"に式を格納する
Next YY ' │ └[第2ループ]終端
Next XX ' └[第1ループ]終端
End Sub
1から9までの部分を、1から12までに変更しました。
たったこれだけの変更で…

12×12までの計算結果が表示されます。
このようにグリッド状の何かを処理する時はすごく便利なんです!
ドット絵を表示してみる
九九の表の説明を聞いていると…
「なんか面倒臭いし、他に何に使える?」なんて思っちゃいますよね。
なので他の例題も用意しました。
2D見下ろしタイプのRPGやSRPGを作る時にExcelで編集したCSVファイルを読んでマップを描画する…みたいな処理を以前作ったことがありましてね、これを少し簡略化したものを例にしますね。
次のスクショをご覧ください。
Excelのワークシート「Data」タブに数字が並んでいます。

「0」のところは白として、「1」のところを黒とします。
ユーザーフォームにコマンドボタンを1つ作って、このボタンを押したら条件に則って「Image」タブにドット絵を描きます。
グリッド状のデータを読んで何らかの処理をするなら二重ループですよ!
Private Sub CommandButton1_Click()
Dim XXMx As Integer '【変数定義】列の最後尾
Dim YYMx As Integer '【 〃 】行の最後尾
Dim XX As Integer '【 〃 】列カウンタ
Dim YY As Integer '【 〃 】行カウンタ
Dim ClrSW As Integer '【 〃 】色スイッチ
Dim Clr As Long '【 〃 】色
XXMx = (Sheets("Data").Cells(1, Columns.Count).End(xlToLeft).Column) ' ワークシート"Data"の列の最後尾を取得
YYMx = (Sheets("Data").Cells(Rows.Count, 1).End(xlUp).Row) ' ワークシート"Data"の行の最後尾を取得
For XX = 1 To XXMx ' ■[第1ループ]列方向のループ
For YY = 1 To YYMx ' ├ ◆[第2ループ]行方向のループ
ClrSW = Sheets("Data").Cells(YY, XX).Value ' │ ├ YYとXXを使用してセルの内容を色スイッチとして取得
If ClrSW = 0 Then Clr = vbWhite ' │ ├ ▼色スイッチが 0 の場合 >> 色変数に 白 を格納
If ClrSW = 1 Then Clr = vbBlack ' │ ├ ▼色スイッチが 1 の場合 >> 色変数に 黒 を格納
Sheets("Image").Cells(YY, XX).Interior.Color = Clr ' │ ├ ワークシート"Image"のセルの色を変更
Next YY ' │ └[第2ループ]終端
Next XX ' └[第1ループ]終端
Sheets("Image").Activate ' ワークシート"Image"を表示する
End Sub
コードの中をみるとFor文の中に、もうひとつFor文がありますよね。
これはもうお馴染みの二重ループです。九九コードとほぼ同じ構造です。
第1ループでは横方向(列)にカウンタが進んでいきます。
第2ループでは縦方向(行)にカウンタが進んでいます。
ワークシート"Data"の中身を読んで、そのセルには何色を表示すればいいのかを判断しています。結果は…日の丸の旗です!

なんか寂しいですね。やっぱり真ん中は赤にしたい。
実は、このように改良したいと思うことが大事だったりします。
練習問題を解いて満足するのではなく、より良くしたいと思うことが理解を深めるんですよ!
ではデータを以下のように変更します。
真ん中の丸のところを「1」ではなく「2」にしました。

引き続き、プログラムもちょっとだけ変更します。
Private Sub CommandButton1_Click()
Dim XXMx As Integer '【変数定義】列の最後尾
Dim YYMx As Integer '【 〃 】行の最後尾
Dim XX As Integer '【 〃 】列カウンタ
Dim YY As Integer '【 〃 】行カウンタ
Dim ClrSW As Integer '【 〃 】色スイッチ
Dim Clr As Long '【 〃 】色
XXMx = (Sheets("Data").Cells(1, Columns.Count).End(xlToLeft).Column) ' ワークシート"Data"の列の最後尾を取得
YYMx = (Sheets("Data").Cells(Rows.Count, 1).End(xlUp).Row) ' ワークシート"Data"の行の最後尾を取得
For XX = 1 To XXMx ' ■[第1ループ]列方向のループ
For YY = 1 To YYMx ' ├ ◆[第2ループ]行方向のループ
ClrSW = Sheets("Data").Cells(YY, XX).Value ' │ ├ YYとXXを使用してセルの内容を色スイッチとして取得
If ClrSW = 0 Then Clr = vbWhite ' │ ├ ▼色スイッチが 0 の場合 >> 色変数に 白 を格納
If ClrSW = 1 Then Clr = vbBlack ' │ ├ ▼色スイッチが 1 の場合 >> 色変数に 黒 を格納
If ClrSW = 2 Then Clr = vbRed ' │ ├ ▼色スイッチが 2 の場合 >> 色変数に 赤 を格納
Sheets("Image").Cells(YY, XX).Interior.Color = Clr ' │ ├ ワークシート"Image"のセルの色を変更
Next YY ' │ └[第2ループ]終端
Next XX ' └[第1ループ]終端
Sheets("Image").Activate ' ワークシート"Image"を表示する
End Sub
どこが変わったか解りますか?
答:「If ClrSW = 2 Then Clr = vbRed」という行が増えています。
ワークシート"Data"に「2」が入っていたら赤を取得するという意味です。
これで動かすと…

一気に日の丸っぽくなりました。
もう、お分かりだと思います。
この例題は「2D見下ろしタイプのRPGやSRPGのマップを作る処理」を簡略化して説明すると前述したとおりでして、
いまはデータの数字を見て色を切り替えているだけですが、色ではなく画像(スプライトやテクスチャ)にするとデータからマップを作り出すことも可能となります。
「1」だったら海、「2」だったら草原、「3」だったら森林…
マップにレイヤーを持たせるなら三重ループでZZというカウンタを作れば、その上に更に画像を重ねることも可能です。
あらら、もうマップをデータ化できそう!!
ちなみに3DダンジョンRPGのマップでも同じような処理を用いて描画していました。ちょっと見やすく色をつけたり、記号を入れ替えていますが、ほぼこのまま使用できます。

結論!
つまり何を言いたいのか…
最初は難しいし面倒臭いと感じるかもしれませんが、実際に使う場面は多々あるということです。慣れたらそこまで面倒臭くない(ハズ)です。
このあたりはコンピュータ系の資格試験でもよく出てくる箇所なので勉強として覚えようとすると難しいんですが、何に使うのかを理解していれば、いつのまにか覚えていると思いますよ。大丈夫!
というわけで今日はここまでです。
また次の記事でお会いできるのを楽しみにしております!
「二重ループは理解したけど、もうちょっとシステム系の勉強したいなー」って方にはコチラがオススメです。
関連記事を以下にまとめてます!(↓)
「勉強はいいから、ゲームを作る方法を教えて!」って方はコチラ!
「読むとゲームができるマガジン」もオススメです。
Unityのお話もありますが、Excelである程度のゲームは作れますよ(↓)