
Excel(VBA)でマインスイーパーを作ってみませんか!?
こんにちは「つけらっとゲームス」プログラム担当のとちです。
今回はExcel(VBA)でマインスイーパーを作りますよ!
これまでもExcel(VBA)で簡単なゲームの作り方を何度か紹介してきましたが、今回はちょっと難しいことをしています。プログラムも長いです。
中身を理解する為にはある程度の練度を要します…
でも、恐れることはありません。
作ってみるのが大事です。とりあえずソースはコピペでいいんです。
というわけで完成すると、こんな感じのマインスイーパーになります。
ごく普通のマインスイーパーですね。
これを作っているわたしですが、マインスイーパーが得意でもないですし、ゲームの仕様そのものの記憶が微妙でして、なんか変なところで苦労しました……
本来であればマウスの左右同時クリックで地雷が無い確定マスを一斉オープンする仕様もあるんですが省略しています。
今回はユーザーフォームを挿入し、各オブジェクトを作っていきます。
最後にソースを丸ごとコピーすると動くようになるハズです。
ソースは冗長的な部分もありますが、ご容赦くださいね!
なお、この記事のスクショについて、わたしのPCに入っているMicrosoft office Home and Business 2016でスクショを撮りました。
ですので微妙に表示が異なる可能性がありますが、デスクトップ版のExcelであれば、開発に使用するVBA(Microsoft Visual Basic for Applications)は同じで作業内容も変わりません。Microsoft365のExcelでも動作します。
それと、開発前に環境を整える必要があります。
以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「Excelの準備」を参照してVBAを使えるようにしておきましょう。
また「読むとゲームができる」記事は以下のマガジンにまとめています。
もうちょっと簡単なゲームを作りたい場合は、こちらのマガジンの中を探してみてくださいね!
必要な素材を準備する
まずは必要な素材を準備します。今回のゲームはコチラのサイトからお借りしております。ありがとうございます。
もちろん、絵を描ける方は自分で書いたモノを使って構いません。
DLしたのは「古典的な爆弾のアイコン」と「旗のフリーアイコン」ですが、皆さんの好みのモノで構いません。
Excel(VBA)ではPNG形式が使えないのでJPG形式が良いです。
サイズは48~128pxくらいでいいでしょう。画像を加工できる方は自分でサイズや雰囲気を変えてもOKです。
ユーザーフォームを作る
Excelの開発準備と、素材が揃ったら以下の作業に進んでください。
最初にやるべきことは「挿入」>「ユーザーフォーム」でまっさらなユーザーフォームを準備することです。
いつもは「ユーザーフォーム」だけで作っていましたが、今回は「標準モジュール」と「クラスモジュール」も使います。それぞれ挿入してください。

(1)挿入→(2)ユーザーフォーム と選択すると UserForm1 が作られます。
同じように、(1)挿入→(2)標準モジュールで Module1 を、
(1)挿入→(2)クラスモジュールで Class1 を作っておきましょう。
次にユーザーフォームのプロパティを変更していきます。
下の画像を拡大して、プロパティ欄を同じように変更します。

(1)フォームをクリックすると、(2)クリックしたオブジェクト(今はユーザーフォーム)のプロパティが表示されます。
フォームの大きさは、(3)の白い四角をドラッグしても変更できますが、プロパティの「Height」を372にし、「Width」を286.5にすると、サンプルと全く同じ大きさになります。
フォームのプロパティで特に確認すべき箇所は以下の通りです。
・(オブジェクト名):UserForm1
フォーム上部のオブジェクト配置
引き続き、ゲーム画面に必要な各種オブジェクトを配置します。

ツールボックスの中から「ラベル」をクリックします。
フォームの上でドラッグすると「ラベル」オブジェクトが作られます。
同様にツールボックスの中から「コマンドボタン」を選びます。
ドラッグすると「コマンドボタン」オブジェクトが作られます。
まずは、おおよその大きさと位置で構わないのでオブジェクトを作ります。
ア~オの5個が「ラベル」、カ・キの2個が「コマンドボタン」です。
各オブジェクトをフォームに作ったらプロパティ欄を変更していきます。
まずはラベルオブジェクトです。
大きさや位置はおおまかでも構わないのですが、オブジェクト名はサンプルと揃えましょう。
フォントは好みのモノで構いません。

