
Excel(VBA)で「干支タイピング」を作る!
こんにちは「つけらっとゲームス」プログラム担当のとちです。
今回はExcel(VBA)でちょっとしたタイピングゲームを作ります!
2026年最初の記事ですからね、ちょっとだけ新年っぽい雰囲気があるゲームを作ってみましょう。この記事を読みながら皆さんもゲームを作ってみませんか?

皆さんは十二支を最初から最後まで言えますか?
子(ね)丑(うし)寅(とら)卯(う)辰(たつ)巳(み)
午(うま)未(ひつじ)申(さる)酉(とり)戌(いぬ)亥(い)
2026年は午年(うまどし)ですね。漢字で書くと馬じゃなくて午です。
なぜ「午年」は「馬年」と書かないのでしょうか?
十二支は時や方角を表すものだそうで、覚えやすくするために後から動物が割り当てられたそうです…今回の本題から離れちゃうので、このあたりの詳しいお話は以下の記事をご覧ください。勉強になりました!
というわけで、

馬だとダメで、

午だとOKなタイピングゲーム(半分クイズっぽいですね)を作ります。
お子様向けにひらがなで「うま」と打ってもOKにしていますが大人な皆様はちゃんと漢字で入力しましょう!
いつものようにユーザーフォームを挿入、各オブジェクトを作っていき最後にソースを丸ごとコピーする流れで作成していきます。
なお、この記事のスクショについて、わたしのPCに入っているMicrosoft office Home and Business 2016でスクショを撮りました。
なので表示が微妙に異なる可能性があります。しかしデスクトップ版のExcelであれば、開発に使用するVBA(Microsoft Visual Basic for Applications)は同じで作業内容も変わりません。Microsoft365のExcelでも動作します。
それと、開発前に環境を整える必要があります。
以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「Excelの準備」を参照してVBAを使えるようにしておきましょう。
また「Excel(VBA)で〇〇を作る」記事は以下のマガジンにまとめています。
他のゲームの解説もあるので、マガジンの中からお好みのゲームを探してくださいね!
開発環境を準備する
「Excelの準備」を参照してVBAを使えるようにできましたか?
それでは任意のフォルダに拡張子「xlsm」のファイルを作りましょう。

上のスクショでは「十二支タイピング.xlsm」という名前で作っていますが、名前は他のモノでも構いません。ただし拡張子は「xlsm」です。
その他に「image」というフォルダを作っておきましょう。こちらにはゲーム内で使用する画像ファイルを入れます。
必要な素材を準備する
画像を見て何年なのかを入力するゲームなので画像が必要となります。もちろん自分で作れる(描ける)方は、ご自分で用意して構いません。
今回は皆様ご存知の「いらすとや」さんから素材をお借りします。
いつもお世話になっております…
「十二支」でイラストを検索すると、打ち出の小槌を振る干支キャラクターが出てきました。今回はコチラをゲーム素材として使用します。

十二支の他にネコがいますね…ネコにも登場して貰いましょう。
ダウンロードしてそのままですと画像ファイル名が長いので変更します。

子から順にネコまで、eto01、eto02、eto03…と形式が統一されているファイル名に変更します。
更にひと手間。なるべくデフォルト状態のExcel(VBA)のユーザーフォームで作りたい。となるとpng形式は使用できません。画像のサイズも統一した方がいいでしょう。

というわけで、各画像800×800ピクセルのjpeg形式にしました。
Photoshop、Gimpあたりの画像編集ソフトを使用できる方はそちらで編集していただいて構いません。
Windows付属のペイントでも十分可能ですが、やったこと無い方や、自信が無い方は以前の記事にある「必要な素材を準備する」をご覧くださいね。
最後にタイトル画像を用意します。ファイル名は「title.jpg」としました。
こちらも800×800のjpeg形式です。お好みの画像を使用して構いません。

ここまでの作業で編集した画像は.xlsmファイルと同じ場所にあるimageフォルダに入れておきます。

imageフォルダの中身は以下のような状態になっていればOKです。

答えデータを作る
素材が揃ったらExcel側の作業をしましょう。
タイピングゲームなのでプレイヤーの文字入力が正しいものか判断する必要があります。いまのうちに答えを作っておきます。

