メインコンテンツへスキップ
見出し画像

Excel(VBA)で10秒を狙ってお菓子をもらおう!お祭りで使えるミニゲームを作る!

    こんにちは「つけらっとゲームス」プログラム担当のとちです。
    今回はExcel(VBA)で10秒チャレンジゲームを作ろうと思います。
    かなり簡単なので記事を読みながら一緒に作りましょ!

    ちなみに、完成品はこんな感じになります。
    背景画像は、いつもお世話になってるOKUMONOさんからお借りしました。
    カワイイ素材がたくさんあります!

    画像
    スタートボタンを押すと…
    画像
    こんな感じになり、10秒経ったと思ったらストップを押す!
    画像
    10秒くらいだと成功!ご褒美ゲット!

    サンプルコードでは9.5~10.5秒であれば成功にしています。
    すっごい単純ですが、町内会イベントや学園祭なんかでは盛り上がるミニゲームになると思います。すぐに作れるのでレッツチャレンジ!

    いつものようにユーザーフォームを挿入、各オブジェクトを作っていき最後にソースを丸ごとコピーする流れで作成していきます。

    なお、この記事のスクショについて、わたしのPCに入っているMicrosoft office Home and Business 2016でスクショを撮りました。

    なので表示が微妙に異なる可能性があります。しかしデスクトップ版のExcelであれば、開発に使用するVBA(Microsoft Visual Basic for Applications)は同じで作業内容も変わりません。Microsoft365のExcelでも動作します。

    それと、開発前に環境を整える必要があります。
    以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「Excelの準備」を参照してVBAを使えるようにしておきましょう。


    開発環境を準備する

    「Excelの準備」を参照してVBAを使えるようにできましたか?
    それでは拡張子が「xlsm」のExcelファイルを作りましょう。

    画像

    上のスクショでは「10SecondChallenge.xlsm」という名前で作っていますが、名前は他のモノでも構いません。ご自分がわかりやすい名前を付けるといいです。ただ、気をつける点が1つ、拡張子は「xlsm」にします!

    いつもの癖で上書き保存して終わっちゃう悲劇が何となく思い浮かぶので、最初の時点でやっちゃいましょう。

    【※ 忘れずに!】
    Excelのメニューバーから「ファイル」→「名前を付けて保存」→ 任意のパスを選択 → ファイルの種類 を Excelマクロ有効ブック(*.xlsm) にして保存 します。


    ユーザーフォームを作る

    Excelファイルを作ったら次にやるべきことはフォームの準備!
    「挿入」>「ユーザーフォーム」でユーザーフォームを作ります。

    画像

    (1)挿入→(2)ユーザーフォーム と選択すると UserForm1 が作られます。
    (3)作られたUserForm1のどこかをシングルクリックすると、(4)プロパティ欄にクリックされたコントロール(オブジェクト)の内容が表示されます。

    今回はユーザーフォームをクリックしたので、ユーザーフォームのプロパティが表示されます。

    画像

    用意する背景画像によって多少は異なりますが、この記事の例で言うと、
    (1)フォーム高 Height:348、(2)フォーム幅 Width:588になってます。

    (3)Picture の欄の[…]をクリックするとファイル選択ダイアログが表示されるのでフォーム背景にしたい画像ファイルを選びます。

    ここで注意、Excel(VBA)のユーザーフォームは基本的にpng形式の画像は使用できません。OKUMONOさんの画像はpng形式なのでjpg形式にしておく必要があります。また、画像サイズも1920x1080と大きいので縮小しておくと良いでしょう。

    ・画像編集をやったことなくても大丈夫!

    Windowsアクセサリのペイントでも編集可能です。画像編集をやったこと無い方向けの説明をします。自分でできる方は読み飛ばしてね。

    画像
    Windows付属のペイントで簡単な画像編集しましょ!

    背景に使用したい画像をペイントで開いたら、(1)をクリックすると「サイズ変更と傾斜」ウィンドウが表示されます。(2)パーセントが選択されている状態で、(3)水平、垂直を40にします。

    OKボタンを押せば40%の大きさに縮小されます。
    次にpng形式からjpg(jpeg)形式にします。

    画像
    40%にした画像のファイル形式を変更します!

    メニューバーから(1)ファイル → (2)名前を付けて保存 → (3)JPEG画像 というように順番に選択します。ファイル名は任意のモノで構いません。
    Haikei_40per.jpg などの意味がわかる名前にすると良いでしょう。

    では改めて、ユーザーフォームに画像を反映させる方法を説明します。
    下のスクショのPicture欄、[…]ボタンをクリックすると画像選択のダイアログが表示されます。

    画像
    画像を反映させたら、こんな感じになります。

    さっき編集した画像ファイル、Haikei_40per.jpg を選択すると、こんな感じになります。一気に華やかになりましたね。


    フォームにオブジェクトを配置する

    それではゲーム中に使用するオブジェクトを、それぞれフォームの上に配置していきましょう。

    画像

    配置するのはラベルコントロール2つ、コマンドボタン3つです。

    画像

    ツールボックスのラベルを選んでフォーム上でドラッグするとラベルが作成されます。大きさや位置は後でプロパティ欄から変更できるのでおおまかに作って構いません。

    同様にツールボックスからコマンドボタンを選び、フォーム上でドラッグしてコマンドボタンを作ります。こちらも大きさや位置は大体でいいです。


    各オブジェクトのプロパティ設定

    選んだ背景画像によっては、サンプルと同じ位置にオブジェクトを置くとしっくりこないかもしれません。その場合はお好きな位置、お好きなサイズにして構いません。が、オブジェクト名だけは例と同じにしましょう。

    コードをコピペする際にオブジェクト名が異なると、想定している動作をしなかったり、バグで停止してしまいます。なのでオブジェクト名だけは揃えましょう!

    サンプルと同じモノを作りたい場合は、以降のスクショを参考に同じ様に設定してくださいね。

    ・ラベルのプロパティ

    まずはラベルのプロパティです。

    画像
    ラベルプロパティ

    テキストの表示位置は「TextAlign」で変更可能です。
    ゲーム中のメッセージを表示する Lbl_Msg は左寄せ、経過時間(回答)を表示する Lbl_Time は中央揃えが良いでしょう。

    「SpecialEffect」を変更すると表示する枠の効果が変化します。
    色々試してみると良いでしょう。サンプルと同じにする場合はスクショと同じ設定にしてくださいね。

    あとは「Font」でしょうか、この欄を選択すると画像を選ぶ時の様に「…」が表示されます。「…」をクリックするとダイアログが表示されるので好みのフォントに変更しましょう。フォントサイズも変更可能です。

    ちなみに、サンプルで使用しているフォント「07やさしさゴシック手書き」はフロップデザインからお借りしました。

    ・コマンドボタンのプロパティ

    引き続き、コマンドボタンのプロパティです。
    ラベルと同じように、オブジェクト名だけはスクショと揃えましょう。

    画像

    なお、Btn_Resetの「最初に戻る」を表示する為に、このボタンだけフォントサイズをすこし小さめにしています。

    【※オブジェクト名のまとめ】
    ・ラベル Lbl_Msg …… ゲーム中のメッセージ表示
    ・ラベル Lbl_Time …… 経過時間(回答)の表示
    ・コマンドボタン Btn_Start ...… ゲーム開始ボタン
    ・コマンドボタン Btn_Stop …… ゲーム終了ボタン
    ・コマンドボタン Btn_Reset …… ゲーム終了後、初期状態に戻すボタン


    コードをコピペする!

    ここまで来たらあと少しです。最後にコードをコピペします!
    まずは下の画像の(1)をダブルクリックしてフォームを表示します。

    フォームが表示されたら、(2)スタートボタンをダブルクリックしましょう!
    するとコード入力画面になります。

    画像

    下のスクショのような画面が表示されます。
    この画面の右側、白くて広い枠にあるコードを一旦消去します。

    画像

    消去し終わったら下のコードを全てコピペしてください。
    コードについてですが、また別の記事で改めて解説したいと思いますので、今はとりあえず何も考えずにコピペでOKです。

    Option Explicit
    Dim Time_Sta   As Double                                    '【変数定義】スタートボタンを押した時間
    Dim Time_End   As Double                                    '【変数定義】ストップボタンを押した時間
    Dim Time_Ans   As Double                                    '【変数定義】経過時間(回答)
    Dim Time_Lw    As Double                                    '【変数定義】成功範囲(下限)デフォルトでは 9.5秒
    Dim Time_Hi    As Double                                    '【変数定義】成功範囲(上限)デフォルトでは10.5秒
    Dim GameMsg(5) As String                                    '【配列定義】ゲーム画面に表示するメッセージ
    
    '------------------------------------------------------------
    '   フォーム初期化時
    '
    '   引数    :なし
    '   戻り値  :なし
    '------------------------------------------------------------
    Private Sub UserForm_Initialize()
        
        Time_Lw = 9.5                                           '成功範囲(下限)の設定
        Time_Hi = 10.5                                          '成功範囲(上限)の設定
        
        '--
        '-- ゲーム画面に表示するメッセージを格納
        '--
        GameMsg(0) = "スタートボタンを押してね!" & vbCr
        GameMsg(1) = Time_Lw & "~" & Time_Hi & "秒ならお菓子をプレゼント!"
        GameMsg(2) = "ぴったり10秒を狙って" & vbCr & "ストップボタンをクリックしよう!"
        GameMsg(3) = "10秒だよ! すごい!" & vbCr & "好きなお菓子を2つプレゼント!"
        GameMsg(4) = "ほぼ10秒だよ! すごい!" & vbCr & "好きなお菓子を1つプレゼント!"
        GameMsg(5) = "ざんねん~、また遊んでね!"
    
        Call Btn_Reset_Click                                    'ゲーム開始時のボタン設定
    
    End Sub
    
    '------------------------------------------------------------
    '   スタートボタン クリック時
    '
    '   引数    :なし
    '   戻り値  :なし
    '------------------------------------------------------------
    Private Sub Btn_Start_Click()
    
        Time_Sta = Timer                                        'スタートボタンを押した時間取得
        Lbl_Time.Caption = "--.----秒"                          '秒数表示の変更
        Lbl_Msg.Caption = GameMsg(2)                            'メッセージの変更
        Btn_Start.Enabled = False                               'スタートボタン 押せない
        Btn_Stop.Enabled = True                                 'ストップボタン 押せる
    
    End Sub
    
    '------------------------------------------------------------
    '   ストップボタン クリック時
    '
    '   引数    :なし
    '   戻り値  :なし
    '------------------------------------------------------------
    Private Sub Btn_Stop_Click()
    
        Dim Time_Txt As String                                  '【変数定義】秒数表示の編集用
        Time_End = Timer                                        'ストップボタンを押した時間取得
        Time_Ans = Time_End - Time_Sta                          '経過時間(回答)の算出
    
        '--
        '-- 表示秒数の編集
        '--
        Time_Txt = Format(Time_Ans, "0.0000") & "秒"            '表示は小数点第四位までとする
        If Time_Ans < 10 Then Time_Txt = " " & Time_Txt         '10秒未満の場合 桁揃えのために頭に半角スペースを追加
        Lbl_Time.Caption = Time_Txt                             '経過時間(回答)の画面表示
    
        If Time_Ans = 10 Then                                   '■経過時間(回答)がピッタリ10秒...ほぼ発生しないけど
            Lbl_Msg.Caption = GameMsg(3)                        '├10秒用のメッセージ表示
        ElseIf Time_Ans >= Time_Lw And Time_Ans <= Time_Hi Then '■経過時間(回答)が成功範囲内の場合
            Lbl_Msg.Caption = GameMsg(4)                        '├ほぼ10秒用のメッセージ表示
        Else                                                    '■経過時間(回答)が成功範囲外の場合
            Lbl_Msg.Caption = GameMsg(5)                        '└失敗用メッセージ表示
        End If
            
        Btn_Stop.Enabled = False                                'ストップボタン 押せない
        Btn_Reset.Visible = True                                'リセットボタン 表示
    
    End Sub
    '------------------------------------------------------------
    '   リセットボタン クリック時
    '
    '   引数    :なし
    '   戻り値  :なし
    '------------------------------------------------------------
    Private Sub Btn_Reset_Click()
    
        Lbl_Msg.Caption = GameMsg(0) & GameMsg(1)               '最初のメッセージ
        Lbl_Time.Caption = "10.0000秒"                          '秒数表示を10.0000秒にしておく
        Btn_Start.Enabled = True                                'スタートボタン 押せる
        Btn_Stop.Enabled = False                                'ストップボタン 押せない
        Btn_Reset.Visible = False                               'リセットボタン 非表示
    
    End Sub
    

    お疲れ様です! これで完成です! しっかり保存しましょう!

    コピペが終わったら下の画像のとおり、
    (1)フォームをダブルクリックして、(2)再生ボタンをクリックするとゲームが動き出します!

    画像

    プログラムを止める場合は表示されているゲーム画面右上の✕ボタンまたは、(2)再生ボタンの隣の隣、■の停止ボタンを押します。

    うまく動かない場合でも落ち着いて…
    以前の記事の「動かないんだけど!?(怒)」を参照してください。

    原因のほとんどは「オブジェクト名が間違っている」だと思います。

    【※ ちょっとだけ注意点】
    今回のコード内にある Timer関数は「午前0時からの経過秒数」を返答するため、日付をまたぐと計算が狂うというちょっとした罠が…町内会イベントや学園祭に使うのであれば問題ないと思います。

    とはいえ、深夜、ほとんど人が訪れない時間帯、お菓子を欲しがる子どもが会場に現れたら…え?怖っ!?


    あそびかた!

    このミニゲームなんですけど、町内会のイベント、ちょっとした秋祭り、学園祭などに使ったらどうかな?っていう想定です。来場した子どもたちに遊んで貰えたらいいですね。

    皆さんのPCにもよく入っているExcelで動いていますし、慣れない方でも数時間あれば簡単に作れるのでいかがでしょう?
    フォームの背景画像を変更すれば秋祭りじゃなくても使えますね!

    というわけで「あそびかた」です!
    再生ボタンを押すと下のスクショのような画面が表示されます。

    画像
    最初の画面

    ゲーム画面のメッセージの通り「スタート」を押して10秒経過したと思ったら「ストップ」を押しましょう。

    画像
    10秒間って結構長い!

    9.5~10.5秒であれば成功です。
    ご褒美としてお菓子を1つプレゼント! やったね!

    画像


    しかし、9.5秒より早い、または10.5秒より遅い場合は失敗です。

    画像

    まぁ、ほぼ無いとは思いますが、10秒ぴったりにも対応しています。
    好きなお菓子を10個あげてもいいくらい出ませんけどね…

    画像

    もっとアプデしたいよね?

    さて、ここまで作業された方、本当にお疲れ様でした。
    簡単ではありますが、これでゲームそのものは動いているハズです。

    ただ、ちょっとしたところが気になります。
    やっぱり音ですよね、最低でも効果音くらいは欲しいです。

    それに、9.5~10.5秒って思ったより難しい。
    子どもたちに遊んで貰うにしても、簡単に成功できないので難易度を下げたいといった不満点、気になる点が多々あると思います。

    成功範囲はこの部分の値を変更すればいいのですが…

        Time_Lw = 9.5                                           '成功範囲(下限)の設定
        Time_Hi = 10.5                                          '成功範囲(上限)の設定

    毎回、会場の様子を見て係員がコードを入れ替えるのは少々危険。
    コードを触るのに慣れている方ばかりではないでしょう。
    ワークシートから取得できるようにするといった工夫もしたい。ですね。
    やっぱりアプデ欲しいですよね?

    それと、すごく簡単なコードなんですけどIf文による複数の分岐、文字列配列操作など、プログラミングを始めたばかりの方には結構学びになる箇所も含まれています。

    これがぱぱっと作れるようになると、実は初心者卒業なのではないかとも思ったりします。

    というわけで次回以降、応用編として機能追加するか、もしくはコードの解説編をするか…とにかく、もうちょっとだけ続きます。

    では、また次の記事でお会いしましょう!

    次の記事は下の埋め込みリンクからどうぞ!(2026.09.30公開)


    ここからはオススメ記事の紹介です。

    システム系の勉強したいなーって方にはコチラがオススメです。
    関連記事を以下にまとめてます!(↓)

    「読むとゲームができるマガジン」もオススメです。
    Unityのお話もありますが、Excelである程度のゲームは作れますよ(↓)



    あなたへのおすすめ