記号エ・オのラベルオブジェクトはゲーム中に見えないモノです。
実はここに設定されている画像をプログラムによってゲーム中の各マスに表示しています。
まず、記号エ・オの両方のオブジェクト名をサンプルに揃えましょう。
普段は表示しないので「Visible」欄を「False」にします。
「True」だと表示されますが「False」だと非表示になります。
記号エの「Picture」欄をクリックすると欄の右側に「…」が表示されます。「…」を選ぶと画像を選択できるので「旗のフリーアイコン」を選びます。
同様に記号オの「Picture」欄をクリックし、欄右側の「…」をクリック。
画像は「古典的な爆弾のアイコン」を選びます。

続いてコマンドボタンです。ゲームを始める前に地雷の数を変更します。
デフォルトは8個で、5~15個の間で変更できるようにします。
これまで同様にオブジェクト名はサンプルに揃えましょう。

マス(グリッド)配置
ここから少し単純作業が続きますが頑張りましょう!
地雷を埋めるグリッドをラベルオブジェクトで作ります。
これまで同様にツールボックスからラベルを選んで、フォームの上でドラッグします。ラベルはコピペして増やすと楽です。

ラベルのオブジェクト名は次の画像のように法則性があります。

下の画像は「Masu11」のひとつ下に配置する「Masu12」と、
「Masu11」のひとつ右に配置する「Masu21」のプロパティです。

グリッドを構成するラベルオブジェクトは、オブジェクト名と表示位置(LeftとTop)が違うだけで、あとは同じモノになります。
頑張って64マスを作っちゃいましょう!
※ ここで作るマス目オブジェクトのBackColorを白にすると、マス目をクリックした後、開いているのか、閉じたままなのか判断しやすくなります。
(白以外でもいいです、好みで変更してみてくださいね!)
画面下部のオブジェクト配置
オブジェクトの作成もあと少しです。
状況を説明するメッセージのラベルと、ゲーム終了後に「もう1回」遊ぶためのコマンドボタンです。
ツールボックスから「ラベル」と「コマンドボタン」を選んで、フォームの上でドラッグしてオブジェクトを配置しましょう。

ラベルとコマンドボタンのプロパティです。
これまでと同じようにオブジェクト名はサンプルに揃えます。Font等は好みで構いません。

ソースコードをコピペ!
結構な量のオブジェクトを作ってプロパティを変更して、単純作業って不思議とメンタル削れますよね。とはいえ、ここまで作った以上は動かしたい。よしっ、動かしましょう!
◆フォーム(UserForm1)
では「ユーザーフォーム」や「もう1回」ボタンをダブルクリックしましょう! すると、こんな感じの画面が表示されるので2行ほど書かれているコードを消しちゃいましょう。