.xlsmファイルのワークシートに、上記のスクショを真似て答えを入れておきます。漢字が上手く表示されない場合は以下からコピペしてください。
子(ね)丑(うし)寅(とら)卯(う)辰(たつ)巳(み)
午(うま)未(ひつじ)申(さる)酉(とり)戌(いぬ)亥(い)
猫(ねこ)
それとシートの名前を「EtoData」にしておきましょう。
画面作成の下準備
まずはメニューバーの「開発」→ 「Visual Basic」を選びます。

画面を作る際に最初にやるべきことは下のスクショの様に「挿入」→「ユーザーフォーム」でまっさらなユーザーフォームを準備することです。

今回は標準モジュールも使います。
先程同様に「挿入」→「標準モジュール」を選んでください。

すると画面がこのようになります。
標準モジュールのModule1の中身を先に書いちゃいます。

いまは何も考えずに上のスクショのオレンジ枠の部分に、下のコードを丸々コピペしてください。
Option Explicit
Public STtime As Date '【変数定義】ゲーム開始タイム
Public DPtime As Date '【 〃 】次の処理タイム(1秒後)
'--------------------------------------------------------------------
' OnTimeStart タイマー処理開始 (1秒後の処理予約)
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Sub OnTimeStart()
EtoTyping.GameTime.Caption = Format(Now() - STtime, "h:nn:ss") ' 現在時から開始時を引き算してゲーム表示タイムを算出
DPtime = Now() + TimeValue("00:00:01") ' 次の処理タイム(1秒後)を算出
Call Application.OnTime(DPtime, "OnTimeStart") ' 1秒後の処理予約
End Sub
'--------------------------------------------------------------------
' OnTimeStop タイマー停止 (1秒後の処理予約を取り消し)
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Sub OnTimeStop()
On Error Resume Next ' エラーが出ても止まらずに次へ進む
Call Application.OnTime(DPtime, "OnTimeStart", , False) ' 予約されている処理をキャンセル
On Error GoTo 0 ' 通常のエラー処理に戻す
End Subコピペが終わったら画面の左側、プロジェクトという枠の中にあるUserForm1(オレンジ枠で青くフォーカスされている)をダブルクリックします。

すると、こんな画面に変化します。
下のスクショのオレンジ文字のとおり、フォームのサイズを大きくしておきます。またツールボックスが無い場合は青文字の指示に従ってください。

次はユーザーフォームのプロパティを修正していきます。
プロパティ欄は下のスクショのオレンジ枠の部分です。

この部分を以下のように変更します。
ただしHeightとWidthは値が違っていても良いです。これはユーザーフォームをドラッグで大きくしたため、多分綺麗な数字にはなっていません。

ここからはユーザーフォームに各オブジェクト(ボタンなど)を作り、そのオブジェクトのプロパティを調整していく作業になります。似たような作業が続きますので飽きてきますが…頑張って進めてください。
問題画像を表示する
まずは作業終了時の画面をお見せしましょう。こんな感じになります。

今回使うコントロールは以下の通りです。
ラベルを作る場合は、ツールボックスの「A」を選んでください。
コマンドボタンを作る場合は丸四角の「ab」を選ぶといった具合です。

ツールを選んだらユーザーフォーム上でクリック、そのままドラッグします。クリックした地点から作成されてドラッグで大きさを調整します。
あとでプロパティ欄で細かい調整ができるので大体の大きさで構いません。
では早速作っていきます。まずは全体図でいうと「ネズミ」画像が表示されているイメージから作っていきましょう。ツールボックスのイメージを選び大体の場所をクリック、大体の大きさになるようドラッグしましょう。
画面上に四角のイメージオブジェクトができたらプロパティを設定します。
下のスクショと同じようにします。

Pictureを選ぶと、Picture欄の右側に[…]ボタンが表示されます。
ここを選ぶと画像選択できるようになります。
後でプログラムで自動で読み込むようにしますが、作成中にわかりやすいように何らかの画像を入れておくと良いでしょう。
問題数とタイム表示
ネズミの画像ができたら、その画像の上に何問目かを表す「QuestionNo」とタイム表示をする「GameTime」を作ります。この2つはラベルです。

ツールボックスから「ラベル」を選んで2つ作ります。
それぞれのプロパティは以下の通りです。同じように設定しましょう。
ただし、フォントや色についてはお好みで構いません!

