
続・Excel(VBA)のゲームでBGMを流したい
前回記事の続きになります。
まだ読んでいない方はコチラ(↓)をご覧ください!
前回記事ではExcel(VBA)でBGMを流す方法ということで、テスト用のユーザーフォームを作って実際に音楽が鳴る環境を作ってみました。

デフォ設定では表示されないメディアプレイヤーを追加して、複数のボタンを配置、対応したBGMやSEが鳴らしたり、音量変更ができるシンプルなフォームなんですけど、当然フォームだけでは動きません。
そこでソースコードも掲載したのですが、プログラムに慣れていない方だと、いまいち何をやっているのか分からない…かもしれない。
ということで、今回はコードの解説をします。
それと、最後の方ではExcel(VBA)で作った「神経衰弱」に音楽を付けたものを動画にしたのでお楽しみに!
※「神経衰弱」を作った回はコチラ(↓)からどうぞ!
毎回そうなのですが、コードの中身を解説すると長くなりがちです。
全てを読むのも大変なので前回記事のコードを見て、わからない箇所の説明を読むという学習方法が良いと思います。
全体の変数定義
まずはオレンジの枠で囲まれた部分から説明します。

Option Explicit
Dim myDir As String '【変数定義】ファイルパス
Dim wmp1V As Integer '【 〃 】WindowsMediaPlayer1 音量
Dim wmp2V As Integer '【 〃 】WindowsMediaPlayer2 音量
Dim StpSW As Integer '【 〃 】BGMループスイッチ [0]Loopしない [1]する最初の1行目にある「Option Explicit」ですが、これは以前の「Excel(VBA)で簡単なゲームを作る(プログラムコード解説編)」でも触れているので、お手数をおかけしますが、そちらをご覧ください。
・Dim myDir As String
このExcelファイルがあるディレクトリ(フォルダ)パスを入れておく変数を定義しています。同じフォルダにSoundフォルダを持っているので、何度もパスを求めるのではなく、変数に入れて覚えておきます。
・Dim wmp1V As Integer
・Dim wmp2V As Integer
フォームに設置したWindowsMediaPlayer1および2のボリュームを入れておく変数です。サンプルではwmp1をBGM、wmp2をSEに割り当てています。
・Dim StpSW As Integer
ループさせる、させないを判断する為の変数です。
UnityなどのゲームエディタであればBGMのループはコンポーネントの設定で済むのですが、今回のサンプルでは音楽の停止を感知したら再生しなおす仕組みになっているため、後で活躍する変数だったりします。
ユーザーフォームのイベント
全体の変数定義の後に並んでいるのが、ユーザーフォームに何らかのイベントが発生した時に動くプロシージャです。

Private Sub UserForm_Initialize()
myDir = ActiveWorkbook.Path ' ファイルパスを取得
myDir = myDir & "\Sound\" ' ファイルパスに音楽データが入っているフォルダ名を追加
wmp1V = WMP1.settings.volume ' WindowsMediaPlayer1 音量を取得
wmp2V = WMP2.settings.volume ' WindowsMediaPlayer2 音量を取得
VolUpdate ' 音量変更時 総合処理
StpSW = 0 ' BGM Stop を押下した場合はBGMループさせない
End Sub・Private Sub UserForm_Initialize()
ユーザーフォームの初期化時の処理を意味します。
このタイミングで全体に関係する変数に必要な値を入れておきます。
・myDir = ActiveWorkbook.Path
・myDir = myDir & "\Sound\"
まず1行目で、アクティブ状態のワークブック、つまり「このExcelファイル」です。これがあるディレクトリ(フォルダ)パスを取得しています。
2行目では、取得したパスにSoundフォルダのパスを追加しています。
・wmp1V = WMP1.settings.volume
・wmp2V = WMP2.settings.volume
ここではWindowsMediaPlayerオブジェクトの現在の音量を変数に取得しています。実はWindowsMediaPlayerの初期状態の音量は50らしいのですが、念のため、定数ではなく取得しています。
・VolUpdate
後述するVolUpdateというサブルーチンを動かしています。
・StpSW = 0
BGMをループさせるorさせないの変数ですね。
最初期ではBGM自体が鳴っていないので「0:ループしない」です。

