メインコンテンツへスキップ
見出し画像

Excel(VBA)で10秒を狙ってお菓子をもらおう![応用編]お祭りで使えるミニゲームを作る!

    こんにちは「つけらっとゲームス」プログラム担当のとちです。
    前回、Excel(VBA)で作った10秒チャレンジゲームですが、遊べる状態ではあるもののお祭り会場での運用を考えると微妙。そして味気ない。

    というわけで今回は応用編としてアプデしますよ!
    おっとその前に、続き物の記事ですので前回をご覧になっていない場合はまずは下の埋め込みリンクの記事をご覧ください~

    で、アプデしてどんな感じになるか、なんですけど…
    ご覧のような感じになります!って変わってないわ!

    画像
    見た目は以前と変わらず…だけどパワーアップしてます!

    じゃぁ何が変わったのか?
    元々が簡単に、それこそプログラミング学習の経験がない方でも作れるミニゲームでしたが箇条書きすると結構なアプデボリュームだったりします。

    • サウンドが追加されます!

    • ワークシートで音量を変更できます!

    • ワークシートで10秒チャレンジの成功範囲を変更可能!

    • ゲーム中のメッセージもワークシートで管理!

    はい、これらを一気にやります。
    準備はよろしいですか? 覚悟が決まったら先に進みましょう!


    まずは環境を整えたい!

    前回作ったExcelファイルがあるフォルダを開いてください。例では10SecondChallenge.xlsmというファイル名にしていました。実際に作業をしたら同じフォルダに背景画像が残っているかもしれませんね。

    その階層に新しいフォルダ「sounds」を作ってください。
    すると、下のスクショのような感じになりますよね?

    画像
    soundsフォルダを追加!

    このフォルダにはそのフォルダ名のとおり音楽ファイルを入れます。
    必要なファイルは以下の4つです。

    • BGM1 …… ゲームスタートからストップを押すまでのチクタク音

    • SE1 …… ユーザーフォームのボタンをクリックした時の効果音

    • SE2 …… 10秒チャレンジ成功した時の効果音

    • SE3 …… 10秒チャレンジ失敗した時の効果音

    今回の例を作りにあたり「効果音ラボ」さんから素材をお借りしました。皆さんもお好みの効果音を準備してくださいね。

    例と同じものを作りたい方に向けてリンクを貼っておきます。
    あ、そうそ、こういう素材サイトさんからお借りする際は「利用規約」を確認する癖をつけましょう。

    【※ なんで効果音素材をここに置いてないの?】
    ゲームの作り方を説明するんだから素材類もここに貼り付けて、すぐに作れるようにしておけばいいのに…とはわたしも思うんですけど、これって再配布に当たりますよね。んで効果音ラボさんの規約を見ると再配布は禁止。

    なので、弊サークルの同テーマ記事では、使う素材はご自分でどれを使用すればゲームにピッタリかを考えながら、ご自分にあったモノをDLしてください。という案内をするようにしています。面倒臭いと感じるかもしれませんが、ご了承くださいませ!

    このゲームの雰囲気にピッタリそうな効果音、わたしの感性では以下スクショにある4つのファイルだと思ったのでDLします!

    画像
    DLしたのはこの4つ

    このままだとプログラム内では使いにくいので名前を変更します。
    変更した結果は以下のスクショの様になります。

    画像
    ファイル名変更後はこんな感じになります。

    フォームのアプデ作業!

    ゲーム内でサウンド再生するためにフォームもちょっとだけアプデ作業をしたいところですが、その前に…

    画像
    ツールボックスを確認!

    ツールボックスにWindowsMediaPlayerコントロールが追加されている必要があります。やり方は次の埋め込みリンクの記事内にある「コントロールの追加」をご覧ください。

    それでは先程のWindowsMediaPlayerコントロールを2つ追加しましょう。
    このオブジェクトはプログラムから非表示にするので大きさは大体でいいです。どうせ見えなくなるし、勝手にサイズ変更されちゃうので…

    画像
    WindowsMediaPlayerを2つ作ってね!

    でもオブジェクト名だけは揃えましょう!
    オブジェクト名は「WMP1」「WMP2」に変更してくださいね。

    画像
    オブジェクト名はこの位置にあります。変更しましょ!

    ワークシートのアプデ作業

    ワークシート側も作業しておきます。シートは2つ用意しましょう。
    シートの名前も例と同じにしてください。
    片方は「config」です。もう片方は「text」にします。

    画像
    プログラムではB列しか使わないけど、他も同じにしてね!
    画像
    プログラムではA~B列しか使わないけど、他も同じにしましょ!

    シート内容もスクショと同じようにしてください。
    プログラムで見ているのは一部ですが、それが何を意味しているのか忘れちゃったら大変なので、項目名や備考も残しておくと良いでしょう。

    とはいえ、同じデータを打つのも大変ですよね。
    csv形式で置いておくので、コイツの内容を貼り付けてもOKです。

    こちらが「config」に貼り付けるデータです。

    こちらが「text」に貼り付けるデータです。


    コードの差し替え!

    最後にコードを差し替えます。
    元々のコードを全て消去したら、以下のコードを丸々コピペしましょう。
    コードの内容については後述します。

    Option Explicit
    Dim Time_Sta        As Double                               '【変数定義】スタートボタンを押した時間
    Dim Time_End        As Double                               '【変数定義】ストップボタンを押した時間
    Dim Time_Ans        As Double                               '【変数定義】経過時間(回答)
    Dim Time_Lw         As Double                               '【変数定義】成功範囲(下限)デフォルトでは 9.5秒
    Dim Time_Hi         As Double                               '【変数定義】成功範囲(上限)デフォルトでは10.5秒
    Dim GameMsg(1 To 5) As String                               '【配列定義】[UPD]ゲーム画面に表示するメッセージ
    
    Dim BGMLoopSW  As Integer                                   '【変数定義】[ADD] BGMループスイッチ [0]ループしない [1]する
    Dim Vol_BGM    As Integer                                   '【変数定義】[ADD] 音量 - BGM(%)
    Dim Vol_SE     As Integer                                   '【変数定義】[ADD] 音量 -  SE(%)
    
    '------------------------------------------------------------
    '   [UPD] フォーム初期化時
    '
    '   引数    :なし
    '   戻り値  :なし
    '------------------------------------------------------------
    Private Sub UserForm_Initialize()
        
        Dim wsC As Worksheet                                    '【変数定義】ワークシート config
        Dim wsT As Worksheet                                    '【変数定義】ワークシート text
        Dim i   As Integer                                      '【変数定義】ループカウンタ用(index)
        Set wsC = Worksheets("config")                          ' 変数にワークシート config をセット
        Set wsT = Worksheets("text")                            ' 変数にワークシート text   をセット
        
        Time_Lw = wsC.Cells(3, 2).Value                         ' 成功範囲(下限)の設定
        Time_Hi = wsC.Cells(4, 2).Value                         ' 成功範囲(上限)の設定
        
        '--
        '-- ゲーム画面に表示するメッセージを格納
        '--
        For i = 1 To UBound(GameMsg)                            ' ■ GameMsg配列の終端までループ
            GameMsg(i) = wsT.Cells(i, 1) & vbCr                 ' ├ i行 1列 取得し改行コードを付加する
            GameMsg(i) = GameMsg(i) & wsT.Cells(i, 2)           ' ├ i行 2列 取得する
            GameMsg(i) = Ret_GameMessage(GameMsg(i))            ' ├ メッセージの中に「#」があるかチェック
        Next i                                                  ' └ ループ終端
    
        Vol_BGM = wsC.Cells(1, 2).Value                         ' ワークシートからBGM音量取得
        Vol_SE = wsC.Cells(2, 2).Value                          ' ワークシートから SE音量取得
        WMP1.settings.volume = Vol_BGM                          ' WindowsMediaPlayer1 - BGM音量の反映
        WMP2.settings.volume = Vol_SE                           ' WindowsMediaPlayer2 -  SE音量の反映
        WMP1.Visible = False                                    ' WindowsMediaPlayer1 の非表示
        WMP2.Visible = False                                    ' WindowsMediaPlayer2 の非表示
        Call Btn_Reset_Click                                    ' ゲーム開始時のボタン設定
    
    End Sub
    
    '------------------------------------------------------------
    '   スタートボタン クリック時
    '
    '   引数    :なし
    '   戻り値  :なし
    '------------------------------------------------------------
    Private Sub Btn_Start_Click()
    
        Dim BGMPath As String
    
        Time_Sta = Timer                                        ' スタートボタンを押した時間取得
        Lbl_Time.Caption = "--.----秒"                          ' 秒数表示の変更
        Lbl_Msg.Caption = GameMsg(2)                            ' メッセージの変更
        Btn_Start.Enabled = False                               ' スタートボタン 押せない
        Btn_Stop.Enabled = True                                 ' ストップボタン 押せる
        Call SoundEffectPlay(1)                                 ' [ADD]クリック音
    
        BGMLoopSW = 1                                           ' [ADD]BGMをループさせる
        BGMPath = ThisWorkbook.Path & "\sounds\BGM1.mp3"        ' [ADD]BGMフルパス
        WMP1.Controls.stop                                      ' [ADD]WindowsMediaPlayer1 停止
        WMP1.Url = BGMPath                                      ' [ADD]WindowsMediaPlayer1 に BGM1のファイルパスを入れる
        WMP1.Controls.Play                                      ' [ADD]WindowsMediaPlayer1 再生
    
    End Sub
    
    '------------------------------------------------------------
    '   ストップボタン クリック時
    '
    '   引数    :なし
    '   戻り値  :なし
    '------------------------------------------------------------
    Private Sub Btn_Stop_Click()
    
        Dim Time_Txt As String                                  '【変数定義】秒数表示の編集用
        Time_End = Timer                                        ' ストップボタンを押した時間取得
        Time_Ans = Time_End - Time_Sta                          ' 経過時間(回答)の算出
    
        '--
        '-- 表示秒数の編集
        '--
        Time_Txt = Format(Time_Ans, "0.0000") & "秒"            ' 表示は小数点第四位までとする
        If Time_Ans < 10 Then Time_Txt = " " & Time_Txt         ' 10秒未満の場合 桁揃えのために頭に半角スペースを追加
        Lbl_Time.Caption = Time_Txt                             ' 経過時間(回答)の画面表示
    
        If Abs(Time_Ans - 10) < 0.0001 Then                     ' ■[ADD]経過時間(回答)がピッタリ10秒...ほぼ発生しないけど
       'If Time_Ans = 10 Then                                   ' ■[DEL]経過時間(回答)がピッタリ10秒...ほぼ発生しないけど
            Lbl_Msg.Caption = GameMsg(3)                        ' ├10秒用のメッセージ表示
            Call SoundEffectPlay(2)                             ' ├[ADD]成功音
        ElseIf Time_Ans >= Time_Lw And Time_Ans <= Time_Hi Then ' ■経過時間(回答)が成功範囲内の場合
            Lbl_Msg.Caption = GameMsg(4)                        ' ├ほぼ10秒用のメッセージ表示
            Call SoundEffectPlay(2)                             ' ├[ADD]成功音
        Else                                                    ' ■経過時間(回答)が成功範囲外の場合
            Lbl_Msg.Caption = GameMsg(5)                        ' ├失敗用メッセージ表示
            Call SoundEffectPlay(3)                             ' └[ADD]失敗音
        End If
            
        Btn_Stop.Enabled = False                                ' ストップボタン 押せない
        Btn_Reset.Visible = True                                ' リセットボタン 表示
        BGMLoopSW = 0                                           ' [ADD]BGMをループさせない
        WMP1.Controls.stop                                      ' [ADD]BGMストップ
    
    End Sub
    
    '------------------------------------------------------------
    '   リセットボタン クリック時
    '
    '   引数    :なし
    '   戻り値  :なし
    '------------------------------------------------------------
    Private Sub Btn_Reset_Click()
    
        Lbl_Msg.Caption = GameMsg(1)                            ' [UPD]最初のメッセージ
        Lbl_Time.Caption = "10.0000秒"                          ' 秒数表示を10.0000秒にしておく
        Btn_Start.Enabled = True                                ' スタートボタン 押せる
        Btn_Stop.Enabled = False                                ' ストップボタン 押せない
        Btn_Reset.Visible = False                               ' リセットボタン 非表示
        Call SoundEffectPlay(1)                                 ' [ADD]クリック音
    
    End Sub
    
    '------------------------------------------------------------
    '   [ADD] Ret_GameMessage ゲームメッセージチェック
    '
    '   引数  :ワークシートから取得したメッセージ
    '   戻値  :編集後のゲームメッセージ
    '------------------------------------------------------------
    Private Function Ret_GameMessage(ChkTxt As String) As String
        
        Dim ChkC    As String                                   '【変数定義】1文字毎チェック用
        Dim RetTxt  As String                                   ' 返答用文字列
        Dim i       As Integer                                  ' ループカウンタ
        
        For i = 1 To Len(ChkTxt)                                ' ■文字列を頭から最後まで1文字毎にチェック
            ChkC = Mid(ChkTxt, i, 1)                            ' ├ 1文字だけ取得
            If ChkC = "#" Or ChkC = "#" Then                   ' ├◆取得した1文字が#(or #)だった場合
                ChkC = Time_Lw & "~" & Time_Hi                 ' │└成功範囲を差し替える
            End If                                              ' │
            RetTxt = RetTxt & ChkC                              ' ├返答用文字列に追加
        Next i                                                  ' └ループ終端
        Ret_GameMessage = RetTxt                                ' 返答用文字列を戻値とする
    
    End Function
    
    '------------------------------------------------------------
    '   [ADD] WMP1 再生状態の変化時
    '
    '   引数  :NewState
    '   戻値  :なし
    '------------------------------------------------------------
    Private Sub WMP1_PlayStateChange(ByVal NewState As Long)
        If BGMLoopSW = 0 Then Exit Sub                          ' BGMLoopSWが[0]ループしない の場合 >> このサブルーチンを抜ける
        If NewState = 1 Or NewState = 8 Then WMP1.Controls.Play ' 再生状態の変化による戻値が 1(停止) or 8(音楽終了) の場合 >> 再び再生する
    End Sub
    
    '------------------------------------------------------------
    '   [ADD] サウンドエフェクト発生処理
    '
    '   引数  :SENo    [1]クリック音    [2]成功音    [3]失敗音
    '   戻値  :なし
    '------------------------------------------------------------
    Private Sub SoundEffectPlay(SENo As Integer)
        If SENo = 0 Then Exit Sub                               ' 効果音SWが0の場合は処理せず抜ける
        Dim SEPath As String                                    ' 効果音のパス
        SEPath = ThisWorkbook.Path & "\sounds\SE"               ' 効果音のパスの文字列編集
        SEPath = SEPath & SENo & ".mp3"                         ' 効果音のパスの文字列編集(SE番号を付加)
        WMP2.Controls.stop                                      ' WindowsMediaPlayer2 停止
        WMP2.Url = SEPath                                       ' WindowsMediaPlayer2 SEのファイルパスを入れる
        WMP2.Controls.Play                                      ' WindowsMediaPlayer2 再生
    End Sub
    
    

    アプデ作業としてはこれで終了です。おつかれさまでした。

    コードの中身については次節をご覧ください。
    とりあえず難しいことを考えたくない方は読み飛ばして構いません。
    必要になった時(改めて勉強しようと思った時)に読み直してください!


    コードを軽く説明!

    ご覧の通りクソ長コードです。
    中身を詳しく説明すると皆さんが睡眠の状態異常を喰らっちゃうので軽めに説明しますね。授業でも長々と説明するよりは早く実習した方が楽しいのと同じ、黙って聞いているよりは手を動かした方が刺激になるもんね。

    学校の勉強ではないので面倒臭い、難しいと思ったら読み飛ばそう…

    前回記事で貼り付けたコードと変わったところからお話しますと、コード内で[ADD]とコメントが付いてるプロシージャや行が追加されたものです。

    また、[DEL]とコメントがついている行は前回までは使用されていたもののコメントアウトして、それに代わる行が[ADD]されています。

    [UPD]と付いているものは変更があったという意味となります。
    前回のコードと比較して解析してみると良い勉強になると思います。

    【各プロシージャの説明】

    プログラミングの勉強をした方や経験を積んだ方であれば、各役割毎に関数化されていて、後々メンテしやすくなっていると気づくと思います。逆に、まだ慣れていない方だとアッチコッチに処理が飛んでいるので難しく感じると思います。なので、各プロシージャで何しているかをお話します。

    これがわかれば、大まかに何をしているかが理解できると思います。
    1行毎の説明についてはコード内コメントをご覧ください。

    ・UserForm_Initialize()

    これはユーザーフォーム初期化時に動くプロシージャです。
    このプロシージャは前回記事から大幅に変更されていますね。

    ゲームの初期設定を行うのが主な役割で、アプデによってシートconfigからゲーム設定を読み込む機能が、textからはゲーム内メッセージを読み込む機能が追加されています。

    少し注目していただきたいのが、このあたり…

    Time_Lw = wsC.Cells(3, 2).Value                         ' 成功範囲(下限)の設定
    Time_Hi = wsC.Cells(4, 2).Value                         ' 成功範囲(上限)の設定

    このプロシージャでは頻繁に出てくる「Cells~」という表記ですが、これは指定されたワークシートのy行目x列目の値を取得しています。これによって必要なデータを、対象となる変数に入れているんですね。

    次に注目すべき箇所は「ゲーム画面に表示するメッセージを格納」とコメントが付いているFor文です。ここでもワークシートからゲームで使用するメッセージを取得していますよね。

    その取得したメッセージを一旦、ユーザ定義関数 Ret_GameMessage に通しています。この関数は後述するのでお楽しみに!

    その他にはWindowsMediaPlayerの音量設定と非表示化、ゲーム開始時の画面設定も行っていますね。

    ・Btn_Start_Click()

    スタートボタンをクリックした時に動くプロシージャです。
    Timer関数を使って、このボタンをクリックした時間取得をしています。

    アプデで追加されたのは音関連の処理ですね。
    ここからストップボタンを押されるまでチクタク音がループ再生されます。

    ・Btn_Stop_Click

    ストップボタンをクリックした時に動くプロシージャです。
    Timer関数を使って、このボタンをクリックした時間取得をします。
    さっき、スタートボタンを押した時間取得もしていますので、その差を求めることで10秒チャレンジ判定をしています。

    アプデで追加が行われた処理を確認すると、そのほとんどが音関係の処理なんですけど、10秒ピッタリ判定が更新されているのがわかります。

    If Time_Ans = 10 Then

    だったモノが、以下のように修正されています。

    If Abs(Time_Ans - 10) < 0.0001 Then

    これが何故かを説明すると…難しいなと思ったら読み飛ばしてね。

    Time_Ansの変数型は倍精度浮動小数点(Double)型です。ピッタリ10秒になる確率はほぼありません。人間的に10秒だと思っても10.00003秒、9.99997秒といった微妙なズレがあったりします。

    例えば、ゲーム結果が10.00003秒だったとしましょう。
    この結果を使ってコードの処理を追ってみます。
    まず、10.00003 - 10 されるので、0.00003となりますね。

    Abs関数は絶対値を求める関数です。-0.00003だった場合でも0.00003として扱います。つまりゲーム結果が9.99997秒だった場合も0.00003となります。

    では計算の続きを見ていきましょう。

    If 0.00003 < 0.0001 then 

    この比較であればif文の判定はtrue、つまりピッタリ扱いになります。
    ゲームとして考えれば、10.00003秒と10秒を区別しなくていいでしょう!
    これが変更した理由です。

    ・Btn_Reset_Click()

    「最初に戻る」ボタンをクリックした時の処理です。
    フォーム初期化時も、このプロシージャを利用し初期画面にしています。

    このプロシージャはアプデで大きな変更はありません。
    ゲーム内メッセージの扱いが変わったのと、ボタンをクリックした時の効果音の発生が変化したところですね。

    ・Ret_GameMessage()

    追加されたファンクションです。
    ここではワークシート text から取得した文字列をチェックしています。
    なにをチェックしているのかというと…コードを覗いてみますね。

    If ChkC = "#" Or ChkC = "#" Then 

    取得した文字列を1文字毎にチェックし、その文字が「#」または「#」なのかを確認していますね。そして、

    ChkC = Time_Lw & "~" & Time_Hi

    「#」を「成功範囲の下限~上限」に差し替えています。
    これ文字列の中に含まれるタグを探しているんです。

    今回差し替えるのが「成功範囲の下限~上限」だけなので「#」を探していますが、例えば「#time」なら成功範囲、「#question_x」なら指定されたx秒チャレンジにする、といったことが可能となります。

    ワークシートに自分以外の係員が入力しただけでゲームのルールまで変更可能って、……なんか、ワクワクしてきません?

    ・WMP1_PlayStateChange()

    WMP1の再生状態の変化時に動くプロシージャです。
    チクタク音は1回再生されたら終わり、ではなくゲーム中にずっと再生されるべき音です。停止したり終了したらもう1度再生する処理を行います。

    ・SoundEffectPlay()

    効果音を再生するプロシージャです。効果音再生を担当するのはWMP2ですね。引数で指定された効果音を再生します。


    おわりに

    チクタク音が追加されたことによって、ちょっと鋭いお子さんは、このチクタク音でタイミングを計り成功率を上げてくると思われます。

    例と同じチクタク音を実装された方は試してみてください。12~13回くらいのチクタクあたりでストップを押すと10秒前後になります。本当の肌感だけで10秒を狙うガチイベントならコンフィグのBGM音量を0%にしましょう。

    そんなガチイベント、ちょっと嫌だな…

    今回も思ったより長い記事になってしまった。
    でも、ですよ、これって結構大きな成長なんすよ。

    プレイヤー視点でみると音が追加された点がすごく大きく変化した箇所のように感じますが、実はこれ作った皆さんがイベント会場にいなくても、係員がワークシートをちょこちょこっと触ると設定が変わるという…思っている以上に大きな便利機能が追加されたアプデなんですよ。

    そして、その便利機能によってルールまで変更できちゃうという。
    なんかすっごく成長した気分になりませんか?

    え? ならない? あれ? 
    いや、これってマジで作っている人にとっては普通って思うでしょうけど、これができれば中級者と言ってもいいんじゃないかと…習い始めの学生がこれ実装してたら、わたしは評価しますよ!

    長い記事を読んでくださりありがとうございます。
    そして実作業された方はお疲れ様でした!

    また別の記事でお会いしましょう!


    ここからはオススメ記事の紹介です。

    システム系の勉強したいなーって方にはコチラがオススメです。
    関連記事を以下にまとめてます!(↓)

    「読むとゲームができるマガジン」もオススメです。
    Unityのお話もありますが、Excelである程度のゲームは作れますよ(↓)

    あなたへのおすすめ