ゲーム中のUI作成
次はネズミ画像の下の入力欄と決定ボタン、ないボタンを作ります。
入力欄は「テキストボックス」を使います。
決定ボタンとないボタンは「コマンドボタン」です。

大体の位置と大きさで作ったら以下のプロパティの様に設定します。

タイトル画面とゲームオーバー画面
面倒な作業も、あともう少しです。
ここではタイトル画面とゲームオーバー画面(ゴール画面)を作ります。
作る順番としてはタイトル画像、ゲームオーバー画像、ゲームオーバーテキスト、スタートボタンの順番が良いでしょう。
画像やオブジェクトの重なり順の関係を考えて、この順番で作っていますが後でも変更できますし、プログラム側でもある程度は制御しています。

タイトル画像とゲームオーバー画像はイメージです。
ゲームオーバーテキストはラベル。スタートボタンはコマンドボタンです。
プロパティ欄は以下のように設定します。
※スクショが小さくなっちゃったのでお手数ですが拡大してご覧ください。

オブジェクトの重なりが気になったら…
前述通りオブジェクトの重なりは後からでも変更可能です。
もし思った通りの重なり順にならなかった場合は以下のようにします。
重なり順を変更したいオブジェクトをシングルクリックし選択状態にする。
メニューバーの「書式」→「順序」→「重なり位置の移動」をします。

コードをコピペする!
ここまで長い作業、お疲れ様でした。
あとは何も考えずにコードをコピペすれば完了です!
下のスクショの通り、何も無いあたりをダブルクリックします。

すると、次のようなスクショの画面が出てきます。
なんか2行のコードが出てきますが、これを全て消してください。

