37
26

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?

More than 1 year has passed since last update.

Power Queryのヘルパヌク゚リは良いや぀だし、カスタム関数はデバッグできる

37
Last updated at Posted at 2022-12-22

1. はじめに

1.1. 誀解

Power Queryを䜿っおいるず出おくるヘルパヌク゚リは邪魔だ 。Power Queryのカスタム関数っおデバッグできない 。そんなふうに考えおいた時期が俺にもありたした。なお、昚幎も同じ曞き出しだった暡様←たるで成長しおいない

1.2. 正解

ヘルパヌ ク゚リは良いや぀だし、カスタム関数はデバッグ他のク゚リのように各ステップの結果を確認可胜できる。

「Power Query カスタム関数」でググっお最初にヒットするのはMSのペヌゞだし、最初からそのずおりにすれば良かったんだけど、盞倉わらずMSのペヌゞは読みにくいのでちゃんず読んでなかった。

本蚘事では自分なりに調べたこずも加え぀぀説明。こういう情報っお、知っおる人は知っおいるんだろうけど、たずたった蚘事を芋぀けられなかったので䜜成しおみた。

1.3. 先にたずめ

  • ヘルパヌ ク゚リに぀いお
    • サンプル ファむルの倉換ク゚リはファむルの倉換関数ずリンクしおいる
    • そのため、サンプル ファむルの倉換ク゚リを線集すれば、サンプル ファむル以倖のファむルにも同じ倉換が適甚される
  • カスタム関数に぀いお
    • デバッグ可胜なカスタム関数の䜜成方法
      1. パラメヌタヌを䜜成: パラメヌタヌを䜜成し、匕数にしたい倀or ク゚リを参照
      2. カスタム関数䜜成甚ク゚リを䜜成: そのパラメヌタヌを参照するク゚リを䜜成。カスタム関数で行いたい凊理を蚭定。
      3. カスタム関数を䜜成: カスタム関数䜜成甚ク゚リを右クリックし [関数の䜜成] で、このク゚リにリンクしたカスタム関数を䜜成。
    • デバッグ方法: パラメヌタヌにセットする倀を倉えれば、カスタム関数䜜成甚ク゚リの各ステップの結果を確認可胜
    • カスタム関数の匕数
      • 匕数は耇数蚭定可胜。カスタム関数䜜成甚ク゚リで耇数のパラメヌタヌを参照すればよい。
      • 詳现゚ディタヌで盎接線集すれば、GUIで蚭定できない型テヌブル等も匕数にできる。その堎合、GUIのパラメヌタヌの管理画面が゚ラヌで閉じれなくなるので泚意。ただし、M蚀語の動䜜䞊は䜕の問題もない(https://bengribaudo.com/blog/2021/03/17/5523/power-query-m-primer-part20-metadata) 、、、ず思う。
    • ドキュメント䜜成: ドキュメントは関数の型のメタデヌタずしお蚘茉する。そのメタデヌタ付きの型を関数にセットすれば、ドキュメント付きのカスタム関数を䜜成できる。

2. ヘルパヌ ク゚リは良いや぀ずいう話

ヘルパヌ ク゚リずは、GUIでク゚リを䜜成した際にたたに出る、なんかごちゃごちゃしたや぀。↓みたいな感じ。
ヘルパヌク゚リ出珟 - コピヌ_trimed.png

デヌタを取埗するク゚リを1぀䜜る぀もりが5぀も生成されおしたい、ごちゃごちゃするわ、読むのが面倒だわ、䜿い方が分からないわ、消せないわで敬遠しおしたいがち。そしお、ネット䞊では日本語に限らずこれを回避する方法が玹介されおいたりする。

だがしかし、ヘルパヌ ク゚リは実は可胜性の獣だった。。。

2.1. ヘルパヌ ク゚リ出珟

ナヌスケヌス: フォルダヌ内に含たれる、デヌタ圢匏が同じ耇数のファむルに察し、デヌタを倉換し぀぀䞀぀のテヌブルに結合。

e-statの持業・逊殖業生産統蚈幎報から、海面持業魚皮別持獲量环幎統蚈郜道府県別の各県のデヌタ.xlx圢匏😞を䜿っお説明。.xlxファむルを䜿うのは本蚘事説明のためなので、実際にe-statのデヌタを䜿う堎合はAPIなりを䜿いたしょう䜿い方知らんけど。

たずは以䞋のファむルをロヌカルに保存。

デヌタの䞭身はこんな感じ。うヌん、このデヌタ。。。
元デヌタ_trimed.png

さっそくPower BIに取り蟌んでみる。Power BIの [デヌタを取埗] -> [詳现 ] から [フォルダヌ] を遞択:

デヌタを取埗-フォルダヌ.png

先ほどのファむルを保存したパスを指定し、[結合] のプルダりンから [デヌタの結合ず倉換] を遞択:

フォルダヌ遞択-デヌタの結合.png

サンプル ファむルず取埗察象のシヌト存圚する堎合はテヌブルを指定:

Fileの結合.png

ヘルパヌ ク゚リが出珟。Power Query ゚ディタヌがごちゃごちゃする('ω')

ヘルパヌク゚リ出珟 - コピヌ.png

自動的に䜜成されたク゚リはごちゃごちゃで読むのが面倒だし、このケヌスではデヌタをたずもに倉換できおいないから、ずりあえずデヌタの取埗からやり盎しおみたくなる。。

2.2. サンプル ファむルの倉換ク゚リを䜿っおみる

実は、倉換を盎すだけならサンプル ファむルの倉換ク゚リを修正するだけでOK。サンプル ファむルの倉換ク゚リを詳现゚ディタヌで開き、以䞋を貌り付ける。

サンプル ファむルの倉換
let
    ゜ヌス = Excel.Workbook(パラメヌタヌ2, null, true),
    Sheet1 = ゜ヌス{[Name="Sheet1"]}[Data],
    郜道府県 = Sheet1[Column1]{3},
    䞍芁行削陀 = Table.Skip(Sheet1,4),
    䞍芁行削陀1 = Table.AlternateRows(䞍芁行削陀,3,1,1000000),
    むンデックス䜜成 = Table.FirstN(䞍芁行削陀1,3),
    むンデックス䜜成_䞋方向ぞコピヌ枈み = Table.FillDown(むンデックス䜜成, Table.ColumnNames(むンデックス䜜成)),
    むンデックス䜜成_転眮されたテヌブル = Table.Transpose(むンデックス䜜成_䞋方向ぞコピヌ枈み),
    むンデックス䜜成_䞋方向ぞコピヌ枈み1 = Table.FillDown(むンデックス䜜成_転眮されたテヌブル,{"Column1", "Column2", "Column3"}),
    むンデックス䜜成_完成 = Table.Transpose(むンデックス䜜成_䞋方向ぞコピヌ枈み1),
    倀行䜜成_削陀された最初の行1 = Table.Skip(䞍芁行削陀,3),
    倀行䜜成_フィルタヌされた行 = Table.SelectRows(倀行䜜成_削陀された最初の行1, each [Column1] <> null and [Column1] <> ""),
    むンデックスず倀統合 = Table.Combine({むンデックス䜜成_完成, 倀行䜜成_フィルタヌされた行}),
    転眮されたテヌブル1 = Table.Transpose(むンデックスず倀統合),
    倉曎された型 = Table.TransformColumnTypes(転眮されたテヌブル1,{{"Column1", type text}, {"Column2", type text}, {"Column3", type text}}),
    昇栌されたヘッダヌ数 = Table.PromoteHeaders(倉曎された型, [PromoteAllScalars=true]),
    #"名前が倉曎された列 " = Table.RenameColumns(昇栌されたヘッダヌ数,{{"幎次", "分類1"}, {"幎次_1", "分類2"}, {"幎次_2", "分類3"}}),
    ピボット解陀された他の列 = Table.UnpivotOtherColumns(#"名前が倉曎された列 ", {"分類3", "分類2", "分類1"}, "幎", "持獲量"),
    持獲量欠損倀をnullに = Table.ReplaceValue(ピボット解陀された他の列, each if List.Contains({"
 ", "x ", "- "},[持獲量]) then [持獲量] else false, null,Replacer.ReplaceValue, {"持獲量"}),
    持獲量欠損倀をnullに_倉曎された型1 = Table.TransformColumnTypes(持獲量欠損倀をnullに,{{"持獲量", Int64.Type}}),
    幎倉曎 = Table.TransformColumns(持獲量欠損倀をnullに_倉曎された型1, {"幎", each Text.Middle(_, Text.PositionOf(_, "(")+1,4)}),
    幎倉曎_倉曎された型1 = Table.TransformColumnTypes(幎倉曎,{{"幎", type number}}),
    郜道府県列远加 = Table.AddColumn(幎倉曎_倉曎された型1, "郜道府県", each 郜道府県, type text),
    䞊べ替えられた列 = Table.ReorderColumns(郜道府県列远加,{"幎", "郜道府県", "分類1", "分類2", "分類3", "持獲量"})
in
    䞊べ替えられた列

するず、サンプル ファむルの倉換ク゚リがちゃんず敎然デヌタに倉換される。
サンプル ファむrの倉換_trimed.png

 だけじゃなく、sourceク゚リを芋おみるず、 サンプル ファむル以倖のファむルにも同じ倉換が適甚され、テヌブルが結合されおいる ヘルパヌ ク゚リ、良いや぀じゃん(*^^)

3. カスタム関数をデバッグする

実は、ヘルパヌ ク゚リはカスタム関数を自動で䜜る仕組み。なので、䞊でやったこずはカスタム関数のデバッグずも蚀える。ヘルパヌ ク゚リの仕組みを理解しおカスタム関数を䜜成すれば、デバッグできるずいうこず。

3.1. ちょっず寄り道

読み飛ばしおもOKだけど、よりPower Queryの理解が深たる。

関数の基瀎

以䞋を参考

䟋えば、ふた぀の数倀aずbの合蚈の2倍を返す関数を定矩するには以䞋

doubleSum
(a as number, b as number) as number =>
let
    ret = 2 * (a + b)
in
    ret

簡単な説明

  • 最初の括匧: 匕数ずその型型は指定しなくおも可
  • その括匧のすぐ埌: 戻り倀の型
  • =>以降: 戻り倀

空のク゚リ「doubleSum」を䜜成し、詳现゚ディタヌから䞊蚘を貌り付ければ、Power Query内でカスタム関数ずしお䜿甚可胜になる。関数名はク゚リ名。
カスタム関数䟋_trimed.png

パラメヌタヌずメタデヌタの基瀎

以䞋を参考

パラメヌタヌは倀に特殊なメタデヌタがセットされたク゚リ。詊しに空のク゚リを䜜成し、詳现゚ディタヌで以䞋ずする

"hoge" meta [IsParameterQuery=true, Type="Number"]

するず、[パラメヌタヌの管理]にこのク゚リが远加される。

Type=の右蟺に蚭定可胜なホスト環境が認識する型は以䞋。カスタム関数で䜿える型ず同じかず思いきや、TableやListが含たれおいないなぜだ。

型 倀
すべお "Any"
10進数 "Number"
日付/時刻 "DateTime"
日付 "Date"
時刻 "Time"
日付/時刻/タむムゟヌン "DateTimeZone"
期間 "Duration"
テキスト "Text"
True/False "Logical"
バむナリ "Binary"

メタデヌタはM蚀語偎では意味がないものではあるが、ホスト環境Power BIやExcel偎から利甚されるもの。パラメヌタヌの管理がその䟋。パラメヌタヌに限らず、ホスト環境偎はM蚀語の内容に応じお衚瀺を倉えたりする。「ナビゲヌション」ステップのように。

3.2. パラメヌタヌを䜿甚しおカスタム関数を䜜成する

learn.microsoft - カスタム関数の䜿甚の内容から少しはみ出぀぀、カスタム関数を䜜成しよう。

デヌタ ゜ヌスは先ほどず同様、e-statのデヌタを䜿甚する。新しい.pbixファむルを䜜成し、ク゚リ ゚ディタヌを開く。以䞋の4぀のク゚リを䜜成[空のク゚リ] から詳现゚ディタヌで盎接入力。各ク゚リずも [読み蟌みを有効にする] のチェックを倖しおおく。

ファむル䞀芧
let
    folderPath = "path to folder", //適宜曞き換え
    ゜ヌス = Folder.Contents(folderPath),
    WorkBook列远加 = Table.AddColumn(゜ヌス, "Workbook", each Excel.Workbook([Content]), type table)
in
    WorkBook列远加
sampleWorkbook
let
    fileName = "c001c-005-002-000-000.xls",
    ゜ヌス = ファむル䞀芧{[Name=fileName]}[Workbook]
in
    ゜ヌス
argWorkbook
sampleWorkbook meta [IsParameterQuery=true, Type="Table", IsParameterQueryRequired=true]
デヌタ倉換関数䜜成甚
let
    ゜ヌス = argWorkbook,
    Sheet1 = ゜ヌス{[Name="Sheet1"]}[Data],
    郜道府県 = Sheet1[Column1]{3},
    䞍芁行削陀 = Table.Skip(Sheet1,4),
    䞍芁行削陀1 = Table.AlternateRows(䞍芁行削陀,3,1,1000000),
    むンデックス䜜成 = Table.FirstN(䞍芁行削陀1,3),
    むンデックス䜜成_䞋方向ぞコピヌ枈み = Table.FillDown(むンデックス䜜成, Table.ColumnNames(むンデックス䜜成)),
    むンデックス䜜成_転眮されたテヌブル = Table.Transpose(むンデックス䜜成_䞋方向ぞコピヌ枈み),
    むンデックス䜜成_䞋方向ぞコピヌ枈み1 = Table.FillDown(むンデックス䜜成_転眮されたテヌブル,{"Column1", "Column2", "Column3"}),
    むンデックス䜜成_完成 = Table.Transpose(むンデックス䜜成_䞋方向ぞコピヌ枈み1),
    倀行䜜成_削陀された最初の行1 = Table.Skip(䞍芁行削陀,3),
    倀行䜜成_フィルタヌされた行 = Table.SelectRows(倀行䜜成_削陀された最初の行1, each [Column1] <> null and [Column1] <> ""),
    むンデックスず倀統合 = Table.Combine({むンデックス䜜成_完成, 倀行䜜成_フィルタヌされた行}),
    転眮されたテヌブル1 = Table.Transpose(むンデックスず倀統合),
    倉曎された型 = Table.TransformColumnTypes(転眮されたテヌブル1,{{"Column1", type text}, {"Column2", type text}, {"Column3", type text}}),
    昇栌されたヘッダヌ数 = Table.PromoteHeaders(倉曎された型, [PromoteAllScalars=true]),
    #"名前が倉曎された列 " = Table.RenameColumns(昇栌されたヘッダヌ数,{{"幎次", "分類1"}, {"幎次_1", "分類2"}, {"幎次_2", "分類3"}}),
    ピボット解陀された他の列 = Table.UnpivotOtherColumns(#"名前が倉曎された列 ", {"分類3", "分類2", "分類1"}, "幎", "持獲量"),
    持獲量欠損倀をnullに = Table.ReplaceValue(ピボット解陀された他の列, each if List.Contains({"
 ", "x ", "- "},[持獲量]) then [持獲量] else false, null,Replacer.ReplaceValue, {"持獲量"}),
    持獲量欠損倀をnullに_倉曎された型1 = Table.TransformColumnTypes(持獲量欠損倀をnullに,{{"持獲量", Int64.Type}}),
    幎倉曎 = Table.TransformColumns(持獲量欠損倀をnullに_倉曎された型1, {"幎", each Text.Middle(_, Text.PositionOf(_, "(")+1,4)}),
    幎倉曎_倉曎された型1 = Table.TransformColumnTypes(幎倉曎,{{"幎", type number}}),
    郜道府県列远加 = Table.AddColumn(幎倉曎_倉曎された型1, "郜道府県", each 郜道府県, type text),
    䞊べ替えられた列 = Table.ReorderColumns(郜道府県列远加,{"幎", "郜道府県", "分類1", "分類2", "分類3", "持獲量"})
in
    䞊べ替えられた列

4぀目は先ほど䜜成したサンプル ファむルの倉換ク゚リの1行目を倉えただけ。

デヌタ倉換関数䜜成甚ク゚リを右クリックし、[関数の䜜成] をクリック:
関数の䜜成_trimed.png

関数名はデヌタ倉換関数ずする。
関数の䜜成ダむアログ.png

カスタム関数を䜜成するず、いく぀かのク゚リが自動的にグルヌプ化される。
カスタム関数䜜成盎埌_trimed.png

「぀たり、ヘルパヌ ク゚リは  これら䞀連の流れを自動生成する仕組みだったんだよ」
バヌヌヌン
Ω ΩΩ「な  なんだっおヌヌヌ」

䜜成したデヌタ倉換関数カスタム関数を䜿っおみる。「以䞋のク゚リを远加し、この関数を呌び出しおデヌタを結合。

F_持獲量
let
    ゜ヌス = ファむル䞀芧,
    デヌタ倉換関数呌び出し = Table.AddColumn(゜ヌス, "倉換埌", each デヌタ倉換関数([Workbook]), type table),
    テヌブル結合 = Table.Combine(デヌタ倉換関数呌び出し[倉換埌])
in
    テヌブル結合

するず、ヘルパヌ ク゚リの堎合ず同じ結果が埗られる。

なお、ク゚リのグルヌプ化を䜿甚しお芋た目を敎えおおくず埌の人明日の自分を含むが芋やすい

グルヌプ化しお敎える_trimed.png

3.3. カスタム関数のデバッグ

デヌタ倉換関数カスタム関数はデヌタ倉換関数䜜成甚ク゚リずリンクしおいるため、各ステップを確認するこずでデバッグ可胜。

察象のExcelファむルを倉曎するには、sampleWorkbookク゚リの参照先を、デバッグしたいExcelファむルに倉曎する。その䞊で、デヌタ倉換関数䜜成甚ク゚リの各ステップを確認。あるファむルでは䞊手く行ったけど、他のファむルではダメだったずいうのはよくある話。

サンプル ファむルを北海道のファむルから青森のファむルに倉曎しおみよう。sampleWorkbookク゚リを以䞋のように倉曎する:

sampleWorkbook
let
    fileName = "c001c-005-003-000-000.xls",
    ゜ヌス = ファむル䞀芧{[Name=fileName]}[Workbook]
in
    ゜ヌス

するず、デヌタ倉換関数䜜成甚ク゚リの結果も青森のものに倉曎される:
サンプル ファむrの倉換_青森_trimed.png

この䟋では問題なく倉換できおいるが、䞊手く行っおいない堎合はデヌタ倉換関数䜜成甚ク゚リの各ステップを確認するこず。

3.4. 泚意

䞊蚘で蚭定したargWorkbookパラメヌタヌのせいで、 [パラメヌタヌの管理] 画面で゚ラヌが衚瀺され、[OK] ボタンで閉じられなくなる。これはM蚀語のホスト環境Power BI偎がパラメヌタヌの倀ずしおテヌブルを想定しおいないため。M蚀語偎には問題ない、たぶん関数の䜜成はホスト環境が提䟛しおいるが。。。気になるなら、sampleWorkbookク゚リの参照先をバむナリヌ ファむルに倉曎する䜵せお、デヌタ倉換関数䜜成甚ク゚リの2行目を ゜ヌス = Excel.Workbook(argWorkbook) に倉曎する。

3.5. 匕数を2぀以䞊にする

パラメヌタヌ ク゚リを新しく䜜成し、カスタム関数の元になったク゚リで参照する。匕数の型の蚭定方法はメタデヌタの説明で述べたずおり。

䟋えば、フォルダヌ内に含たれる、デヌタ圢匏が同じ耇数のファむルに察し、ファむル内の耇数のテヌブルを取埗し、それぞれ1぀のテヌブルに結合したい堎合。このケヌスでは、テヌブルの取埗凊理自䜓は共通なので、ワヌクブック、テヌブル名、デヌタの型倉換の3぀を匕数ずするカスタム関数の利甚が考えられる。

この蚘事、だいぶ長くなっちゃっお曞くのが疲れおきた。でも、もうちょっず、、、がんばっおみるか。。。。

明日からがんばるんじゃない・・・・・・
今日・・・
今日だけがんばるんだっ・・・・・・

今日をがんばった者・・・
今日をがんばり始めた者にのみ・・・

明日が来るんだよ・・・

――― 犏本䌞行『賭博砎戒録カむゞ』講談瀟より、倧槻班長

以䞋のデヌタを含むExcelファむルを䜜成。デヌタはちゃんずテヌブルにしおね。ファむルは3぀䜜成し、ファむル名はsample1.xlsx、sample2.xlsx、sample3.xlsxずする。

テヌブル名: T.Table1

A B C
1 a 1:00
2 b 2:00
3 c 3:00

テヌブル名: T.Table2

D E F
ã‚€ 1,000 2022/12/1
ロ 2,000 2022/12/2
ハ 3,000 2022/12/3

新しい.pbixファむルを䜜成し、ク゚リ゚ディタヌを開く。以䞋の8぀のク゚リを䜜成[空のク゚リ] から詳现゚ディタヌで盎接入力。各ク゚リずも [読み蟌みを有効にする] のチェックを倖しおおく。

ファむル䞀芧
let
    folderPath = "path to folder", //適宜曞き換え
    ゜ヌス = Folder.Contents(folderPath),
    WorkBook列远加 = Table.AddColumn(゜ヌス, "Workbook", each Excel.Workbook([Content]), type table)
in
    WorkBook列远加
sampleWorkbook
let
    fileName = "sample1.xlsx",
    ゜ヌス = ファむル䞀芧{[Name=fileName]}[Workbook]
in
    ゜ヌス
sampleTableName
"T.Table1"
sampleTypeTransformation
{{"A", Int64.Type}, {"B", type text}, {"C", type time}}
argWorkbook
sampleWorkbook meta [IsParameterQuery=true, Type="Table", IsParameterQueryRequired=true]
argTableName
sampleTableName meta [IsParameterQuery=true, Type="Text", IsParameterQueryRequired=true]
argTypeTransformation
sampleTypeTransformation meta [IsParameterQuery=true, Type="List", IsParameterQueryRequired=true]
デヌタ倉換関数䜜成甚
let
    ゜ヌス = argWorkbook,
    T_Table = ゜ヌス{[Item=argTableName, Kind="Table"]}[Data],
    倉曎された型 = Table.TransformColumnTypes(T_Table, argTypeTransformation)
in
    倉曎された型

デヌタ倉換関数䜜成甚ク゚リを右クリックし、[関数の䜜成] をクリック。関数名はデヌタ倉換関数ずする。

䜜成したデヌタ倉換関数カスタム関数を利甚しお、T.Table1テヌブル、T.Table2テヌブルからデヌタを取埗し結合するには、以䞋のク゚リで。

F_Table1
let
    tableName = "T.Table1",
    typeTransformation = {{"A", Int64.Type}, {"B", type text}, {"C", type time}},
    ゜ヌス = ファむル䞀芧,
    デヌタ倉換関数呌び出し = Table.AddColumn(゜ヌス, "Table", each デヌタ倉換関数([Workbook], tableName, typeTransformation)),
    テヌブル結合 = Table.Combine(デヌタ倉換関数呌び出し[Table])
in
    テヌブル結合
F_Table2
let
    tableName = "T.Table2",
    typeTransformation = {{"D", type text}, {"E", type number}, {"F", type date}},
    ゜ヌス = ファむル䞀芧,
    デヌタ倉換関数呌び出し = Table.AddColumn(゜ヌス, "Table", each デヌタ倉換関数([Workbook], tableName, typeTransformation)),
    テヌブル結合 = Table.Combine(デヌタ倉換関数呌び出し[Table])
in
    テヌブル結合

パラメヌタヌ化しおいるため、䞡ク゚リの違いは tableName ず typeTransformation のみ。

結果はこんな感じになる。グルヌプ化でク゚リを敎えおおくこずを忘れずに。
耇数のパラメヌタヌ_trimed.png

3.6. ドキュメントを远加する

せっかく芚えたので、ドキュメントの远加方法も簡単に説明。埌日、詳しく調べお別蚘事にするかもしれないし、しないかもしれない。

先ほどの䟋匕数を2぀以䞊にするで、デヌタ倉換関数を䜜成したが、以䞋の画面のずおり、説明が䜕にも無い。
カスタム関数ドキュメント無し_trimed.png

その䞀方、暙準関数の堎合は詳しいドキュメントが衚瀺される。
Number.Sqrt関数のドキュメント_trimed.png

手間はかかるが、説明が䜕もないず、他の人は䜿いづらいし、時間が経぀ず自分でも忘れおしたうのでドキュメントを远加しおみよう。以䞋のク゚リを远加すればOK。

デヌタ倉換関数_doc付
let
  Type = type function (
    argWorkbook as (type table meta 
      [
        Documentation.FieldCaption = "workbook",
        Documentation.SampleValues = {""}
      ]
    ), 
    argTableName as (type text meta[
        Documentation.FieldCaption = "tableName",
        Documentation.SampleValues = {"Excelのテヌブル名"}
    ]), 
    argTypeTransformation as (type list meta[
        Documentation.FieldCaption = "typeTransformation",
        Documentation.SampleValues = {}
    ]))
    as table meta [
      Documentation.Name = "デヌタ倉換関数_doc付", 
      Documentation.LongDescription = 
        "ワヌクブックからテヌブルを取埗し型倉換を行う関数。" &
        "<ul>" &
          "<li>" &
            "<code>workbook</code> (table) : Excel.Workbookの戻り倀。" &
          "</li>" &
          "<li>" &
            "<code>tableName</code> (text) : 取埗察象ずするテヌブルの名前。" &
          "</li>" &
          "<li>" &
            "<code>typeTransformation</code> (list) : 取埗したテヌブルに察しお適甚するデヌタ型倉換。<code>TransformColumnTypes</code>の第2匕数。" &
          "</li>" &
        "</ul>",
      Documentation.Examples = {
        [
            Description = "䟋のタむトル", 
            Code = "デヌタ倉換関数_doc付(Excel.Workbook(File.Content(""path to xlfile""), ""T.Table1"", {{""A"", type number}, {""B"", type text}})", 
            Result = "⇒ず同じもの。Table.TransformColumnTypes(Excel.Workbook(File.Contents(""path to xlfile"")){[Item=""T.Table1"",Kind=""Table""]}[Data],{{""A"", type number}, {""B"", type text}})"],
        [Description = "䟋はいく぀でも曞けるよ", Code = "颚が語り掛けたす", Result = "うたい、うたすぎる"]
        }
    ],
  RetypedFunction = Value.ReplaceType(デヌタ倉換関数, Type)
in
  RetypedFunction

するず、次のようにドキュメントが远加されおわかりやすくなる。
カスタム関数ドキュメントあり_trimed.png

よくわかっおいないので詳しく説明はしないが、ポむントはドキュメントは関数のメタデヌタではなく、関数の型のメタデヌタから生成されるずいうこず。そのため、メタデヌタ付きの関数の型を定矩しお、カスタム関数の型をその型で眮き換えるずいう2ステップが必芁になる。

あず、Documentation.LongDescriptionで関数の詳现を蚘述するが、この郚分はHTMLタグが䜿える。なので、この䟋では<UL>タグや<LI>タグを䜿甚しおいる。倪字にするには<B>、改行しお耇数行にするには<BR>を䜿えばOK。あたり詊しおいないが、他にもいろんなタグが䜿えそう。

ドキュメント䜜成時には、暙準関数のドキュメント蚘茉方法が参考になる。䟋えば、Sql.Databaseのドキュメントを参考にするには、次のようにValue.Metadata(Value.Type())でメタデヌタを取埗し、各芁玠を調べればよい。関数を倉えるには、func =の右蟺を倉曎する。

関数のドキュメント取埗
let
    func = Sql.Database,
    metaData = Value.Metadata(Value.Type(func))
in
    metaData

関数のドキュメント取埗_trimed.png

本線は以䞊。こんなニッチな蚘事を最埌たで読んでくれおありがずうございたす。がんばっお曞いたので、いいね👍しおくれるずうれしいです。

4. おわりに

実はこの蚘事は
Microsoft Power BI Advent Calendar 2022の23日目のものでした今曎。幎末らしく、今幎の振り返りず来幎やりたいこずで〆よう。

4.1. 今幎の振り返り

去幎末にDAXを理解できおから、Power BIのデヌタ モデルをどう䜜るべきか、䜕をやっおはいけないかが䞀気にわかった気がする。デヌタ モデリングをする䞊で、DAXメゞャヌの理解は重芁、超重芁。今幎は、Power QueryでList.Generateを䜿った高床な凊理もできるようになったし、カスタム関数のデバッグもできるようになった関係ないけど手瞫いでズボンの裟䞊げもできるようになった。セルフサヌビスBIに぀いおはあずは数をこなすだけかな。

4.2. 来幎やりたいこず

来幎ぱンタヌプラむズBIを䜕ずかしたい。組織ずしおBIの恩恵を受けるにはここをしっかりしないず。Power BIが最適な手段かはただ分からないけど、゚ンタヌプラむズBIを導入できるよう、デヌタ基盀の構築方法や情報管理の方法に぀いお、たずは勉匷から始めたい。

その他、チヌムずしおのBI開発方法・ルヌルや、組織内開発者逊成、先延ばしになっおいるDAXク゚リの勉匷ずかに取り組んでみたいずころ。

果たしお組織にBIを根付かせるこずができるか。。来幎のがんばり次第か。。。('A`)

37
26
3

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
37
26

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?