まっさらな画面になったら、以下のクソ長コードをコピペします。
プログラムに馴染みの無い方へ、今はコードの意味を考えません、とりあえずコピペするのです。
プログラムとある程度仲良くしている方は、コードの中にコメントを残していますので、少し覗いてみるのもアリです!
Option Explicit
Dim GameStart As Integer '【変数定義】ゲーム開始フラグ [0]開始時 [1]地雷埋設済み
Dim GridMine(7, 7) As Integer '【 〃 】二次元配列 - 地雷埋設位置
Dim GridFlag(7, 7) As Integer '【 〃 】 〃 - 旗設置位置(チェック用)
Dim GridOpen(7, 7) As Integer '【 〃 】 〃 - オープン位置
Private MineCol As Collection 'コレクション定義
'----------------------------------------------------------------
' ユーザーフォームの初期化時
'----------------------------------------------------------------
Private Sub UserForm_Initialize()
Set MineCol = New Collection ' コレクションオブジェクト作成
Set GameForm = Me ' グローバル変数のGameFormにこのフォームを設定
Dim MineCtrl As Control '【変数定義】コントロール変数
Dim MineObj As Class1 '【 〃 】インスタンス変数
Dim MineNm As String '【 〃 】コレクション追加判断オブジェクト名
For Each MineCtrl In Me.Controls '■このフォームのコントロール全部分のループ
'│
If TypeName(MineCtrl) = "Label" Then '├◆ このコントロールがラベルの場合
MineNm = MineCtrl.Name '│├ オブジェクト名を取得
'││
If Mid(MineNm, 1, 4) = "Masu" Then '│└▼ オブジェクト名の頭4文字が"Masu"の場合
Set MineObj = New Class1 '│ ├ インスタンス生成
MineObj.SetCtrl MineCtrl '│ ├ コントロールセット
MineCol.Add MineObj '│ ├ コレクション追加
Set MineObj = Nothing '│ └ インスタンス破棄
End If '│
'│
End If '│
'│
Next '└ ループ終端
GameStart = 0 ' ゲーム開始フラグを [0]開始時 にする
End Sub
'----------------------------------------------------------------
' [-]ボタンをクリックした時 (地雷の数を減らす)
'----------------------------------------------------------------
Private Sub BtnMineDw_Click()
Dim MineCnt As Integer '【変数定義】地雷の数
MineCnt = CInt(LblMineCnt.Caption) ' フォームに表示されている地雷の数を取得
MineCnt = MineCnt - 1 ' 地雷の数を-1
If MineCnt <= 5 Then MineCnt = 5 ' ■地雷の数が5個以下の場合 >> 最低5個にする
LblMineCnt.Caption = MineCnt ' 地雷の数を画面に反映する
End Sub
'----------------------------------------------------------------
' [+]ボタンをクリックした時 (地雷の数を増やす)
'----------------------------------------------------------------
Private Sub BtnMineUp_Click()
Dim MineCnt As Integer '【変数定義】地雷の数
MineCnt = CInt(LblMineCnt.Caption) ' フォームに表示されている地雷の数を取得
MineCnt = MineCnt + 1 ' 地雷の数を+1
If MineCnt >= 15 Then MineCnt = 15 ' ■地雷の数が15個以上の場合 >> 最大15個にする
LblMineCnt.Caption = MineCnt ' 地雷の数を画面に反映する
End Sub
'----------------------------------------------------------------
' もう1回ボタンをクリックした時
'----------------------------------------------------------------
Private Sub BtnReStart_Click()
Dim XX As Integer '【変数定義】二次元配列の添え字x
Dim YY As Integer '【 〃 】二次元配列の添え字y
Dim wOBJNm As String '【 〃 】地雷埋設場所のラベルオブジェクト名
Dim wOBJ As Object '【 〃 】地雷埋設場所のラベルオブジェクト
For YY = 0 To 7 '■二次元配列y分のループ
For XX = 0 To 7 '├◆二次元配列x分のループ
'││
wOBJNm = "Masu" & (XX + 1) & (YY + 1) '│├添え字からオブジェクト名を編集
Set wOBJ = Me.Controls(wOBJNm) '│├オブジェクトの取得
wOBJ.BackStyle = 0 '│├対象オブジェクトの背景を透過
wOBJ.Caption = "" '│├対象オブジェクトのキャプションを初期化
wOBJ.Picture = Nothing '│├対象オブジェクトのピクチャ を初期化
GridMine(XX, YY) = 0 '│├地雷埋設位置の初期化
GridFlag(XX, YY) = 0 '│├旗設置位置 の初期化
GridOpen(XX, YY) = 0 '│├オープン位置の初期化
'││
Next '│└ループ終端
Next '└ループ終端
GameStart = 0 ' ゲーム開始フラグを [0]開始時 にする
LblMsg.Visible = False ' メッセージ用ラベルを非表示化
BtnReStart.Visible = False ' もう1回ボタン を非表示化
End Sub
'----------------------------------------------------------------
' マスをクリック(内容チェック)
'----------------------------------------------------------------
Public Sub MineMasu_Check(Btn As Integer, XX As Integer, YY As Integer)
Dim wOBJNm As String '【変数定義】地雷埋設場所のラベルオブジェクト名
Dim wOBJ As Object '【 〃 】地雷埋設場所のラベルオブジェクト
Dim wXX As Integer '【 〃 】二次元配列の添え字x
Dim wYY As Integer '【 〃 】二次元配列の添え字y
Dim ClrSW As Integer '【 〃 】クリアフラグ
Dim EndSW As Integer '【 〃 】ゲームオーバーフラグ
wOBJNm = "Masu" & XX & YY 'クリックされたオブジェクト名
Set wOBJ = Me.Controls(wOBJNm) 'クリックされたオブジェクト
wXX = XX - 1 'オブジェクト名から添え字xを算出
wYY = YY - 1 'オブジェクト名から添え字yを算出
If Btn = 1 Then '■マス目に左クリックした時
'│
If GameStart = 0 Then '├◆ゲーム開始フラグ [0]開始時 の場合
Call MineSet(wXX, wYY) '│├ はじめて左クリックされた場合 >> 地雷設置サブルーチン
GameStart = 1 '│└ ゲーム開始フラグ [1]地雷埋設済み にする
End If '│
'│
If GridFlag(wXX, wYY) >= 1 Then Exit Sub '├◆旗が立っている場合 >> 左クリックできない
If GridOpen(wXX, wYY) >= 1 Then Exit Sub '├◆オープン済みの場合 >> 左クリックできない
'│
GridOpen(wXX, wYY) = 1 '├ マスをオープン
wOBJ.BackStyle = 1 '├ マスをオープンしたらラベル背景を白にする
'│
If GridMine(wXX, wYY) = 0 Then '├◆ 地雷設置位置がゼロの場合(付近に地雷が無い)
wOBJ.Caption = "" '│├ クリックされたオブジェクトのキャプションを初期化
Call OpenProc(wXX, wYY) '│├ 地雷の無いマスをオープンするサブルーチン
ElseIf GridMine(wXX, wYY) = 9 Then '│◆ 地雷設置位置が[9]の場合(地雷を踏んだ!)
wOBJ.Caption = "" '│├ クリックされたオブジェクトのキャプションを初期化
wOBJ.Picture = BaseBomb.Picture '│├ 地雷アイコンをピクチャに代入
EndSW = 1 '│├ ゲームオーバーフラグを立てる
Else '│◆ 地雷設置位置が[1~8]の場合
wOBJ.Caption = GridMine(wXX, wYY) '│└ クリックされたオブジェクトのキャプションに数字を代入
End If '│
'│
Else '■マス目に右クリックした時
'│
If GridOpen(wXX, wYY) >= 1 Then Exit Sub '├◆ オープン済みの場合 >> 右クリックできない
If GridFlag(wXX, wYY) = 0 Then '└◆ 旗が立っていない場合
wOBJ.Picture = BaseFlag.Picture ' ├ 旗アイコンをピクチャに代入
GridFlag(wXX, wYY) = 1 ' ├ 旗設置位置(チェック用)に[1]チェック を代入
Else ' ◆ 旗が立っている場合
wOBJ.Picture = Nothing ' ├ 旗アイコンを消す
GridFlag(wXX, wYY) = 0 ' └ 旗設置位置(チェック用)に[0]未チェック を代入
End If
End If
ClrSW = fClearCheck() 'クリアフラグにクリアチェックファンクションの戻値を代入
If ClrSW = 1 Then LblMsg.Caption = "クリアおめでとう!" '■クリアフラグが[1]クリア の場合 >> クリアメッセージ表示
If EndSW = 1 Then '■ゲームオーバーフラグが[1]ゲームオーバー の場合
LblMsg.Caption = "ゲームオーバー..." '├ ゲームオーバーメッセージ表示
For wYY = 0 To 7 '├◆二次元配列y分のループ
For wXX = 0 To 7 '│├▼二次元配列x分のループ
Call MasuUpdate(wXX, wYY) '││└ マスの表示更新サブルーチン
Next '│└ループ終端
Next '└ループ終端
End If
If ClrSW = 1 Or EndSW = 1 Then '■クリアフラグかゲームオーバーフラグが立っていた場合
BtnMineDw.Enabled = True '├ 地雷設置カウント(Max)[-]ボタンを操作可にする
BtnMineUp.Enabled = True '├ 地雷設置カウント(Max)[+]ボタンを操作可にする
LblMsg.Visible = True '├ メッセージ用ラベルを表示化
BtnReStart.Visible = True '└ もう1回ボタンを表示化
End If
End Sub
'----------------------------------------------------------------
' 地雷の無いマスを自動オープンするサブルーチン
'----------------------------------------------------------------
Private Sub OpenProc(XX As Integer, YY As Integer)
Dim cOpen(7, 7) As Integer '【変数定義】二次元配列 - 自動オープンチェック
Dim cXX(7) As Integer '【 〃 】一次元配列 - 対象マスを中心としたx軸マス
Dim cYY(7) As Integer '【 〃 】一次元配列 - 対象マスを中心としたy軸マス
Dim ix As Integer '【 〃 】一次元配列を操作する添え字
Dim chkOK As Integer '【 〃 】自動オープン処理の終了スイッチ [1]終了
Do While True '■ループ
'│
cOpen(XX, YY) = 2 '├ 選択されたマスを [2]チェック済みマスとする
cXX(0) = XX - 1: cXX(1) = XX + 0: cXX(2) = XX + 1 '├ 対象マスを中心としたx軸マス位置の設定
cXX(3) = XX - 1: cXX(4) = XX + 1: cXX(5) = XX - 1 '├ 〃 〃 〃
cXX(6) = XX + 0: cXX(7) = XX + 1 '├ 〃 〃 〃
cYY(0) = YY - 1: cYY(1) = YY - 1: cYY(2) = YY - 1 '├ 対象マスを中心としたy軸マス位置の設定
cYY(3) = YY + 0: cYY(4) = YY + 0: cYY(5) = YY + 1 '├ 〃 〃 〃
cYY(6) = YY + 1: cYY(7) = YY + 1 '├ 〃 〃 〃
'│
For ix = 0 To 7 '├◆対象マスを中止とした8マス分ループ
'-- チェックするマス(対象マス)が存在している
If cXX(ix) >= 0 And cXX(ix) <= 7 And cYY(ix) >= 0 And cYY(ix) <= 7 Then
'-- 対象マス に旗(チェック用)が立っている場合は [2]チェック済みマス とする
If GridFlag(cXX(ix), cYY(ix)) = 1 Then cOpen(cXX(ix), cYY(ix)) = 2
'-- 対象マス は[2未満]未チェック状態の場合
'-- 地雷と接する数が0 の場合 >> [1]要チェックマス とする
'-- 地雷と接する数が1~8の場合 >> [2]チェック済マス として マスの表示更新サブルーチン
If cOpen(cXX(ix), cYY(ix)) < 2 Then
If GridMine(cXX(ix), cYY(ix)) = 0 Then cOpen(cXX(ix), cYY(ix)) = 1
If GridMine(cXX(ix), cYY(ix)) >= 1 And GridMine(cXX(ix), cYY(ix)) <= 8 Then
Call MasuUpdate(cXX(ix), cYY(ix))
cOpen(cXX(ix), cYY(ix)) = 2
End If '│
End If '│
End If '│
Next '│
'│
chkOK = 1 '├ 自動オープン処理の終了スイッチを [1]終了 に設定する
For YY = 0 To 7 '├◆ 二次元配列y分のループ
For XX = 0 To 7 '│├▼ 二次元配列x分のループ
If cOpen(XX, YY) = 1 Then '││├◇ 対象マスが[1]要チェックマス の場合
Call MasuUpdate(XX, YY) '│││├ マスの表示更新サブルーチン
chkOK = 0 '│││├ 自動オープン処理の終了スイッチを [0]継続 に設定する
Exit For '│││└ このループを抜ける
End If '│││
Next '││└ループ終端
If chkOK = 0 Then Exit For '│├▼ 自動オープン処理の終了スイッチが [0]継続 の場合 >> このループを抜ける
Next '│└ループ終端
'│
If chkOK = 1 Then Exit Do '├◆ 自動オープン処理の終了スイッチが [1]終了 だった場合 >> このループを抜ける
DoEvents '├制御を一旦システムに渡す
Loop '└ループ終端
End Sub
'----------------------------------------------------------------
' マスの表示更新サブルーチン(指定マスをオープン)
'----------------------------------------------------------------
Private Sub MasuUpdate(XX As Integer, YY As Integer)
Dim wOBJNm As String '【変数定義】地雷埋設場所のラベルオブジェクト名
Dim wOBJ As Object '【 〃 】地雷埋設場所のラベルオブジェクト
'
GridOpen(XX, YY) = 1 ' 二次元配列 - オープン位置 の対象要素に[1]オープン を代入
wOBJNm = "Masu" & (XX + 1) & (YY + 1) ' 対象となるラベルオブジェクト名
Set wOBJ = Me.Controls(wOBJNm) ' 対象となるラベルオブジェクト
wOBJ.BackStyle = 1 ' 対象となるラベルオブジェクトの背景を非透過化
If GridMine(XX, YY) = 0 Then ' ■二次元配列 - 地雷埋設位置 の 対象要素が[0]隣接マスに地雷がない場合
wOBJ.Caption = "" ' ├ 対象オブジェクトのキャプションを初期化
wOBJ.Picture = Nothing ' ├ 対象オブジェクトのピクチャ を初期化
ElseIf GridMine(XX, YY) >= 1 And GridMine(XX, YY) <= 8 Then ' ■二次元配列 - 地雷埋設位置 の 対象要素が[1~8]隣接マスに地雷がある場合
wOBJ.Caption = GridMine(XX, YY) ' ├ 対象オブジェクトのキャプションに数字を代入
wOBJ.Picture = Nothing ' ├ 対象オブジェクトのピクチャ を初期化
Else ' ■二次元配列 - 地雷埋設位置 の 対象要素が[9]地雷マスの場合
wOBJ.Caption = "" ' ├ 対象オブジェクトのキャプションを初期化
wOBJ.Picture = BaseBomb.Picture ' └ 対象オブジェクトのピクチャ を爆弾にする
End If
End Sub
'----------------------------------------------------------------
' 地雷設置サブルーチン(初期配置)
'----------------------------------------------------------------
Private Sub MineSet(stXX As Integer, stYY As Integer)
Dim ProcCnt As Integer '【変数定義】地雷設置カウント(Now)
Dim MineCnt As Integer '【 〃 】地雷設置カウント(Max)
Dim XX As Integer '【 〃 】二次元配列の添え字x
Dim YY As Integer '【 〃 】二次元配列の添え字y
Dim XXL As Integer '【 〃 】設置位置xの1つ左
Dim XXR As Integer '【 〃 】設置位置xの1つ右
Dim YYU As Integer '【 〃 】設置位置yの1つ上
Dim YYD As Integer '【 〃 】設置位置yの1つ下
MineCnt = CInt(LblMineCnt.Caption) '地雷設置カウント(Max)値をフォームから取得
ProcCnt = 0 '地雷設置カウント(Now)値を初期化
BtnMineDw.Enabled = False '地雷設置カウント(Max)[-]ボタンを操作不可にする
BtnMineUp.Enabled = False '地雷設置カウント(Max)[+]ボタンを操作不可にする
Randomize '乱数初期化
Do While True '■ループ
XX = fRandom(7, 0) '├ 二次元配列の添え字xに乱数取得
YY = fRandom(7, 0) '├ 二次元配列の添え字yに乱数取得
If stXX = XX And stYY = YY Then '├■最初にクリックされたマス目と乱数が同じ場合 >> 処理しない
Else '├■最初にクリックされたマス目と乱数が違う場合
If GridMine(XX, YY) < 9 Then '│└◆指定マスに地雷が埋まっていない場合
GridMine(XX, YY) = 20 '│ ├ 指定マスに地雷を埋める[20]を入れる
ProcCnt = ProcCnt + 1 '│ ├ 地雷設置カウント(Now) +1
XXL = XX - 1 '│ ├ 対象マスの周囲8マスの添え字を算出
XXR = XX + 1 '│ ├ 〃 〃 〃
YYU = YY - 1 '│ ├ 〃 〃 〃
YYD = YY + 1 '│ ├ 〃 〃 〃
'-- 地雷埋設マスの周囲マスが存在している
'-- 周囲マスに+1をする
If XXL >= 0 Then
GridMine(XXL, YY) = GridMine(XXL, YY) + 1
If YYU >= 0 Then GridMine(XXL, YYU) = GridMine(XXL, YYU) + 1
If YYD <= 7 Then GridMine(XXL, YYD) = GridMine(XXL, YYD) + 1
End If
If XXR <= 7 Then
GridMine(XXR, YY) = GridMine(XXR, YY) + 1
If YYU >= 0 Then GridMine(XXR, YYU) = GridMine(XXR, YYU) + 1
If YYD <= 7 Then GridMine(XXR, YYD) = GridMine(XXR, YYD) + 1
End If
If YYU >= 0 Then GridMine(XX, YYU) = GridMine(XX, YYU) + 1
If YYD <= 7 Then GridMine(XX, YYD) = GridMine(XX, YYD) + 1
'-- 処理カウンタが8以上(初期値)になったらループを抜ける
If ProcCnt >= MineCnt Then Exit Do
End If '│
End If '│
Loop '└ループ終端
'-- 地雷は9だが、周囲8マスに数字を入れるときに9を超えることがあるので9に揃える
For YY = 0 To 7
For XX = 0 To 7
If GridMine(XX, YY) >= 20 Then GridMine(XX, YY) = 9
Next
Next
End Sub
'----------------------------------------------------------------
' クリアチェック(クリアの場合は1を返答)
'----------------------------------------------------------------
Function fClearCheck()
Dim XX As Integer '【変数定義】二次元配列の添え字x
Dim YY As Integer '【 〃 】二次元配列の添え字y
Dim OpenCnt As Integer '【 〃 】マスを開けた数
Dim MineCnt As Integer '【 〃 】埋設されている地雷数
MineCnt = CInt(LblMineCnt.Caption) 'フォームに表示されている地雷の数を取得
For YY = 0 To 7 '■二次元配列y分のループ
For XX = 0 To 7 '├◆二次元配列x分のループ
If GridOpen(XX, YY) = 1 Then OpenCnt = OpenCnt + 1 '│├▼マスがオープンされていた場合 >> 開けた数+1
Next '│└ループ終端
Next '└ループ終端
If MineCnt = (64 - OpenCnt) Then '■地雷数と(全マス-開けた数)が同じ場合
fClearCheck = 1 '├クリアフラグを返答
For YY = 0 To 7 '└◆二次元配列y分のループ
For XX = 0 To 7 ' ├◆二次元配列x分のループ
Call MasuUpdate(XX, YY) ' │├▼マスオープン
Next ' │└ループ終端
Next ' └ループ終端
End If
End Function
'----------------------------------------------------------------
' 最大値と最小値を指定した乱数取得ファンクション
'----------------------------------------------------------------
Function fRandom(dMax As Integer, dMin As Integer) '
fRandom = Int((dMax - dMin + 1) * Rnd + dMin) ' 最小~最大値の間の値を乱数を用いて返答する
End Function '
普段だとこれで動くようになるんですけど、今回はワークブック、標準モジュール、クラスモジュールの方にも少しだけ記述が必要です。順にコピペしていきます。
◆ワークブック
下の画像のとおりプロジェクトエクスプローラーの(1)ThisWorkbookをダブルクリックします。(2)何かコードが表示されていたら一旦消します。