そして、次の長いコードを消した場所にコピペすれば作業完了です。
Option Explicit
Dim EtoImg(1 To 13) As Object '【配列定義】干支画像
Dim EtoSW(1 To 13) As Integer '【 〃 】干支画像出題スイッチ [0]未出題 [1]出題済
Dim AnsTxt(1 To 13, 1 To 2) As String '【 〃 】干支正解文字列
Dim AnsIx As Integer '【 〃 】干支正解位置index
Dim QuesNo As Integer '【 〃 】出題数 (10問でゴール)
'--------------------------------------------------------------------
' フォーム初期化時
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub UserForm_Initialize()
Dim ImgPath As String '【変数定義】干支画像のパス
Dim ImgDire As String '【 〃 】干支画像のフォルダパス
Dim iNo As String '【 〃 】干支画像のパス作成用カウンタ
Dim i As Integer '【 〃 】ループカウント
Randomize ' ランダム関数の初期化
ImgDire = ThisWorkbook.Path & "\Image\" ' 干支画像のフォルダパスを取得
For i = 1 To 13 ' ■ループ
iNo = i ' ├パス作成用カウンタを取得
If i <= 9 Then iNo = "0" & iNo ' ├◆ループカウンタが9以下の場合 >> パス作成用カウンタを2桁にする
ImgPath = ImgDire & "Eto" & iNo & ".jpg" ' ├干支画像のパスを生成
Set EtoImg(i) = LoadPicture(ImgPath) ' ├干支画像を読み込んで配列に格納
AnsTxt(i, 1) = Worksheets("EtoData").Cells(i, 1) ' ├干支正解文字列(漢字)
AnsTxt(i, 2) = Worksheets("EtoData").Cells(i, 2) ' ├干支正解文字列(かな)
Next i ' └ループ終端
EtoTyping.Height = 402 ' フォーム高
EtoTyping.Width = 396 ' フォーム幅
ImgTitle.Top = 6 ' タイトル画像 y位置
ImgTitle.Left = 6 ' タイトル画像 x位置
ImgGameOver.Top = 366 ' ゲームオーバー画像 y位置
ImgGameOver.Left = 450 ' ゲームオーバー画像 x位置
TxGameOver.Top = 444 ' ゲームオーバーText y位置
TxGameOver.Left = 450 ' ゲームオーバーText x位置
Btn_Start.Top = 318 ' スタートボタン y位置
Btn_Start.Left = 156 ' スタートボタン x位置
inpText.Visible = False ' 入力欄 非表示
Btn_Enter.Visible = False ' 決定ボタン 非表示
Btn_neko.Visible = False ' ないボタン 非表示
Btn_Start.Visible = True ' スタートボタン 表示
Btn_Start.ZOrder (0) ' スタートボタン 最前列へ
QuestionNo.BorderStyle = fmBorderStyleNone ' 出題数の枠線 非表示
GameTime.BorderStyle = fmBorderStyleNone ' タイムの枠線 非表示
TxGameOver.BorderStyle = fmBorderStyleNone ' ゲームオーバーTextの枠線 非表示
End Sub
'--------------------------------------------------------------------
' フォーム閉じた時
'
' 引数 Cancel 0以外でQueryCloseイベントが停止する
' CloseMode QueryClose発生原因
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
Call OnTimeStop ' タイマー処理を停止
End Sub
'--------------------------------------------------------------------
' スタートボタン クリック時
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Btn_Start_Click()
Dim i As Integer '【変数定義】ループカウンタ
QuesNo = 0 ' 出題数をクリア
ImgTitle.Left = 800 ' タイトル画像 を画面外へ
Btn_Start.Left = 800 ' スタートボタン を画面外へ
ImgGameOver.Left = 800 ' ゲームオーバー画像を画面外へ
TxGameOver.Left = 800 ' ゲームオーバーTextを画面外へ
inpText.Visible = True ' 入力欄 を表示
Btn_Enter.Visible = True ' 決定ボタン を表示
Btn_neko.Visible = True ' ないボタン を表示
Btn_Start.Visible = False ' スタートボタン を非表示
For i = 1 To 13 ' ■ループ
EtoSW(i) = 0 ' ├干支画像出題スイッチのクリア
Next i ' └ループ終端
Call GetNextQuestion ' 次の問題を取得
Module1.STtime = Now() ' ゲームスタート時を取得
Call OnTimeStart ' タイマー処理開始
End Sub
'--------------------------------------------------------------------
' 決定ボタン クリック時
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Btn_Enter_Click()
Dim okSW As Integer '【変数定義】正解スイッチ [0]不正解 [1]正解
Dim i As Integer '【 〃 】ループカウンタ
inpText.SetFocus ' 入力欄にカーソル移動
If AnsIx = 13 Then Exit Sub ' ■ AnsIx = 13(猫の場合)は「ない」が正解なので処理を抜ける
For i = 1 To 2 ' ■ ループ
If inpText.Value = AnsTxt(AnsIx, i) Then okSW = 1 ' ├ ◆入力欄と干支正解文字列(AnsIx)が同じなら正解スイッチに[1]を入れる
Next i ' └ ループ終端
If okSW = 1 Then ' ■ 正解の場合
inpText.Value = "" ' ├ 入力欄をクリア
If QuesNo >= 10 Then ' └ ◆ 出題数が10以上の場合
Call Rtn_GameOver ' ├ ゴール処理
Else ' ◆ 出題数が10以上ではない場合
Call GetNextQuestion ' └ 次の問題を取得
End If
End If
End Sub
'--------------------------------------------------------------------
' ないボタン クリック時 (ネコの場合のみ有効)
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Btn_neko_Click()
inpText.SetFocus ' 入力欄にカーソル移動
If AnsIx <> 13 Then Exit Sub ' ■ AnsIx <> 13(猫以外の場合)は無効なので処理を抜ける
If QuesNo >= 10 Then ' ■ 出題数が10以上の場合
Call Rtn_GameOver ' ├ ゴール処理
Else ' ■ 出題数が10以上ではない場合
Call GetNextQuestion ' └ 次の問題を取得
End If
End Sub
'--------------------------------------------------------------------
' Rtn_GameOver ゴール処理
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub Rtn_GameOver()
Dim wTx As String '【変数定義】表示文字列の編集用
Call OnTimeStop ' タイマー停止
wTx = "ゴール!" & Chr(13) & Chr(13) ' 表示文字列の編集
wTx = wTx & "Time : " & GameTime.Caption ' 表示文字列の編集
TxGameOver.Caption = wTx ' ゴールとタイム表示
ImgGameOver.Top = 6 ' ゲームオーバー画像のy位置
ImgGameOver.Left = 6 ' ゲームオーバー画像のx位置
TxGameOver.Top = 84 ' ゲームオーバーTextのy位置
TxGameOver.Left = 6 ' ゲームオーバーTextのx位置
Btn_Start.Visible = True ' スタートボタンを表示
Btn_Start.ZOrder (0) ' スタートボタンを最前列に移動
Btn_Start.SetFocus ' スタートボタンにカーソル移動
Btn_Start.Caption = "もう1回!" ' スタートボタンを「もう1回!」に変更
inpText.Visible = False ' 入力欄 非表示
Btn_Enter.Visible = False ' 決定ボタン 非表示
Btn_neko.Visible = False ' ないボタン 非表示
Btn_Start.Top = 318 ' スタートボタンのy位置
Btn_Start.Left = 156 ' スタートボタンのx位置
End Sub
'--------------------------------------------------------------------
' GetNextQuestion 次の問題を取得
'
' 引数 なし
'
' 戻値 なし
'
'--------------------------------------------------------------------
Private Sub GetNextQuestion()
AnsIx = fRandom(13, 1) ' 干支正解位置indexをランダムに取得
Do While True ' ■ ループ
If EtoSW(AnsIx) = 0 Then Exit Do ' ├ ◆ 干支画像出題スイッチがZero(未出題)の場合 ループを抜ける
AnsIx = AnsIx + 1 ' ├ 干支正解位置index +1
If AnsIx >= 14 Then AnsIx = 1 ' ├ ◆ 干支正解位置index が14以上の場合 >> 干支正解位置indexを 1 にする
Loop ' └ ループ終端
Image1.Picture = EtoImg(AnsIx) ' 干支イメージを表示
EtoSW(AnsIx) = 1 ' 干支画像出題スイッチ [1]出題済 にする
QuesNo = QuesNo + 1 ' 出題数 +1
QuestionNo.Caption = "問題" & QuesNo ' 出題数を画面表示
End Sub
'--------------------------------------------------------------------
' fRandom 最大値と最小値を指定した乱数取得ファンクション
'
' 引数 dMax 乱数取得範囲の最大値
' dMin 乱数取得範囲の最小値
'
' 戻値 乱数取得範囲内の値
'
'--------------------------------------------------------------------
Function fRandom(dMax As Integer, dMin As Integer)
fRandom = Int((dMax - dMin + 1) * Rnd + dMin) ' 最小~最大値の間の値を乱数を用いて返答する
End Function
コピペが終わったら次のスクショのプロジェクト欄にある①EtoTypingをダブルクリックし、ツールバーにある②再生ボタンを押すと動きます。