Private Sub UserForm_Terminate()
StpSW = 0 ' BGMループさせない
WMP1.Controls.stop ' WindowsMediaPlayer1 停止
WMP2.Controls.stop ' WindowsMediaPlayer2 停止
End Sub・Private Sub UserForm_Terminate()
ユーザーフォームの終了時に発生するイベントです。
・StpSW = 0
またまた登場のBGMをループさせるorさせないの変数ですね。
もしBGMを鳴らしていた場合は「1:ループする」ことになっているので、ここで0に戻しています。
・WMP1.Controls.stop
・WMP2.Controls.stop
フォームが終了した時点で何らかの音楽が鳴っていたら停止させます。
あらかじめ「0:ループしない」設定にしたのは、ここで停止した時にループさせない為です。
これらが無いと、フォームが消えているのに音楽が鳴り続けてしまいます。
BGMの再生/停止ボタン
ここからはボタン押下(クリックされた)時に発生するイベントが続きます。まずはBGMの再生/停止ボタンです。

Private Sub BGM1Play_Click()
WMP1.Controls.stop ' WindowsMediaPlayer1 停止
WMP1.Url = myDir & "BGM1.mp3" ' WindowsMediaPlayer1 に BGM1のファイルパスを入れる
WMP1.Controls.Play ' WindowsMediaPlayer1 再生
StpSW = 1 ' BGMをループさせる
End Sub・Private Sub BGM1Play_Click()
・Private Sub BGM2Play_Click()
BGM1または2を再生するボタンがクリックされた時に動くプロシージャで、内容はほぼ同じです。異なる箇所は再生するファイル名だけ、なので上記コードはBGM1の方だけ掲載します。
・WMP1.Controls.stop
WindowsMediaPlayer1で新たにBGMを再生するので、動いていた場合に備えて、一旦ここで停止させています。
・WMP1.Url = myDir & "BGM1.mp3"
・WMP1.Controls.Play
myDirはSoundフォルダのパスが入っています。そのパスに再生するファイル名を追加しています。2行目では再生を指示しています。
※ BGM2Playボタンの場合はファイル名はBGM2.mp3になっています。
・StpSW = 1
またまた登場のStpSWです。今はBGMが鳴り始めたタイミングです。
BGM終了後ループさせたいので、ここでは「1:ループする」とします。
Private Sub BGMStop_Click()
StpSW = 0 ' BGM Stop を押下した場合はBGMループさせない
WMP1.Controls.stop ' WindowsMediaPlayer1 停止
End Sub・Private Sub BGMStop_Click()
BGMStopボタンをクリックした時に動くプロシージャです。
・StpSW = 0
・WMP1.Controls.stop
もう見慣れたStpSW。ここではBGMを停止させていますので「0:ループしない」に戻してあげましょう。先にこれをやらないとBGM停止に反応してループしてしまうので注意です。
BGMの音量調整ボタン
ここではBGMの音量調整ボタンの動きを設定しています。
似ているようなコードが並んでいますね。

Private Sub BGMVolpp_Click()
wmp1V = wmp1V + 10 ' WindowsMediaPlayer1 音量+10
VolUpdate ' 音量変更時 総合処理
End Sub・Private Sub BGMVolpp_Click()
・Private Sub BGMVolp_Click()
・Private Sub BGMVolmm_Click()
・Private Sub BGMVolm_Click()
BGMの音量を調整するボタンをクリックしたら動くプロシージャで、内容はほぼ同じです。異なる箇所は押されたボタンによって音量の加減算量が異なるだけです。ここでは「BGM++」ボタンのコードだけ掲載しました。
・wmp1V = wmp1V + 10
各ボタンそれぞれ、押下された時に変化するボリュームが異なります。
「++」であれば+10され、「+」なら+1、「--」だったら-10、「-」の場合は-1されます。
計算結果を最初に定義した変数「wmp1V」 に格納しています。
・VolUpdate
BGMまたはSEのボリュームに変更があったら必ず動くサブルーチン「VolUpdate」を動かしています。
SEの再生ボタン
SEを再生するボタンのコードが並んでいます。
BGMの場合は停止ボタンも作っていましたが、SEは一瞬で終わっちゃうので停止ボタンを作っていません。