そして以下のコードをコピペします!
Private Sub Workbook_Open()
UserForm1.Show
End Subあともう少しです!
◆標準モジュール(Module1)
下の画像のとおりプロジェクトエクスプローラーの(1)Module1をダブルクリックします。(2)何かコードが表示されていたら一旦消します。

そして以下のコードをコピペ!
Public GameForm As UserForm1 '【変数定義】(連絡用)ユーザーフォーム次でラストです!
◆クラスモジュール(Class1)
そろそろ飽きてきた頃だと思いますが、やることは同じ!
下の画像のとおりプロジェクトエクスプローラーの(1)Class1をダブルクリックします。(2)何かコードが表示されていたら一旦消します。

そして以下のコードをコピペ!
Option Explicit
Private WithEvents MineMasu As MSForms.Label 'ラベルオブジェクトのイベントをまとめる
Public Sub SetCtrl(new_ctrl As MSForms.Label)
Set MineMasu = new_ctrl 'コントロールをセット
End Sub
Private Sub MineMasu_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Dim XX As Integer '【変数定義】オブジェクト名から取得するx添え字
Dim YY As Integer '【変数定義】オブジェクト名から取得するy添え字
XX = CInt(Mid(MineMasu.Name, 5, 1)) ' x添え字 を オブジェクト名から取得
YY = CInt(Mid(MineMasu.Name, 6, 1)) ' y添え字 を オブジェクト名から取得
Call GameForm.MineMasu_Check(Button, XX, YY) ' フォーム側のサブルーチンを動かす
End Subゲームを動かしてみよう!
コードをコピペし終わったら実際にゲームを動かしてみましょう。スクショの通り(1)ユーザーフォームの名前の部分をダブルクリックすると、ユーザーフォームが表示されます。
(2)再生ボタンをクリックするとゲームが動くハズです!

