メインコンテンツへスキップ
見出し画像

Excel(VBA)でスライドパズルを作ろう!

    こんにちは「つけらっとゲームス」プログラム担当のとちです。
    今回はExcel(VBA)でスライドパズル(15パズル)を作ります!

    Excel(VBA)でマインスイーパーを作った回は難易度が少し高めでした。
    さて今回は…Excel(VBA)だけで全て完結しようと思ったら難易度が高くなってしまうので、少々手間ですが画像ファイルを別途準備する形式で進めて行きたいと思います。

    というわけで完成すると、こんな感じのスライドパズルになります。

    思ったより「ちゃんとしたスライドパズル」ですよね!?

    いつものようにユーザーフォームを挿入、各オブジェクトを作っていき最後にソースを丸ごとコピーする流れで作成していきます。

    なお、この記事のスクショについて、わたしのPCに入っているMicrosoft office Home and Business 2016でスクショを撮りました。

    ですので微妙に表示が異なる可能性がありますが、デスクトップ版のExcelであれば、開発に使用するVBA(Microsoft Visual Basic for Applications)は同じで作業内容も変わりません。Microsoft365のExcelでも動作します。

    それと、開発前に環境を整える必要があります。
    以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「Excelの準備」を参照してVBAを使えるようにしておきましょう。

    また「読むとゲームができる」記事は以下のマガジンにまとめています。
    他のゲームの解説もあるので、マガジンの中からお好みのゲームを探してみてくださいね!


    開発環境を準備する

    「Excelの準備」を参照してVBAを使えるようにできたら、こんなフォルダを準備しておきましょう。

    画像

    SlidePzl.xlsmが実際にスライドパズルを動かすExcelファイルです。
    このExcelファイルと同じ階層に「PuzzleData」「Sound」のフォルダを作っておきます。

    画像ファイルの準備

    次は必要な素材を準備します。
    今回はコチラのサイトからお借りしております。ありがとうございます。

    いつもお世話になっているOKUMONOさん。
    やわらかく、かわいらしい素材がたくさんあります。

    DLしたのは「背景」「ネコの顔」です。
    色やキャラクターは好みで構いません!

    使用できる画像形式について

    Excel(VBA)ではpng形式を使えません。jpg形式に変換する必要があります。Photoshop、Gimpあたりの画像編集ソフトを使用できる方はそちらで編集していただいて構いません。

    Windows付属のペイントでも十分可能ですが、やったこと無い方や、自信が無い方は「必要な素材を準備する」をご覧ください。

    画像サイズの目安について

    ・背景 1137×640 ピクセル
    ・ネコ 120×120 ピクセル

    画像編集ソフト(ペイントなど)で上記サイズに揃えると作りやすいです。


    効果音の準備

    次は効果音を用意しましょう。

    DLしたのは以下の3つです。
    「カーソル移動8」「カードを台の上に出す」「決定ボタン8」
    これらをプログラム中で使いやすくするために名前を変更しておきます。

    「カーソル移動8.mp3」を「SE1.mp3」に、
    「カードを台の上に出す.mp3」を「SE2.mp3」に、
    「決定ボタン8.mp3」を「SE3.mp3」にリネームします。

    リネームした3つのファイルを「Sound」フォルダに入れます。

    画像
    ファイル名を変更して、Soundフォルダに入れとく!

    タイル用画像の準備

    次は実際にスライドパズルとして使用する画像です。
    今回は用意した画像がありますのでご利用ください。

    Zipファイルを解凍するとtile0~tile16.jpgファイルになります。
    これを「PuzzleData」フォルダに入れます。

    tile0.jpgは分割する前の元画像ファイルです。
    4×4のグリッド状に分割しています。
    tile1~tile16の位置関係は以下の画像のとおりです。

    画像
    解凍したら、この画像ファイルを PuzzleData フォルダに入れます。

    同じような画像ファイルがあれば、あなただけのスライドパズルを遊べるようになります。

    画像
    こんな感じで、自分の好みのパズルを作れるよ!

    上の画像のデータはいらすとやさんのチャボだったりします。
    ここで画像ファイルを配布すると二次配布になっちゃうので、お手数をおかけして申し訳ないのですがご自分でご用意ください…

    本当はExcel(VBA)の中で画像を分割しようと思ったんです。
    が、ワークシート上ならshapeでそれっぽいことはできるんですよ、でもユーザーフォーム上だといい方法が思いつかない。

    多分、APIを使わないと無理そう…となると、わたしもやったことないから試してみないと、っていうか初心者向けからも逸脱しちゃう?

    ってことで今回は…とりあえずコチラで準備したZIPファイルをダウンロードして進めましょう。


    ユーザーフォームを作る

    素材が揃ったら以下の作業に進んでください。

    最初にやるべきことは「挿入」>「ユーザーフォーム」でまっさらなユーザーフォームを準備することです。

    画像

    (1)挿入→(2)ユーザーフォーム と選択すると UserForm1 が作られます。
    (3)作られたUserForm1のどこかをシングルクリックすると、(4)プロパティ欄にクリックされたコントロール(オブジェクト)の内容が表示されます。

    次の画像はユーザーフォームのプロパティ欄です。
    これと同じような設定に変更します。

    画像

    (オブジェクト名)はUserForm1です。

    「Picture」を選ぶと上のスクショのように右端にボタンが表示されます。
    クリックするとファイル選択のダイアログが表示されるので、用意した背景画像を選択しましょう。

    「Height」を510にし、「Width」を864にすると、サンプルと同じ大きさになります。「PictureAlignment」を「0-fmPictureAlignmentTopLeft」にすると背景画像が左上にピッタリくっつきます。

    今後は、コントロール(オブジェクト)をフォームに配置し、そのプロパティ欄の値をサンプルのように真似て修正する作業を繰り返します。

    今回使用するコントロールは、下のスクショのとおりです。
    ツールボックスから必要なコントロールをクリックし、フォーム上にドラッグすることで各オブジェクトを配置できます。

    画像

    ツールボックスですが「ラベル」「コマンドボタン」「オプションボタン」「イメージ」は初期設定で表示されています。

    ただし「WindowsMediaPlayer」が表示されていない場合があります。
    コチラの記事「Excel(VBA)のゲームでBGMを流したい」から「コントロールの追加」ご覧ください。


    完成図オブジェクトの設置

    では、さっそくオブジェクトを配置していきます。
    とりあえず、ツールボックスからイメージを選んでフォーム上に適当に配置します。すると、以下のように灰色の四角が作られます。

    画像

    このImageオブジェクトは完成図を表示する為のモノなので大きい四角にします。では、サンプルのプロパティ欄を真似て各項目を変更します。

    画像

    (オブジェクト名)をImage0に変更します。

    「Height」を 400 にします。「Width」を 400 にします。
    これはフォームの大きさでも出てきましたね。

    「Left」を100にして「Top」を42にします。
    これが配置する位置になります。

    「PictureAlignment」は 2-fmPictureAlignmentCenter です。
    イメージオブジェクトの中でのピクチャの配置位置です。

    「PictureSizeMode」を 1-fmPictureSizeModeStretch にします。
    この設定でピクチャがイメージオブジェクトのサイズより小さい場合は引き延ばしてくれます。ピッタリ合わない時に便利ですね。

    なお「Picture」はコードで呼び出すので変更する必要はありません。


    タイル画像オブジェクトの設置

    次にパズルで使用するタイル画像のイメージを配置します。
    ツールボックスからイメージを選び、16個のオブジェクトを作ります。
    この時点では大きさや場所はおおまかなもので構いません。

    画像

    というのも、コード内でタイルの大きさと位置、つまり「Height」「Width」「Left」「Top」を調整しているからです。
    「PictureSizeMode」もコード中で変更していますが、開発中のフォームを整えるためにも、この後のスクショを真似て変更しておくと良いでしょう。

    (オブジェクト名)を見て足りないものがないか確認も忘れずに!

    ではタイルに使用するイメージのプロパティを16個連続表示!
    小さくなってしまったので、クリックして拡大してご覧ください。

    画像
    画像
    画像
    画像

    次にタイル番号のラベルを配置します。
    ツールボックスからラベルを選び、16個のオブジェクトを作ります。
    こちらの大きさや場所も現時点ではある程度テキトーで大丈夫です。

    画像

    コード内でタイル番号の「Height」「Width」「Left」「Top」を調整していますが、やはり開発中のフォームを整えるためにも、この後にあるスクショを真似てプロパティ欄を変更しておきます。

    (オブジェクト名)を見て、足りないものがないか確認を忘れずに…
    「Font」は好みのフォントを選択して構いません。

    ではタイル番号に使用するラベルのプロパティを16個連続表示!
    小さくなってしまったので、クリックして拡大してご覧ください。

    画像
    画像
    画像
    画像

    最後にImage99を作っておきます。
    ツールボックスからイメージを選び、Image0と同じくらいの大きさのイメージオブジェクトを作ります。位置や場所はおおまかで構いませんが、これまで作ったタイルやタイル番号の上に被せておきます。

    画像

    次のスクショはImage99のプロパティ欄です。
    (オブジェクト名)をImage99に変更します。

    「BackStyle」を 0-fmBackStyleTransparent にします。
    これで灰色の四角が透明になります。

    Image99についても「Height」「Width」「Left」「Top」等はプログラムの中で調整していますが、開発中のフォームを綺麗に保つためにはスクショを真似て変更しておくと良いでしょう。

    画像

    【注意】オブジェクトの重なり順

    ここまで作ってきたオブジェクトは、大きく4つに分けられます。

    画像

    次の図をご覧ください。
    「Image0」がこの中で最も背面に配置されている必要があります。
    「Image1~16」がその次、「Label1~16」がその次に配置されおり、
    「Image99」がこの中で最も前面にあります。

    画像

    順番通りに作っていれば問題ないのですが、ちょっとした操作ミス等で表示順が変わっている可能性があるので注意が必要です。

    もし表示されている順番が変だなーと思ったら次のスクショのとおり、
    「書式」→「順序」→を使って順番を整えます。

    画像

    UI等の設置

    ここまで何個もオブジェクトを作ってきました。
    そろそろ疲れてきた頃ですよね。でも作るオブジェクトはあと少し…頑張りましょう!

    コマンドボタンを作る

    ツールボックスから「コマンドボタン」を選んで3つ作ります。
    後でプロパティ欄を見て調整するので、大きさと位置は雰囲気で大丈夫!

    画像

    これらのコマンドボタンはコード内では特に調整をしていません。
    なので、次のプロパティ欄と見比べて内容を修正してください。

    とは言っても、タイルとは異なり多少ズレていてもゲーム進行には影響しないんですけどね…「Font」は好みで構いません。

    (オブジェクト名)だけ揃っていれば大きな問題はないハズです。

    画像

    ラベルとイメージの追加

    ツールボックスから「ラベル」を選んで2つ追加します。
    それが終わったら「イメージ」を選んで1つ追加してください。

    画像

    次のスクショは「ラベル」と「イメージ」のプロパティです。
    これらはコード内で調整していないのでスクショと同じように変更します。

    これまで同様に「Font」は好みで構いません。
    (オブジェクト名)だけ揃っていれば大きな問題はないハズ…
    Image100の「Picture」は素材として準備したネコを選びましょう。

    画像

    オプションボタンを追加

    ツールボックスから「オプションボタン」を選んで3つ追加します。

    画像

    綺麗に並べた方が良いので、この後のスクショを真似てプロパティ欄を修正してください。

    ここは(オブジェクト名)を少し修正しているので正確に揃えましょう。
    これまで同様に「Font」は好みで構いません。

    「OptBtn1」の「Value」を「True」にしておきます。
    「OptBtn2」と「OptBtn3」は「Value」を「False」にします。

    画像

    WindowsMediaPlayerを追加

    ツールボックスから「WindowsMediaPlayer」のアイコンを選んで追加します。このオブジェクトはゲームが始まるとユーザーには見えないモノなので、画面の端に設置しておきましょう。

    画像

    (オブジェクト名)を「WMP1」にします。
    ユーザーから見えないようにするので「Visible」を「False」にします。

    画像

    ソースコードをコピペ!

    ここまで結構な量のオブジェクトを作りプロパティを変更しました。
    ここまで作った以上は動かしたい。もう少しです。頑張りましょう。

    まず、(1)プロジェクトウィンドウの「ThisWorkbook」をダブルクリックします。するとフォームが表示されているところが、コード入力できる画面に切り替わります。

    画像

    (2)コード入力できる画面になったら、上のスクショの部分に次のコードをコピペしましょう。

    Private Sub Workbook_Open()
        UserForm1.Show
    End Sub

    これは「このエクセルファイルを開いたらユーザーフォーム1を見せる」という意味です。


    引き続き、(1)プロジェクトウィンドウの「UserForm1」をダブルクリックします。するとフォームが表示されます。

    画像

    (2)「完成図を見せて!」ボタンをダブルクリックします。

    実際にはフォームの何も無いところや、他のボタンでも構いません。
    フォームに配置されているオブジェクトをダブルクリックすると、そのボタン等のイベントプロシージャが表示されます。

    (3)コードを入力する画面が表示されますが、そこに書かれている2行ほどのコードを、一旦消します!

    画像

    2行ほどのコードを消したら、そこに以下のコードを全部コピペします。(※ 2025.07.05 不具合があったので一部修正しました)

    Option Explicit
    
    Dim tOBJ(0 To 16) As Object                                 '【変数定義】タイル(イメージ)
    Dim tLbl(1 To 16) As Object                                 '【  〃  】タイルNo(ラベル)
    Dim xBase   As Integer                                      '【  〃  】元画像のx初期位置(タイル配置のx基準)
    Dim yBase   As Integer                                      '【  〃  】元画像のy初期位置(タイル配置のy基準)
    Dim wFolder As FileDialog                                   '【  〃  】フォルダー指定用のダイアログ
    Dim wPath   As String                                       '【  〃  】画像ファイルが入っているフォルダのパス
    Dim fPath   As String                                       '【  〃  】画像ファイルのパス
    Dim sPath   As String                                       '【  〃  】サウンドエフェクトのパス
    Dim EReadSW As Integer                                      '【  〃  】読込エラースイッチ     [1]画像読み込み時にエラーが発生した
    Dim HintSW  As Integer                                      '【  〃  】ヒント表示スイッチ     [1]完成図を表示中
    
    '----------------------------------------------------------------
    ' ユーザーフォームの初期化時
    '----------------------------------------------------------------
    Private Sub UserForm_Initialize()
        Randomize                                               ' 乱数の初期化
        Call FormImageSet(0)                                    ' フォームとイメージの配置(0:初期配置)
        tileNoColorChange                                       ' タイル番号の表示色を変更
                                                                '
        CommandButton2.Enabled = False                          '[無効化]「同じ画像でスタート!」ボタン
        CommandButton3.Enabled = False                          '[ 〃 ]「完成図を見せて!」ボタン
        Image99.Enabled = False                                 '[ 〃 ]タイル全体の上に被せているImageコントロール
                                                                '
        Label18.Caption = Chr(13) & " 画像を選んでね!"         ' ゲームメッセージの表示
        sPath = ThisWorkbook.Path & "\Sound\"                   ' ファイルパスに効果音データが入っているフォルダ名を格納
                                                                '
    End Sub
    
    '----------------------------------------------------------------
    '   「画像を選択してスタート!」ボタンをクリック時
    '----------------------------------------------------------------
    Private Sub CommandButton1_Click()
        
        Call SoundEffectPlay(1)                                 '[効果音]ボタンクリック音
                                                                '
        Set wFolder = Application.FileDialog(4)                 ' フォルダ選択ダイアログの設定(4 : msoFileDialogFolderPicker)
        wFolder.Title = "フォルダを選択してください"            ' フォルダ選択ダイアログのタイトル
        wFolder.InitialFileName = ThisWorkbook.Path             ' フォルダ選択の初期位置をこのファイルパスとする
        wFolder.AllowMultiSelect = False                        ' 選択できるのは1個
        If wFolder.Show = 0 Then Exit Sub                       ' ダイアログを表示 >> フォルダ選択時にキャンセルした場合は処理を抜ける
        wPath = wFolder.SelectedItems(1)                        ' 選択されたフォルダパスを保持
                                                                '
        Call FormImageSet(1)                                    ' フォームとイメージの配置(1:画像選択後)
                                                                '
    End Sub
    
    '----------------------------------------------------------------
    '   「同じ画像でスタート!」ボタンをクリック時
    '----------------------------------------------------------------
    Private Sub CommandButton2_Click()
        Call SoundEffectPlay(1)                                 '[効果音]ボタンクリック音
        Call FormImageSet(1)                                    ' フォームとイメージの配置(1:画像選択後)
    End Sub
    
    '----------------------------------------------------------------
    '   「完成図を見せて!」ボタンをクリック時
    '----------------------------------------------------------------
    Private Sub CommandButton3_Click()
    
        Dim i  As Integer                                       '【変数定義】タイル全体ループの添え字
        Dim b  As Boolean                                       '【  〃   】[有効化/無効化・切替]タイル全体と各ボタン
        Dim z  As Boolean                                       '【  〃   】[有効化/無効化・切替]完成図
        Dim t1 As String                                        '【  〃   】ボタンテキスト編集用
        Dim t2 As String                                        '【  〃   】ゲームメッセージ編集用
                                                                '
        Call SoundEffectPlay(1)                                 '[効果音]ボタンクリック音
        If HintSW = 0 Then                                      ' ■ヒント表示スイッチが [0]完成図を非表示 の場合
            t1 = "ゲームに戻る!"                               ' ├ ボタンテキスト編集
            t2 = " 完成図はこちら~" & Chr(13)                  ' ├ ゲームメッセージ編集 1行目
            t2 = t2 & " しっかり覚えてね!"                     ' ├ ゲームメッセージ編集 2行目
            z = True                                            ' ├ 完成図の有効化
        Else                                                    ' ■ヒント表示スイッチが [1]完成図を表示中 の場合
            t1 = "完成図を見せて!"                             ' ├ ボタンテキスト編集
            t2 = " 元の画像に戻せるかな?"                      ' ├ ゲームメッセージ編集
            b = True                                            ' └ タイル全体と各ボタンの有効化
        End If                                                  '
        OptBtn1.Enabled = b                                     '[有効化/無効化]タイル番号(black)表示
        OptBtn2.Enabled = b                                     '[   〃   ]タイル番号(white)表示
        OptBtn3.Enabled = b                                     '[   〃   ]タイル番号を表示しない
        For i = 1 To 16                                         ' ■タイル全体ループ
            If OptBtn3.Value = False Then tLbl(i).Visible = b   ' ├[表示/非表示]タイル番号(OptBtn3がFalseの場合のみ)
            tOBJ(i).Visible = b                                 ' ├[表示/非表示]タイル
        Next i                                                  ' └ ループ終端
                                                                '
        tOBJ(0).Visible = z                                     '[有効化/無効化]完成図
        CommandButton3.Caption = t1                             ' ボタンテキストを画面反映
        Label18.Caption = Chr(13) & t2                          ' ゲームメッセージを画面反映
        HintSW = HintSW + 1                                     ' ヒント表示スイッチを +1
        If HintSW >= 2 Then HintSW = 0                          ' ■ヒント表示スイッチが2以上の場合 >> 0に戻す
                                                                '
    End Sub
    
    '----------------------------------------------------------------
    '   タイル番号の表示色を変更(black)
    '----------------------------------------------------------------
    Private Sub OptBtn1_Click()
        tileNoColorChange                                       ' タイル番号の表示色を変更
    End Sub
    
    '----------------------------------------------------------------
    '   タイル番号の表示色を変更(white)
    '----------------------------------------------------------------
    Private Sub OptBtn2_Click()
        tileNoColorChange                                       ' タイル番号の表示色を変更
    End Sub
    
    '----------------------------------------------------------------
    '   タイル番号の表示色を変更(非表示)
    '----------------------------------------------------------------
    Private Sub OptBtn3_Click()
        tileNoColorChange                                       ' タイル番号の表示色を変更
    End Sub
        
    '----------------------------------------------------------------
    ' Image99上でマウスダウン時
    '----------------------------------------------------------------
    Private Sub Image99_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    
        Dim gridX      As Integer                               '【変数定義】取得した座標をグリッドx(0~3)に変換
        Dim gridY      As Integer                               '【  〃   】取得した座標をグリッドy(0~3)に変換
        Dim posX       As Integer                               '【  〃   】グリッドxから算出したタイルのx位置
        Dim posY       As Integer                               '【  〃   】グリッドyから算出したタイルのy位置
        Dim MoveX      As Integer                               '【  〃   】マウスダウンされたタイルの移動先x座標
        Dim MoveY      As Integer                               '【  〃   】マウスダウンされたタイルの移動先y座標
        Dim cTile      As Integer                               '【  〃   】マウスダウンされたタイルのタイル番号
        Dim cUpd       As Integer                               '【  〃   】マウスダウンされたタイルの位置更新フラグ [1]位置更新が発生
        Dim ix         As Integer                               '【  〃   】タイル全体ループの添え字
                                                                '
        gridX = X \ 100                                         ' 取得した座標をグリッドx(0~3)に変換
        gridY = Y \ 100                                         ' 取得した座標をグリッドy(0~3)に変換
        posX = gridX * 100 + xBase                              ' グリッドxから算出したタイルのx位置
        posY = gridY * 100 + yBase                              ' グリッドyから算出したタイルのy位置
        cTile = Get_TileImageNo(posX, posY)                     ' マウスダウンされたタイルのタイル番号を取得
                                                                '
        If tOBJ(0).Visible = True Then Exit Sub                 ' ■全体図が表示されている場合は処理を抜ける
                                                                '
        If gridY >= 1 Then                                      ' ■グリッドyが1以上の(上に1マス以上ある)場合
            If Get_TileImageNo(posX, posY - 100) = 0 Then       ' └◆ひとつ上のタイル番号が0の(タイルが無い)場合
                cUpd = 1                                        '   ├ 位置更新が発生
                MoveX = posX                                    '   ├ 移動先x座標を算出
                MoveY = posY - 100                              '   └ 移動先y座標を算出
            End If                                              '
        End If                                                  '
        If gridY <= 2 Then                                      ' ■グリッドyが2以下の(下に1マス以上ある)場合
           If Get_TileImageNo(posX, posY + 100) = 0 Then        ' └◆ひとつ下のタイル番号が0の(タイルが無い)場合
                cUpd = 1                                        '   ├ 位置更新が発生
                MoveX = posX                                    '   ├ 移動先x座標を算出
                MoveY = posY + 100                              '   └ 移動先y座標を算出
           End If                                               '
        End If                                                  '
        If gridX >= 1 Then                                      ' ■グリッドxが1以上の(左に1マス以上ある)場合
            If Get_TileImageNo(posX - 100, posY) = 0 Then       ' └◆ひとつ左のタイル番号が0の(タイルが無い)場合
                cUpd = 1                                        '   ├ 位置更新が発生
                MoveX = posX - 100                              '   ├ 移動先x座標を算出
                MoveY = posY                                    '   └ 移動先y座標を算出
            End If                                              '
        End If                                                  '
        If gridX <= 2 Then                                      ' ■グリッドxが2以下の(右に1マス以上ある)場合
            If Get_TileImageNo(posX + 100, posY) = 0 Then       ' └◆ひとつ右のタイル番号が0の(タイルが無い)場合
                cUpd = 1                                        '   ├ 位置更新が発生
                MoveX = posX + 100                              '   ├ 移動先x座標を算出
                MoveY = posY                                    '   └ 移動先y座標を算出
            End If                                              '
        End If                                                  '
        If cUpd = 0 Then Exit Sub                               ' ■ここまで位置更新フラグが立っていない場合   >> 処理を抜ける
        Do While True                                           ' ■ループ
            If MoveX > posX Then posX = posX + 1                ' ├◆移動先xが現在のタイルx位置より大きい場合 >> 現在のタイルx位置+1
            If MoveX < posX Then posX = posX - 1                ' ├◆移動先xが現在のタイルx位置より小さい場合 >> 現在のタイルx位置-1
            If MoveY > posY Then posY = posY + 1                ' ├◆移動先yが現在のタイルy位置より大きい場合 >> 現在のタイルy位置+1
            If MoveY < posY Then posY = posY - 1                ' ├◆移動先yが現在のタイルy位置より小さい場合 >> 現在のタイルy位置-1
            tOBJ(cTile).Left = posX                             ' ├ マウスダウンされたタイル位置に算出結果を反映する
            tOBJ(cTile).Top = posY                              ' ├   〃       〃        〃
            tLbl(cTile).Left = posX                             ' ├ マウスダウンされたタイル番号に算出結果を反映する
            tLbl(cTile).Top = posY                              ' ├   〃       〃        〃
            DoEvents                                            ' ├ システムに一旦制御を譲渡する
            If MoveX = posX And MoveY = posY Then Exit Do       ' ├ 移動先位置に到達したらループを抜ける
        Loop                                                    ' └ ループ終端
        Call SoundEffectPlay(2)                                 '[効果音]タイル移動完了
        '---------------------------------------------------    '
        '   完成チェック                                        '
        '---------------------------------------------------    '
        Dim xx As Integer                                       '【変数定義】タイルの4x4グリッド位置
        Dim yy As Integer                                       '【  〃  】タイルの4x4グリッド位置
        Dim ok As Integer                                       '【  〃  】タイル正位置カウンタ
        Dim tx As String                                        '【  〃  】ゲームメッセージ編集用
        For ix = 1 To 15                                        ' ■タイル全体ループ(最後のタイルは除外)
           xx = (ix - 1) Mod 4                                  ' ├ グリッドx を ix から算出
           yy = (ix - 1) \ 4                                    ' ├ グリッドy を ix から算出
           If tOBJ(ix).Left = xx * 100 + xBase Then ok = ok + 1 ' ├◆そのタイルが本来のx位置に存在する場合 >> 正位置カウンタ+1
           If tOBJ(ix).Top = yy * 100 + yBase Then ok = ok + 1  ' ├◆そのタイルが本来のy位置に存在する場合 >> 正位置カウンタ+1
        Next ix                                                 ' └ ループ終端
        If ok >= 30 Then                                        ' ■正位置カウンタが30以上(15タイルのxy位置が正しい)場合
            tx = Chr(13) & " 完成したよ~" & Chr(13)            ' ├ ゲームメッセージ編集
            tx = tx & " ゲームクリアだよ!"                     ' ├   〃   〃
            Label18.Caption = tx                                ' ├ ゲームメッセージ画面反映
            CommandButton1.Enabled = True                       ' ├[有効化]「画像を選択してスタート!」ボタン
            CommandButton2.Enabled = True                       ' ├[有効化]「同じ画像でスタート!」ボタン
            CommandButton3.Enabled = False                      ' ├[無効化]「同じ画像でスタート!」ボタン
            OptBtn1.Enabled = False                             ' ├[無効化]タイル番号(black)表示
            OptBtn2.Enabled = False                             ' ├[無効化]タイル番号(white)表示
            OptBtn3.Enabled = False                             ' ├[無効化]タイル番号を表示しない
            For ix = 1 To 16                                    ' ├◆タイル全体ループ
                tLbl(ix).Visible = False                        ' │├[非表示]タイル番号
                tOBJ(ix).Visible = False                        ' │├[非表示]タイル
            Next ix                                             ' │└ ループ終端
            tOBJ(0).Visible = True                              ' ├[表示化]完成図
            Call SoundEffectPlay(3)                             ' └[効果音]完成時
        End If                                                  '
    End Sub
    
    '----------------------------------------------------------------
    ' フォームとイメージの配置
    '
    '   引数    optSW : 0 初期配置
    '                 : 1 画像選択後のイメージ配置
    '
    '----------------------------------------------------------------
    Private Sub FormImageSet(optSW As Integer)
    
        Dim tileSz  As Integer                                  '【変数定義】画像ファイルサイズ(タイル:100x100 元画像:400x400とする)
        Dim xx      As Integer                                  '【  〃  】タイルの4x4グリッド位置
        Dim yy      As Integer                                  '【  〃  】タイルの4x4グリッド位置
        Dim ix      As Integer                                  '【  〃  】ループ用添え字
        Dim Msg     As String                                   '【  〃  】メッセージ編集用
        tileSz = 400                                            ' タイルサイズを400x400とする
        For ix = 0 To 16                                        ' ■タイル全体ループ
            fPath = wPath & "\tile" & ix & ".jpg"               ' ├ 画像ファイルのパス
            Set tOBJ(ix) = Me.Controls("Image" & ix)            ' ├ ImageコントロールをtOBJ配列に格納(タイル)
            If ix > 0 Then                                      ' ├◆添え字が0より大きい場合
                tileSz = 100                                    ' │├ タイルサイズを100x100とする
                Set tLbl(ix) = Me.Controls("Label" & ix)        ' │└ LabelコントロールをtLbl配列に格納(タイル番号)
            End If                                              ' │
            xx = (ix - 1) Mod 4                                 ' ├ 添え字からグリッドx位置を算出
            yy = (ix - 1) \ 4                                   ' ├ 添え字からグリッドy位置を算出
            tOBJ(ix).AutoSize = False                           ' ├ タイルのオートサイズ
            tOBJ(ix).PictureSizeMode = 1                        ' ├ タイルのピクチャサイズモード(ストレッチ)
            tOBJ(ix).Height = tileSz                            ' ├ タイルのyサイズを画面反映
            tOBJ(ix).Width = tileSz                             ' ├ タイルのxサイズを画面反映
            EReadSW = 0                                         ' ├ 読込エラースイッチを初期化
            If optSW = 0 Then tOBJ(ix).Picture = Nothing        ' ├◆optSW:0 の場合 >> イメージオブジェクトのpictureをなしにする
            If optSW = 1 Then                                   ' ├◆optSW:1 の場合
              If Dir(fPath) <> "" Then                          ' │└▼ 画像ファイルを取得できている場合
                tOBJ(ix).Picture = LoadPicture(fPath)           ' │  ├ 画像ファイルを読み込んでtOBJオブジェクトに格納する
              Else                                              ' │  ▼ 画像ファイルを取得できていない場合
                Msg = Chr(13) & " パズル用のファイルが"         ' │  ├ メッセージ編集
                Msg = Msg & Chr(13) & " 揃っていないみたい..."  ' │  ├ メッセージ編集
                Label18.Caption = Msg                           ' │  ├ メッセージを画面反映
                EReadSW = 1                                     ' │  ├ 読込エラースイッチ [1]画像読み込み時にエラーが発生した
                Exit Sub                                        ' │  └ この処理を抜ける
              End If                                            ' │
            End If                                              ' │
            If ix = 0 Then                                      ' ├◆添え字が0の場合(元画像)
                xBase = tOBJ(ix).Left                           ' │├元画像のx位置をタイル配置のx基準とする
                yBase = tOBJ(ix).Top                            ' │├元画像のy位置をタイル配置のy基準とする
                tOBJ(ix).Visible = False                        ' │├元画像を非表示化
            Else                                                ' │◆添え字が0以外の場合(各タイル)
                tOBJ(ix).Left = xx * 100 + xBase                ' │├グリッドx位置からタイルの正位置を算出し配置する
                tOBJ(ix).Top = yy * 100 + yBase                 ' │├グリッドy位置からタイルの正位置を算出し配置する
                tLbl(ix).Left = xx * 100 + xBase                ' │├グリッドx位置からタイル番号の正位置を算出し配置する
                tLbl(ix).Top = yy * 100 + yBase                 ' │├グリッドy位置からタイル番号の正位置を算出し配置する
                tOBJ(ix).Visible = True                         ' │├タイルを表示化
                If ix = 16 Then                                 ' │└▼添え字が16の場合
                    tOBJ(ix).Left = -100                        ' │  ├最後のタイルは画面から見えないようにする
                    tOBJ(ix).Top = -100                         ' │  ├最後のタイルは画面から見えないようにする
                    tLbl(ix).Left = -100                        ' │  ├最後のタイル番号は画面から見えないようにする
                    tLbl(ix).Top = -100                         ' │  └最後のタイル番号は画面から見えないようにする
                End If                                          ' │
            End If                                              ' │
        Next ix                                                 ' └ループ終端
        Image99.Left = xBase                                    ' タイル全体の上に被せているImageコントロールを元画像の位置に合わせる
        Image99.Top = yBase                                     '       〃      〃      〃      〃
        Image99.Width = 400                                     '       〃      〃      〃      〃
        Image99.Height = 400                                    '       〃      〃      〃      〃
        If optSW = 1 Then                                       ' ■optSW:1の場合
            Call TileRandomSet                                  ' ├タイルのランダム配置
            CommandButton1.Enabled = False                      ' ├[無効化]「画像を選択してスタート!」ボタン
            CommandButton2.Enabled = False                      ' ├[無効化]「同じ画像でスタート!」ボタン
            CommandButton3.Enabled = True                       ' ├[有効化]「完成図を見せて!」ボタン
            OptBtn1.Enabled = True                              ' ├[有効化]タイル番号の表示色を変更(black)
            OptBtn2.Enabled = True                              ' ├[有効化]タイル番号の表示色を変更(white)
            OptBtn3.Enabled = True                              ' ├[有効化]タイル番号の非表示
            Image99.Enabled = True                              ' ├[有効化]タイル全体の上に被せているImageコントロール
            HintSW = 0                                          ' ├ ヒント表示スイッチ 初期化
            Msg = Chr(13) & " 元の画像に戻せるかな?"           ' ├ メッセージ編集
            Label18.Caption = Msg                               ' ├ メッセージ画面反映
            tileNoColorChange                                   ' └ タイル番号の表示色を変更
        End If
    End Sub
        
    '----------------------------------------------------------------
    '   タイルをランダム配置
    '
    '       ※ 不可能な配置を回避するランダム配置
    '       参考:https://ja.wikipedia.org/wiki/15パズル
    '
    '----------------------------------------------------------------
    Private Sub TileRandomSet()
    
        Dim j  As Integer                                       '【変数定義】タイル交換対象 の添え字
        Dim p  As Integer                                       '【  〃   】タイル全体ループの添え字
        Dim jx As Integer                                       '【  〃   】タイル交換対象 のx座標
        Dim jy As Integer                                       '【  〃   】タイル交換対象 のy座標
        Dim px As Integer                                       '【  〃   】ループ選択タイルのx座標
        Dim py As Integer                                       '【  〃   】ループ選択タイルのy座標
        Dim rd As Integer                                       '【  〃   】乱数取得用
        For p = 1 To 15                                         '■タイル全体ループ
            rd = fRandom(9, 2)                                  '├乱数取得(2~9)
            If rd = 4 Then rd = rd + 1                          '├◆取得した乱数が4(縦に隣り合ったタイルが交換対象の場合 >> 乱数+1
            j = p + rd                                          '├ループ選択タイルの添え字+乱数 をタイル交換対象の添え字として格納
            Do While True                                       '├◆ループ
                If j > 15 Then j = j - 15                       '│├▼タイル交換対象の添え字が15より大きい場合 >> タイル交換対象の添え字-15
                If j < 16 Then Exit Do                          '│├▼タイル交換対象の添え字が16より小さい場合 >> ループを抜ける
            Loop                                                '│└ループ終端
            px = tOBJ(p).Left                                   '├ ループ選択のタイルx位置を退避
            py = tOBJ(p).Top                                    '├ ループ選択のタイルy位置を退避
            jx = tOBJ(j).Left                                   '├ 交換対象 のタイルx位置を退避
            jy = tOBJ(j).Top                                    '├ 交換対象 のタイルy位置を退避
            tOBJ(p).Left = jx                                   '├ ループ選択のタイルに交換対象のx位置を格納
            tOBJ(p).Top = jy                                    '├ ループ選択のタイルに交換対象のy位置を格納
            tOBJ(j).Left = px                                   '├ 交換対象のタイルにループ選択のx位置を格納
            tOBJ(j).Top = py                                    '├ 交換対象のタイルにループ対象のy位置を格納
        Next p                                                  '└ ループ終端
        px = tOBJ(1).Left                                       '-----------------------------------------------
        py = tOBJ(1).Top                                        '
        jx = tOBJ(3).Left                                       ' このままだと奇数回の交換になるので
        jy = tOBJ(3).Top                                        ' 最後に1番目と3番目のタイルを入れ替えることで
        tOBJ(1).Left = jx                                       ' 偶数回の交換を実現する
        tOBJ(1).Top = jy                                        '
        tOBJ(3).Left = px                                       '
        tOBJ(3).Top = py                                        '-----------------------------------------------
        For p = 1 To 15                                         ' ■ タイル番号全体ループ
            tLbl(p).Left = tOBJ(p).Left                         ' ├ タイル番号x位置 と タイルx位置を同じにする
            tLbl(p).Top = tOBJ(p).Top                           ' ├ タイル番号y位置 と タイルy位置を同じにする
        Next p                                                  ' └ ループ終端
    
    End Sub
    
    '----------------------------------------------------------------
    '   タイル番号の表示色を変更
    '----------------------------------------------------------------
    Private Sub tileNoColorChange()
        Dim i As Integer                                        '【変数定義】タイル番号全体ループの添え字
        Call SoundEffectPlay(1)                                 '[効果音] クリック音
        For i = 1 To 16                                         ' ■タイル番号全体ループ
            With tLbl(i)                                        ' ├◆オブジェクト名 tLbl(i)
              .Visible = True                                   ' │├[表示化]タイル番号
              If OptBtn1.Value = True Then .ForeColor = vbBlack ' │├▼OptBtn1が選択されている場合 >> タイル番号を黒にする
              If OptBtn2.Value = True Then .ForeColor = vbWhite ' │├▼OptBtn2が選択されている場合 >> タイル番号を白にする
              If OptBtn3.Value = True Then .Visible = False     ' │├▼OptBtn3が選択されている場合 >> タイル番号を表示しない
            End With                                            ' │└オブジェクト名 tLbl(i) 終端
        Next i                                                  ' └ループ終端
    End Sub
    
    '----------------------------------------------------------------
    '   サウンドエフェクト発生処理
    '
    '   引数   SENo : 効果音番号
    '
    '----------------------------------------------------------------
    Private Sub SoundEffectPlay(SENo As Integer)
        WMP1.Controls.stop                                      ' WindowsMediaPlayer1 停止
        WMP1.Url = sPath & "SE" & SENo & ".mp3"                 ' WindowsMediaPlayer1 に "SE" + SENo のファイルパスを入れる
        WMP1.Controls.Play                                      ' WindowsMediaPlayer1 再生
    End Sub
    
    '----------------------------------------------------------------
    '   引数の座標からタイル番号を取得
    '
    '   引数    tx : タイルのx位置
    '           ty : タイルのy位置
    '
    '   戻値    タイル番号
    '
    '----------------------------------------------------------------
    Private Function Get_TileImageNo(tx As Integer, tY As Integer) As Integer
        Dim ix As Integer                                       '【変数定義】タイル全体ループの添え字
        Dim ok As Integer                                       '【   〃   】タイル位置該当フラグ
        Dim rt As Integer                                       '【   〃   】返答用変数
        rt = 0                                                  ' 返答用変数の初期化
        For ix = 1 To 16                                        '■ タイル全体ループ
            ok = 0                                              '├ タイル位置該当フラグの初期化
            If tOBJ(ix).Left = tx Then ok = ok + 1              '├◆引数のタイルx位置とチェック中のタイルx位置が同一の場合 >> タイル位置該当フラグ+1
            If tOBJ(ix).Top = tY Then ok = ok + 1               '├◆引数のタイルy位置とチェック中のタイルy位置が同一の場合 >> タイル位置該当フラグ+1
            If ok >= 2 Then rt = ix                             '├◆タイル位置該当フラグが2以上の場合 >> 返答用変数に添え字を格納
        Next ix                                                 '└ ループ終端
        Get_TileImageNo = rt                                    ' 返答用変数を返答する
    End Function
    
    '----------------------------------------------------------------
    '   最大値と最小値を指定した乱数取得ファンクション
    '
    '   引数    dMax : 取得乱数の最大値
    '           dMin : 取得乱数の最小値
    '
    '   戻値    乱数
    '
    '----------------------------------------------------------------
    Private Function fRandom(dMax As Integer, dMin As Integer)
        fRandom = Int((dMax - dMin + 1) * Rnd + dMin)           ' 最小~最大値の間の値を乱数を用いて返答する
    End Function                                                '

    長っ!


    ゲームを動かしてみよう!

    コードをコピペし終わったら実際にゲームを動かしてみましょう。

    (1)プロジェクトウィンドウの「UserForm1」をダブルクリックします。するとフォームが表示されます。

    (2)再生ボタンをクリックするとゲームが動くハズです!

    画像

    上手く動かない場合は、同テーマの過去記事「Excel(VBA)で簡単なゲームを作る」の「動かないんだけど!?(怒)」を参考に原因を探ってみましょう。落ち着いて確認してみてください。

    エラーの原因の9割はオブジェクト名が間違っています!(多分)


    おわりに

    これでゲームそのものは動くハズですが…

    画像
    画像
    知らん人からメールで送られてきたExcelファイルなんかは危ない…から気をつけてね!

    セキュリティの問題なんかで、ActiveXがどうのマクロの有効化がどうのって表示される可能性があります。しかし、自分で作ったものですからね。
    「有効化」「OK」でいいです。


    んで、「遊び方」を説明していませんでした!

    再生ボタンを押してフォームが表示されたら「画像を選択してスタート!」をクリックします。画像セットは「PuzzleData」フォルダに入っています。
    このフォルダを選んで「OK」でゲームスタートです。

    あとは空いているマスに隣接したタイルをクリックすると、タイルが動きます。元画像と同じようにタイルが並べばゲームクリアです。


    で、次回以降のお話…
    今回のコードは、同テーマの過去記事で作った「マインスイーパー」に比べると難易度的には少し低めです。

    クラスモジュールを使用せずに15個のタイルをImage99のプロシージャ1つで動かせていますからね…

    しかし、それでもプログラムを学んだことのない方には結構な規模のコードだと思います。これだけの規模になると1行毎に説明されても、他の行との関連性がわからなくて理解できません。

    ですので、行毎の説明より、処理の流れとして解説した方が良いのではないかと思っています…(といっても解説記事は次々回あたりになりそうです)

    今回も長い記事にお付き合いいただきありがとうございました。
    また別の記事でお会いしましょう!


    ここからはオススメ記事の紹介です。

    システム系の勉強したいなーって方にはコチラがオススメです。
    関連記事を以下にまとめてます!(↓)

    「読むとゲームができるマガジン」もオススメです。
    Unityのお話もありますが、Excelである程度のゲームは作れますよ(↓)


    あなたへのおすすめ