Private Sub SE1Play_Click()
WMP2.Controls.stop ' WindowsMediaPlayer2 停止
WMP2.Url = myDir & "SE1.mp3" ' WindowsMediaPlayer2 に SE1 のファイルパスを入れる
WMP2.Controls.Play ' WindowsMediaPlayer2 再生
End Sub・Private Sub SE1Play_Click()
・Private Sub SE2Play_Click()
SE1または2を再生するボタンがクリックされた時に動くプロシージャで、内容はほぼ同じです。異なる箇所は再生するファイル名だけ、なので上記コードはSE1の方だけ掲載します。
・WMP2.Controls.stop
BGMはWindowsMediaPlayer1を、SEはWindowsMediaPlayer2を使用します。
WindowsMediaPlayer2で新たにSEを再生するので、動いていた場合に備えて、一旦ここで停止させています。
・WMP2.Url = myDir & "SE1.mp3"
・WMP2.Controls.Play
myDirも何度も出てきているので、もう覚えちゃった方もいらっしゃるでしょう。myDirにはSoundフォルダのパスが入っています。そのパスに再生するファイル名を追加しています。2行目では再生を指示してますね。
※ SE2Playボタンの場合はファイル名はSE2.mp3になっています。
SEの音量調整ボタン
SEの音量調整ボタンの動きを設定しています。

Private Sub SEVolpp_Click()
wmp2V = wmp2V + 10 ' WindowsMediaPlayer2 音量+10
VolUpdate ' 音量変更時 総合処理
End Sub・Private Sub SEVolpp_Click()
・Private Sub SEVolp_Click()
・Private Sub SEVolmm_Click()
・Private Sub SEVolm_Click()
SE音量を変更するボタンをクリックすることで動くプロシージャです。
内容はほぼ同じです。異なる箇所は押されたボタンによって音量の加減算量が違うだけ…ここでは「SE++」ボタンのコードだけ掲載しました。
・wmp2V = wmp2V + 10
・VolUpdate
各ボタン、押下されると変化するボリュームが違います。
「++」であれば+10され、「+」なら+1、「--」だったら-10、「-」の場合は-1されます。BGMの場合と同じですね。計算結果を最初に定義した変数「wmp2V」 に格納しています。
その後、BGMまたはSEのボリュームに変更があったら必ず動くサブルーチン「VolUpdate」を動かしています。
音量変更時 総合処理
これまでの説明で何度か出てきたサブルーチン「VolUpdate」のコードがここに書かれています。音量に何らかの変化があった場合は必ずここで対応する処理を行います。

Private Sub VolUpdate()
If wmp1V > 100 Then wmp1V = 100 ' WindowsMediaPlayer1 音量が100を上回っている場合 >> 100 にする
If wmp1V < 0 Then wmp1V = 0 ' 〃 音量が 0を下回っている場合 >> 0 にする
If wmp2V > 100 Then wmp2V = 100 ' WindowsMediaPlayer2 音量が100を上回っている場合 >> 100 にする
If wmp2V < 0 Then wmp2V = 0 ' 〃 音量が 0を下回っている場合 >> 0 にする
WMP1.settings.volume = wmp1V ' WindowsMediaPlayer1 音量変更
WMP2.settings.volume = wmp2V ' WindowsMediaPlayer2 音量変更
BGMVolLbl = "" & wmp1V ' BGM音量ラベルの表示変更
SEVolLbl = "" & wmp2V ' SE音量ラベルの表示変更
End Sub・If wmp1V > 100 Then wmp1V = 100
・If wmp1V < 0 Then wmp1V = 0
WindowsMediaPlayerの1つ目、つまりBGMの音量をチェックします。
100を超えたら上限を100とし、0より小さい場合は0を下限とします。
・If wmp2V > 100 Then wmp1V = 100
・If wmp2V < 0 Then wmp1V = 0
WindowsMediaPlayerの2つ目、つまりSEの音量を確認します。
こちらも100を超えたら上限を100とし、0未満だったら0を下限とします。
・ WMP1.settings.volume = wmp1V
・WMP2.settings.volume = wmp2V
BGMおよびSEの上限(下限)チェック後の音量をメディアプレイヤーそれぞれに反映させます。
・BGMVolLbl = "" & wmp1V
・SEVolLbl = "" & wmp2V
BGMおよびSEの上限(下限)チェック後の音量を画面表示します。
WMP1 再生状態の変化
前述したとおり、UnityなどのゲームエディタのようにBGMのループ設定を簡単に行う項目がないため(わたしが見つけられないだけ?)ここではWMP1の再生状態が変化した際に発生するイベントを利用して、再生しなおしを指示しています。
Private Sub WMP1_PlayStateChange(ByVal NewState As Long)
If StpSW = 0 Then Exit Sub ' StpSWが0の場合 >> このサブルーチンを抜ける
If NewState = 1 Or NewState = 8 Then WMP1.Controls.Play ' 再生状態の変化による戻値が 1(停止) or 8(音楽終了) の場合 >> 再び再生する
End Sub・If StpSW = 0 Then Exit Sub
毎度おなじみStpSWが「0:ループしない」場合は、この処理は不要となりますので、処理自体を抜けています。
・If NewState = 1 Or NewState = 8 Then WMP1.Controls.Play
はい、これが最後の行となります。
しかし、これが一番重要な1行だったります。
このプロシージャには引数が設定されています。
WMP1のPlayStateがChangeしたときの引数があるんですね。
Private Sub WMP1_PlayStateChange(ByVal NewState As Long)
太字の部分が引数です。何が引数として割り当てられているのかを調べます。するとコチラにサンプルコードがあったりするんですね…
「うわ、英語だ!」
「しかも、サンプルコードを解析するのが手間だ!」
という声が聞こえてきそうなので、わたしの方でも表にまとめました。