上手く動かない場合は、同テーマの過去記事「Excel(VBA)で簡単なゲームを作る」の「動かないんだけど!?(怒)」を参考に原因を探ってみましょう。落ち着いて確認してみてください。
エラーの原因の9割はオブジェクト名が間違っています!(多分)
おわりに
これでゲームそのものは動いているハズ…
さて、マインスイーパーのルールですが皆さんご存知のゲームなので今まで言及してません、が、さすがに書いといた方がいいかなってことで、
以下「あそびかた」です。
左クリックでグリッド状に並んだパネルを開きます。
そこに地雷があったらゲームオーバーです。
周囲8マスに地雷がある場合はその数が表示されます。
64マス中に8個(初期値)の地雷があるので、56個のパネルを開いたらクリアとなります。
右クリックでグリッド上に旗(地雷がありそうなところに立てるチェック的なアレ)が表示されます。既に旗が立っている場合は旗を消します。
旗が立っているパネルは開くことができません。
さて次回以降の話も少し…
とりあえずコピペで動いているプログラムですが、ある程度プログラムをかじった人はわかるかもしれません。
ただし、普通の学校教育における情報科で習った経験しかないと理解できそうに見えて全く意味が分からないレベルだと思います。
というのも、今回のソースに必要な知識は配列。可能であれば二次元配列の知識が欲しいですし、それを多重ループで処理をしています。
クラスモジュールも使ったので、そこそこの規模の演習問題をやってないと触れもしない箇所があります。実際サンプルコードを打ってる間、何度も思いました。
「これを使わない方が理解しやすいんだろうなぁ…」
64マス分の同じようなコードを書くのが嫌という個人の都合なんですけど勘弁してください。
つまり、全部を詳しく解説したところで更に混乱を呼ぶ(初心者にとっては)悪魔のコードなんですよ。なので、次回はある程度の勉強をしている方に向けて要所を解説するような感じになると思います。
全然意味わかんないって方は、とりあえずマインスイーパーが動くところまで行けたらOKです。
プログラムは色々な部品をブロック化して組み合わせていくような作り方をしているんですが、そのために色々な部品の仕組みを理解する必要があります。
「全然わからん」を「ある程度わかった」になって欲しいとは考えていますが、理解までにかかる時間は人によって異なります。難しくて投げ出すくらいだったら少し難易度を下げた課題に手を出した方が良いです。
そして、難易度を少し落とした課題は以下のマガジンに何個かあります。
クイズゲームあたりは比較的楽だと思いますよ。
配列(二次元配列)等の考え方は以下のマガジンに幾つか記事がありますので、基本的な部分から学びたい方はコチラからどうぞ!
今回も長い記事になってしまいました。
最後までお付き合いいただきありがとうございました。また次の記事でお会いしましょう!