止める場合は表示されているゲーム画面右上の✕ボタンまたは、②再生ボタンの隣の隣、■の停止ボタンを押します。
うまく動かない場合でも落ち着いて…
以前の記事の「動かないんだけど!?(怒)」を参照してください。
原因のほとんどは「オブジェクト名が間違っている」だと思います。
あそびかた
画面に表示されている画像を見て何年かを入力します。
「うま」や「ひつじ」などは、そのまま入力しても大丈夫ですが「ねずみ」は「ねどし」なので「ね」と入力したら「決定」ボタンを押してください。
正解であれば次の画像が表示されます。
間違っていると先へは進めません。
注意点としては「ネコ」が表示された場合です。
「ねこどし」は無いので、「ない」ボタンを押さないと次に進めません。
10問がランダムで出題されます。
ひらがな入力だと15~25秒くらいを目指しましょう。漢字なら40~60秒くらいになるかなぁ?
マウスを使わなくてもキーボードで完結します。
各ボタンには良い具合にフォーカスが当たる様になっているので、エンターキーを押すと次に進むようになっているハズです。
ただ単にフォーカスを移動するにはTabキーを押します。これは「ネコ」の場合に使用すると良いでしょう。
続きます!
これで簡単ではありますが、ゲームそのものは動いているハズです。
単純なゲームなので改良したい部分が出てくるかもですね。
その想いはプログラムコードを書き換えると実装可能です。しかし、書き換えるためにはプログラムの中身を理解しないといけません。
というわけで次回以降は応用編として機能追加するか、もしくはコードの解説をするか…とにかく、もうちょっと続きます。
長い記事を読んでくださりありがとうございます。
そして実作業された方はお疲れ様でした!
また次の記事でお会いしましょう!
▼続きはコチラです!
ここからはオススメ記事の紹介です。
システム系の勉強したいなーって方にはコチラがオススメです。
関連記事を以下にまとめてます!(↓)
「読むとゲームができるマガジン」もオススメです。
今回のゲームとは別のゲームが色々あります。
Unityのお話もありますが、Excelである程度のゲームは作れますよ(↓)