なんか、こんな感じらしいので「8:再生終了」の時に再生しなおせばいいのかなぁ~と思い、最初はこんなコードを書きました。
If StpSW = 0 Then Exit Sub
If NewState = 8 Then WMP1.Controls.Playしかし1周したらBGMが止まってしまうんですよね。
こういう時は慌ててしまいますよね。
「エラーだ!」「不具合だ!」「なんでだ!?」
「せっかくココまで作ったのに上手く行かない!」
大丈夫! 落ち着いてください。
こんな時は「NewState」に何が入ってきているのかを確認すればいい!
If StpSW = 0 Then Exit Sub
MsgBox NewState
If NewState = 8 Then WMP1.Controls.Play何が変わったか分かりますか?
メッセージボックスに「NewState」するだけでいいんですよ。
この状態で再生するとまずは「3」が表示されます。
「3:再生中」なので納得です。停止すると「8」だけでなく「1:停止」も表示されました。ということは…
If StpSW = 0 Then Exit Sub
If NewState = 1 Or NewState = 8 Then WMP1.Controls.Playこれならループされました!
やったね!
Windows Media Player SDK は、従来の機能です。これはMediaPlayerに置き換えられました。
サンプルコードがあったページを和訳すると、このような一文があることに不安を感じますが、調べたところ現時点でVBA単体で対応はできないっぽいので、いまは…見なかったことにします……
Excel(VBA)のゲームに実装する
順調にコード解説できて、今回はそこまで長くないなーと思ったら最後の最後で予想外の不具合に遭遇し、更には調べ物まで発生するという、微妙に時間を奪われる話になりました…なんてこった。
しかし、ここで心が折れたらもったいない!
せっかくExcel(VBA)でBGMもSEも鳴っているんです。これはゲームに実装しないといけませんよ!
というわけで、以前作成した神経衰弱をバージョンアップしてみました。
主な修正内容はこんな感じです。
・BGMが鳴る!
・SEも鳴る!
・コンフィグボタンを押すと音量を変更可能!
大急ぎの修正作業だったんですが、Excel(VBA)なのにまぁまぁゲームっぽくなりましたよね。やっぱりBGMと効果音は大事です。
もっとゲームらしくするためには、カードめくり時のウェイトとか、カード配布時の演出とか、うーん、やれなくはないんですが、いまのわたしだとUnityの方が作りやすいですね…
だけど、手軽にプログラミング学習をするならExcel(VBA)の方が良さそう。
いきなり複雑な仕組みのゲームを作ると学習用には適さないんですよね…
というわけで、今回はここまでとしましょう。
これからもプログラミング学習についてだけでなく、ゲーム開発についても色々なお話を書けたらいいなーと思っています。
もしこの記事が貴方のお役に立ったら、試しに別の記事も読んでみてくださいね。それではまた別の記事でお会いしましょう!
以降はオススメ記事の紹介です。
「読むとゲームができる」記事は、このマガジンにまとめています。
情報関連の勉強をしている方、復習したい方にはコチラ!
基本情報技術者試験のアルゴリズムとか苦手!って方にもオススメです。