
Excel(VBA)でパズルゲームを作る!(大幅アップデート編)
こんにちは「つけらっとゲームス」プログラム担当のとちです。
今回は少し前にExcel(VBA)で作ったパズルゲームの大幅アプデをします。
続き物の記事となっております。
同テーマの前回記事は以下の埋め込みリンクからご覧ください。
どんな感じになるのかというと?
Excel(VBA)で作ったパズルゲーム!
— とち/ゲーム作ってる人 (@totitoti_) July 11, 2026
同じパネルを3~4個、縦横斜めor四角形に並べても消えるシンプルなモノ。
無音だと寂しいのでBGMと効果音を付けてみた。
ファミコンっぽいのが欲しかったので、イワシロ音楽素材さん(https://t.co/Id8NdBpvhU)からお借りしました。
思ってたよりいい感じになった! pic.twitter.com/iCsnGMUS4N
はい、こんな感じになります!
さて、今回は大幅アップデート編ということで前回作ったパズルゲームを改良していくわけですが、ただ単純にゲームの作り方を解説する記事として読んでいただいても、もちろん構いません。
しかし、本格的な情報科の勉強をし始めた学生さんや、将来的に自分の考えた最強のゲームを作りたい方には、すこし違った視点で記事を読んで欲しいと思っております。
というのも、これってシステム開発の手法(手順)として教科書や参考書にも、基本情報技術者試験にも出てくる「アジャイル開発」っていうヤツなんですよ。そういった視点でも参考になればいいな~。
そのへんについてご興味が無い方、とりあえず「作業させろ」という方は少し読み飛ばして「追加仕様!」からご覧くださいね。
開発の手法って気にする?
正直言うと、わたし自身は「〇〇モデルで開発しよう」とまでは意識していませんが、企業や開発チームの方針で「こういった手順で開発を進める」というのはありますし、何より試験に出てくるんですよね。
で、インディーゲームの作り方として、非エンジニアでも、知識がなくても自分が作りたいものを必死に作った方が良いという考え方もありまして、実のところ、その方がモノを覚えるんじゃないかな~と思っています。
ただ、学校で勉強として学ぶ場合だったり、長きにわたって趣味として楽しむ場合は、人間である以上、どこかで飽きが出てくるものです。もちろん仕事としてのシステム開発であっても同じ、
大規模でガチガチの仕様が決まっており「正解はこれしかない!」という堅牢で完璧なシステム開発は完成まで多くの作業があり、長い時間を要するわけでして、これが結構きつかったりするんですよね(個人の感想です)
このやり方はウォーターフォールモデルなんて呼ばれたりします。
開発期間や費用など、計画を立てやすいという点ではメリットです。
悪いと言ってるわけじゃないですよ。そこは誤解のないように…
アジャイル開発とはなんぞや?
前節のウォーターフォールモデルに対し、イテレーションという短めの期間(1週間とか1ヶ月とか…)を単位として、開発工程を繰り返すのがアジャイル開発ってやつです。
ちなみにイテレーション(Iteration)は反復とか繰り返しを意味します。
この手法のメリットとして、イテレーションの終わりには開発途中とはいえ、それなりに動くプログラムができるので、ユーザーとしても開発チームとしても途中で状況を確認できるってことなんですよね。
スマホアプリの利用状況によってバランス調整や仕様変更が可能なので、今回のようにゲームの大幅アップデートとは親和性が高い手法です。
そうそ、Steamのアーリーアクセスでユーザーのフィードバックを貰い改良していくのもアジャイル開発と言えるでしょう。
今回のExcel(VBA)で作ったパズルゲームに当てはめると…
1.まずは最小限のルールで動くものを作る(前回作ったモノ)
2.機能や演出を追加してより良いゲームにする(今回の記事)
となり、現時点で既に動くものがあるわけですから、モチベも維持しやすいと言えますね。あ、テンション上がったところ申し訳ないですが注意。バックアップをとってからアプデ作業しましょうね!
追加仕様!
それでは、前回の記事で作ったパズルゲームに何を追加するかを順を追って説明しますよ~。
【パネルの消し方の追加】
前回の記事では、横または縦に同じパネルが3~4つ並んでいる場合にパネルが消えるという仕様でした。
縦横だけだと窮屈だし、ミスって置いたパネルがゲームオーバーまで残ってしまう。遊んでて窮屈な印象を受けると思います。
今回は「斜め消し」と「四角消し」を追加します。
これにより大幅に戦術性が高まるんですよ!

【BGMと効果音の追加】
ゲーム開発ツールと比較すると、どうしてもExcel(VBA)は弱い。
その弱さを感じる最大のポイントは演出面です。
アニメーションや画像透過が簡単にできるUnity等で作れば楽なんですけど、本記事ではWindowsユーザーには身近なExcelを使うという前提条件を設定しているので、仕方ないといえば仕方ない…
こういった演出はゲームに限らず、どんなシステムであっても致命的なデメリットを生じさせます。それがユーザーの操作ミス。操作ミスが発生しやすいし、操作ミスをしたことに気づかないんですよ。
ボタンを押した時に凹んだり、すこし拡大する、揺れる等の、操作に対して何らかのリアクションがないと二重入力する可能性があります。これを演出によって軽減することができますが、前述通りExcel(VBA)はそこが弱い。
その他の演出で操作ミスを減らす方法。音です。これならできる!
SEが鳴るとユーザーの操作をシステム側が受け取っていると認識できます。
ちょっとした効果音ですが結構大事なんですよね。
というわけでサウンドを導入します。

まずは、ゲームが動作するExcelファイルと同じフォルダに「sounds」フォルダを作ります。中には幾つかのファイルがあります。
用意するmp3ファイルについては後述しますね!

【ワークシートから設定切替】
今回はワークシート「Config」を用意し、セルに設定されている値を使用してゲームの設定を変更できるようにします。
ゲームの中で使用する固定値は外部で調整できた方が何かと便利です。
プログラム内の定数にしてしまうとコード修正が必要になりますからね。

上のスクショを見るとBGMやSEの音量だけでなく「斜め置き」「四角置き」の使用可/不可が切替できるようになっています。また、ゲームの難易度が変化するペースを設定できるようになっています。
コンフィグ設定は、遊ぶ側に自分の遊びたい環境を設定させるという意味でも良いんですけど、開発側でもバランス調整する際はあると便利ですよね。
サウンドファイルの用意!
ではアップデート作業を始めましょうか!?
まずは音を追加するべく、サウンドファイルの用意からスタートです。
やっぱり、BGMと効果音があるとゲームっぽくなりますね。
今回も「魔王は200年ごとに蘇る」でお世話になったイワシロ音楽素材さんからお借り(ダウンロード)しましょう。
用意するのはBGMとして使用する1つと、効果音8種類です。
用意するサウンドファイルは以下の一覧表を参考にしてくださいね。
ダウンロードしたらプログラムから呼び出しやすくするためにファイル名を変更しておきましょう。

各ファイルをsoundsフォルダに入れる作業は終わりましたか?
作業した結果、下のスクショのようになっているハズです。

フォームのアプデ作業!
ゲーム内にBGMと効果音を再生するためにフォームもちょっとだけアプデ作業をしたいところですが、その前に…

ツールボックスにWindowsMediaPlayerコントロールが追加されている必要があります。やり方は次の埋め込みリンクの記事内にある「コントロールの追加」をご覧ください。
WindowsMediaPlayerコントロールを2つ追加するために、下のスクショのようにフォームを横に広げます。

フォームが広がったら、下のスクショのように2つのWindowsMediaPlayerオブジェクトを作成します。

それぞれのオブジェクトのプロパティは以下の通りです。
オブジェクト名を変更しておきましょう!

ゲーム中はWindowsMediaPlayerを表示する必要がありません。
なのでプログラムでフォームのサイズを狭めています。
ワークシートのアプデ作業
ワークシート側も作業もしておきます。
まず、忘れずにシート名を「Config」に変更します。

あとは上のスクショを参考に同じように入力してください。
コード内で参照しているのはB列のみですが、設定変更する時に困らないようにA列に項目名を、D列に備考を残しておきましょう。
コードの差し替え!
最後にコードを差し替えます。
元々のコードを全て消去したら、以下のコードを丸々コピペしましょう。
コードの内容については後述します。
Option Explicit
Dim GameSW As Boolean ' True:ゲーム中
Dim pPutSW As Boolean ' True:パネルをグリッドに置いた
Dim bImg(9) As MSForms.Image ' 複写元のベースイメージ(画像)
Dim gImg(3, 3) As MSForms.Image ' メイングリッドイメージ(画像)
Dim nImg(3) As MSForms.Image ' Next欄のイメージ(画像)
Dim hImg As MSForms.Image ' Hold欄のイメージ(画像)
Dim gDat() As Integer ' メイングリッドの内容
Dim nDat(3) As Integer ' Next欄の内容
Dim hDat As Integer ' Hold欄の内容
Dim StepCnt As Integer ' Stepカウント パネルをグリッド配置した時に+1
Dim DelCnt As Long ' 消去パネルカウント
Dim dScore As Long ' スコア
'--
'-- [ADD] 応用編で追加された変数
'--
Dim Set_Nana As Integer ' 斜め置きを許可する [1] 許可
Dim Set_4kak As Integer ' 4角置きを許可する [1] 許可
Dim Set_Bomb As Integer ' 爆弾出現率が低下するステップカウント
Dim Set_PN1 As Integer ' パネル追加ステップ数 1
Dim Set_PN2 As Integer ' パネル追加ステップ数 2
Dim SudStpSW As Integer ' サウンドの停止スイッチ [0]停止する [1]停止しない
Dim SEPlaySW As Integer ' 再生する効果音番号
Dim Vol_BGM As Integer ' 音量 - BGM
Dim Vol_SE As Integer ' 音量 - SE
'------------------------------------------------------------
' ユーザーフォーム初期化時
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub UserForm_Initialize()
Dim folderPath As String ' 画像フォルダのパス
Dim ImagePath As String ' 画像ファイルのパス
Dim cNm As String ' オブジェクト名生成用 文字列変数
Dim X As Integer ' グリッドx方向の添え字
Dim Y As Integer ' グリッドy方向の添え字
'--
'-- 複製元 ベースとなる画像データ
'--
folderPath = ThisWorkbook.Path & "\Images\pImage_"
For X = 0 To 9
ImagePath = folderPath & X & ".jpg"
Set bImg(X) = Me.Controls.Add("Forms.image.1", "bImg_" & X)
bImg(X).Picture = LoadPicture(ImagePath)
bImg(X).Left = -500
Next X
'--
'-- メイングリッド 作成
'--
For Y = 0 To 3
For X = 0 To 3
cNm = "Grid_" & X & "_" & Y
Set gImg(X, Y) = Me.Controls.Add("Forms.image.1", cNm)
gImg(X, Y).Picture = bImg(0).Picture
gImg(X, Y).Left = X * 54 + 12 ' グリッド1マスの横座標
gImg(X, Y).Top = Y * 54 + 12 ' グリッド1マスの縦座標
gImg(X, Y).Width = 54 ' グリッド1マスの横サイズ
gImg(X, Y).Height = 54 ' グリッド1マスの縦サイズ
gImg(X, Y).PictureSizeMode = 1
Next X
Next Y
'--
'-- Next欄 作成
'--
For X = 0 To 3
Set nImg(X) = Me.Controls.Add("Forms.image.1", "nImg_" & X)
nImg(X).Picture = bImg(0).Picture
nImg(X).Left = 252 ' Next欄1個の横座標
nImg(X).Top = X * 36 + 48 ' Next欄1個の縦座標
nImg(X).Width = 36 ' Next欄1個の横サイズ
nImg(X).Height = 36 ' Next欄1個の縦サイズ
nImg(X).PictureSizeMode = 3
Next X
'--
'-- Hold欄 作成
'--
Set hImg = Me.Controls.Add("Forms.image.1", "hImg_f")
hImg.Picture = bImg(0).Picture
hImg.Left = 246 ' Hold欄の横座標
hImg.Top = 234 ' Hold欄の縦座標
hImg.Width = 48 ' Hold欄の横サイズ
hImg.Height = 48 ' Hold欄の縦サイズ
hImg.PictureSizeMode = 3
'--
'-- グリッド全体のマウス入力受取を行うイメージコントロール
'--
GridClickChk.Left = 12 ' 横座標
GridClickChk.Top = 12 ' 縦座標
GridClickChk.Width = 300 ' 横サイズ
GridClickChk.Height = 216 ' 縦サイズ
GridClickChk.BorderStyle = 0 ' 境界線の非表示
GridClickChk.ZOrder fmZOrderFront ' 最前面表示
'--
'-- Hold欄のマウス入力受取を行うイメージコントロール
'--
HoldClickChk.Left = 246 ' 横座標
HoldClickChk.Top = 234 ' 縦座標
HoldClickChk.Width = 48 ' 横サイズ
HoldClickChk.Height = 48 ' 縦サイズ
HoldClickChk.BorderStyle = 0 ' 境界線の非表示
HoldClickChk.ZOrder fmZOrderFront ' 最前面表示
'--
'-- [ADD] フォームサイズなどの最終調整
'--
Me.Width = 336
Me.Height = 396
Vol_BGM = Worksheets("Config").Cells(1, 2).Value ' ワークシートからBGM音量取得
Vol_SE = Worksheets("Config").Cells(2, 2).Value ' ワークシートから SE音量取得
Set_Nana = Worksheets("Config").Cells(3, 2).Value ' 斜め置きを許可するか?
Set_4kak = Worksheets("Config").Cells(4, 2).Value ' 四角置きを許可するか?
Set_Bomb = Worksheets("Config").Cells(5, 2).Value ' 爆弾出現率が低下するステップカウント
Set_PN1 = Worksheets("Config").Cells(6, 2).Value ' パネル追加ステップ数 1
Set_PN2 = Worksheets("Config").Cells(7, 2).Value ' パネル追加ステップ数 2
folderPath = ThisWorkbook.Path & "\sounds\BGM1.mp3" ' メインBGMフルパス
SudStpSW = 1 ' サウンド停止スイッチ [1]停止しない
WMP1.settings.volume = Vol_BGM ' BGM音量の反映
WMP2.settings.volume = Vol_SE ' SE音量の反映
WMP1.Controls.stop ' WindowsMediaPlayer1 停止
WMP1.Url = folderPath ' WindowsMediaPlayer1 に BGM1のファイルパスを入れる
WMP1.Controls.Play ' WindowsMediaPlayer1 再生
End Sub
'------------------------------------------------------------
' [ADD] フォーム閉じた時
'
' 引数 Cancel 0以外でQueryCloseイベントが停止する
' CloseMode QueryClose発生原因
' 戻値 なし
'------------------------------------------------------------
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
SudStpSW = 0 ' サウンド停止スイッチを[0]停止する に変更
WMP1.Controls.stop ' WindowsMediaPlayer1 停止
WMP2.Controls.stop ' WindowsMediaPlayer2 停止
End Sub
'------------------------------------------------------------
' ゲーム中にメイングリッドをクリック(Down)した時
'
' 引数 :imageコントロール MouseDown
' 戻り値 :なし
'------------------------------------------------------------
Private Sub GridClickChk_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
If GameSW = False Then Exit Sub ' ゲーム中以外の場合は処理を抜ける
Dim gX As Integer ' グリッド座標x
Dim gY As Integer ' グリッド座標y
'--
'-- クリック座標を54で除算し対象グリッドを算出
'-- メイングリッド外の場合は処理を抜ける
'--
gX = X \ 54 ' メイングリッドの一辺の大きさが54x54なので、
gY = Y \ 54 ' 54で除算するとグリッド座標が算出できる
If gX <= -1 Or gX >= 4 Then Exit Sub ' もしグリッド座標外の値が算出された場合は
If gY <= -1 Or gY >= 4 Then Exit Sub ' この処理を抜ける
pPutSW = False ' パネル配置スイッチの初期化(False)
'--
'-- Next欄の一番上がパネル1~8の場合
'-- パネルが既に設置されていると置けない
'--
If nDat(0) >= 1 And nDat(0) <= 8 Then ' Next欄の一番上が通常パネルだった場合
If gDat(gX, gY) = 0 Then ' パネルが既に設置されている場合は置けない
gImg(gX, gY).Picture = bImg(nDat(0)).Picture ' グリッドにパネル表示
gDat(gX, gY) = nDat(0) ' グリッド内容にパネル番号(1~8)を格納
pPutSW = True ' パネル配置スイッチをTrueにする
End If
End If
'--
'-- Next欄の一番上がパネル9(爆弾)の場合
'-- パネルが既に設置してあっても置ける
'--
If nDat(0) = 9 Then ' Next欄の一番上が爆弾パネルだった場合
gImg(gX, gY).Picture = bImg(nDat(0)).Picture ' グリッドに爆弾表示
gDat(gX, gY) = nDat(0) ' グリッド内容に9:爆弾を格納
pPutSW = True ' パネル配置スイッチをTrueにする
End If
'--
'-- メイングリッドにパネルを置けた場合
'--
If pPutSW = True Then ' ここまででグリッドにパネルを置けた場合
StepCnt = StepCnt + 1 ' Stepカウント+1
Call NextWindowUpdate ' Next欄を更新
Call SoundEffectPlay(2) ' [ADD] パネル配置の効果音再生
End If
End Sub
'------------------------------------------------------------
' ゲーム中にメイングリッドをクリック(Up)した後
'
' 引数 :imageコントロール MouseDown
' 戻り値 :なし
'------------------------------------------------------------
Private Sub GridClickChk_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
If GameSW = False Then Exit Sub ' ゲームプレイ中以外の場合は処理を抜ける
If pPutSW = False Then Exit Sub ' パネル配置されていない場合は処理を抜ける
SEPlaySW = 0 ' [ADD] この処理の最後に再生する効果音SWを初期化しておく
Call PointCheckProc ' スコア計算
Call GameOverCheckProc ' ゲームオーバーチェック処理
Call SoundEffectPlay(SEPlaySW) ' [ADD] 効果音の再生
End Sub
'------------------------------------------------------------
' Hold欄をクリック(Down)した時
'
' 引数 :imageコントロール MouseDown
' 戻り値 :なし
'------------------------------------------------------------
Private Sub HoldClickChk_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
If GameSW = False Then Exit Sub ' ゲーム中以外の場合は処理を抜ける
Call SoundEffectPlay(6) ' [ADD] Hold欄クリック時のSE
'--
'-- Hold欄に何も入っていない場合
'-- Next欄の一番上をHoldする
'--
If hDat <= 0 Then ' Hold欄の内容が0以下(入っていない場合)
hDat = nDat(0) ' Next欄の一番上の内容を保持
hImg.Picture = nImg(0).Picture ' Next欄の一番上の画像を保持
Call NextWindowUpdate ' Next欄を更新する
Exit Sub ' 処理を抜ける
End If
'--
'-- Hold欄に何か入っていた場合
'-- Next欄の一番上とHold欄を入れ替える
'--
Dim sv As Integer ' 入替時に使用する変数
sv = hDat ' Hold欄を入替用変数に格納
hDat = nDat(0) ' Hold欄にNext欄の一番上の内容を格納
hImg.Picture = nImg(0).Picture ' Hold欄の画像を更新
nDat(0) = sv ' 入替用変数をNext欄の一番上に格納
nImg(0).Picture = bImg(sv).Picture ' Next欄の一番上の画像を更新
End Sub
'------------------------------------------------------------
' スタートボタン クリック時
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub StartButton_Click()
Dim i As Integer ' 配列全件ループ用添え字
Dim j As Integer ' グリッドに対する初期配置パネル数をランダム取得
Dim X As Integer ' グリッドx方向の添え字
Dim Y As Integer ' グリッドy方向の添え字
Rnd -1 ' 乱数系列の初期化
Randomize CLng(NowSeed.Value) ' 乱数種の取得
ReDim gDat(3, 3) As Integer ' グリッド内容配列を再定義
'--
'-- 押したボタンのキャプションが"Restart"の場合
'--
If StartButton.Caption = "Restart" Then
For Y = 0 To 3 ' メイングリッドの全件ループ
For X = 0 To 3 ' メイングリッドの画像を全てない状態にする
gImg(X, Y).Picture = bImg(0).Picture
Next X
Next Y
hImg.Picture = bImg(0).Picture ' Hold欄をない状態にする
hDat = 0 ' Hold欄の内容を初期化
GridClickChk.ZOrder fmZOrderFront ' グリッドクリック用のImageコントロールを前面にする
HoldClickChk.ZOrder fmZOrderFront ' Hold欄クリック用 のImageコントロールを前面にする
End If
'--
'-- Next欄の全件ループ
'--
For i = 0 To 3
nDat(i) = fRandom(6, 1) ' Next欄の内容をランダム取得
nImg(i).Picture = bImg(nDat(i)).Picture ' Next欄の画像を画面反映
Next i
'--
'-- グリッド欄の初期配置(パネルを幾つか配置)
'--
j = fRandom(4, 1) ' グリッドの配置する初期パネル数(1~4個)
For i = 0 To j ' 初期配置パネル数に達するまでループ
X = fRandom(3, 0) ' 初期配置パネルx座標 取得
Y = fRandom(3, 0) ' 初期配置パネルy座標 取得
gDat(X, Y) = fRandom(6, 1) ' ランダム取得した座標に内容を格納
gImg(X, Y).Picture = bImg(gDat(X, Y)).Picture ' ランダム取得した座標に内容に対応した画像を反映
Next i
'--
'-- その他・ゲーム開始の準備処理
'--
GameOverLbl.Visible = False ' ゲームオーバーのラベルを非表示化
StartButton.Enabled = False ' このボタンを押せないようにする
NowSeed.Enabled = False ' 乱数シード入力欄を使用不可にする
GameSW = True ' ゲーム開始
dScore = 0 ' スコアの初期化
StepCnt = 0 ' ステップ数の初期化
NowScore.Caption = dScore ' スコアの画面表示
NowStep.Caption = StepCnt ' ステップ数の画面表示
Call SoundEffectPlay(8) ' [ADD] スタートボタンクリック時のSE
End Sub
'------------------------------------------------------------
' Next欄の変更
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub NextWindowUpdate()
Dim i As Integer ' Next欄を探索する添え字
Dim BombSW As Integer ' 爆弾の発生スイッチ 0:爆弾発生
Dim BombMx As Integer ' 爆弾が発生する確率を変動させるための乱数上限値
Dim PanelMx As Integer ' ランダム発生するNext欄の発生するパネル種類数
For i = 0 To 2 ' Next欄の全件探索
nDat(i) = nDat(i + 1) ' Next欄の下の内容をひとつ上に転記する
nImg(i).Picture = bImg(nDat(i)).Picture ' Next欄の下の画像をひとつ上に転記する
Next i
'BombMx = 3 + (StepCnt \ 50) ' [DEL] ボムの発生確率時に使う乱数上限値を算出 Step:50毎に徐々に爆弾は出なくなる
BombMx = 3 + (StepCnt \ Set_Bomb) ' [ADD] 指定されたステップカウント毎に爆弾発生率が落ちていく
BombSW = fRandom(BombMx, 0) ' 爆弾発生スイッチを取得 0:爆弾発生
PanelMx = 6 ' Next欄に発生する通常パネル種 6種類
'If StepCnt >= 75 Then PanelMx = 7 ' [DEL] ステップ数が 75以上の場合 7種類
'If StepCnt >= 150 Then PanelMx = 8 ' [DEL] ステップ数が150以上の場合 8種類
If StepCnt >= Set_PN1 Then PanelMx = 7 ' [ADD] ステップ数が 75以上の場合 7種類
If StepCnt >= Set_PN2 Then PanelMx = 8 ' [ADD] ステップ数が150以上の場合 8種類
If BombSW = 0 Then ' 爆弾発生の場合
i = fRandom(PanelMx, 0) ' 0を含めたパネルのランダム発生値を取得
Else ' 爆弾発生しない場合
i = fRandom(PanelMx, 1) ' 0を含めないパネルのランダム発生値を取得
End If
If i = 0 Then i = 9 ' パネルのランダム発生値が0の場合 パネル番号を9:爆弾とする
nDat(3) = i ' パネルのランダム発生値をNext欄の一番下に入れる
nImg(3).Picture = bImg(i).Picture ' 対応したパネル画像をNext欄の一番下に入れる
End Sub
'------------------------------------------------------------
' メイングリッドの状況を見て点数を算出
' 同時にグリッドの表示変更
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub PointCheckProc()
Dim X As Integer ' グリッドx方向の添え字
Dim Y As Integer ' グリッドy方向の添え字
Dim cDel As Integer ' 消去カウント >> この処理で消去されるパネル数
Dim cTbl(3, 3) As Integer ' 消去テーブル >> この処理で消去されるパネル位置に1を立てる
'--
'-- 爆弾チェック
'--
For Y = 0 To 3 ' グリッド内容を全件チェックする二重ループ
For X = 0 To 3 ' グリッド内容が9:爆弾の場合
If gDat(X, Y) = 9 Then ' グリッド内容を0:何も無い状態にする
gImg(X, Y).Picture = bImg(0).Picture ' グリッド画像も何も無い状態に更新する
gDat(X, Y) = 0 ' ※ 爆弾の場合はパネルを消したことにしない
SEPlaySW = 1 ' [ADD] 爆弾使用の効果音
End If
Next X
Next Y
'--
'-- 横チェック
'-- 同じパネルが横に3または4並んでいる場合 >> 消去テーブルに1を立てる
'--
For Y = 0 To 3
If gDat(0, Y) > 0 And _
gDat(0, Y) = gDat(1, Y) And _
gDat(0, Y) = gDat(2, Y) And _
gDat(0, Y) = gDat(3, Y) Then
cTbl(0, Y) = 1: cTbl(1, Y) = 1
cTbl(2, Y) = 1: cTbl(3, Y) = 1
ElseIf gDat(0, Y) > 0 And _
gDat(0, Y) = gDat(1, Y) And _
gDat(0, Y) = gDat(2, Y) Then
cTbl(0, Y) = 1: cTbl(1, Y) = 1: cTbl(2, Y) = 1
ElseIf gDat(1, Y) > 0 And _
gDat(1, Y) = gDat(2, Y) And _
gDat(1, Y) = gDat(3, Y) Then
cTbl(1, Y) = 1: cTbl(2, Y) = 1: cTbl(3, Y) = 1
End If
Next Y
'--
'-- 縦チェック
'-- 同じパネルが縦に3または4並んでいる場合 >> 消去テーブルに1を立てる
'--
For X = 0 To 3
If gDat(X, 0) > 0 And _
gDat(X, 0) = gDat(X, 1) And _
gDat(X, 0) = gDat(X, 2) And _
gDat(X, 0) = gDat(X, 3) Then
cTbl(X, 0) = 1: cTbl(X, 1) = 1
cTbl(X, 2) = 1: cTbl(X, 3) = 1
ElseIf gDat(X, 0) > 0 And _
gDat(X, 0) = gDat(X, 1) And _
gDat(X, 0) = gDat(X, 2) Then
cTbl(X, 0) = 1: cTbl(X, 1) = 1: cTbl(X, 2) = 1
ElseIf gDat(X, 1) > 0 And _
gDat(X, 1) = gDat(X, 2) And _
gDat(X, 1) = gDat(X, 3) Then
cTbl(X, 1) = 1: cTbl(X, 2) = 1: cTbl(X, 3) = 1
End If
Next X
'--
'-- [ADD] 斜め置きチェック
'-- 同じパネルが斜めに3以上並んでいる場合 >> 消去テーブルに1を立てる
'-- ワークシート Config で設定する [1]であれば斜め置きを許可する
'--
If Set_Nana = 1 Then
If gDat(1, 1) > 0 And gDat(1, 1) = gDat(2, 2) Then
If gDat(1, 1) = gDat(0, 0) Then cTbl(1, 1) = 1: cTbl(2, 2) = 1: cTbl(0, 0) = 1
If gDat(1, 1) = gDat(3, 3) Then cTbl(1, 1) = 1: cTbl(2, 2) = 1: cTbl(3, 3) = 1
End If
If gDat(2, 1) > 0 And gDat(2, 1) = gDat(1, 2) Then
If gDat(2, 1) = gDat(0, 3) Then cTbl(2, 1) = 1: cTbl(1, 2) = 1: cTbl(0, 3) = 1
If gDat(2, 1) = gDat(3, 0) Then cTbl(2, 1) = 1: cTbl(1, 2) = 1: cTbl(3, 0) = 1
End If
If gDat(1, 0) > 0 And _
gDat(1, 0) = gDat(2, 1) And gDat(1, 0) = gDat(3, 2) Then
cTbl(1, 0) = 1: cTbl(2, 1) = 1: cTbl(3, 2) = 1
End If
If gDat(0, 1) > 0 And _
gDat(0, 1) = gDat(1, 2) And gDat(0, 1) = gDat(2, 3) Then
cTbl(0, 1) = 1: cTbl(1, 2) = 1: cTbl(2, 3) = 1
End If
If gDat(2, 0) > 0 And _
gDat(2, 0) = gDat(1, 1) And gDat(2, 0) = gDat(0, 2) Then
cTbl(2, 0) = 1: cTbl(1, 1) = 1: cTbl(0, 2) = 1
End If
If gDat(3, 1) > 0 And _
gDat(3, 1) = gDat(2, 2) And gDat(3, 1) = gDat(1, 3) Then
cTbl(3, 1) = 1: cTbl(2, 2) = 1: cTbl(1, 3) = 1
End If
End If
'--
'-- [ADD] 四角置き
'-- 同じパネルが四角形のように4つ並んでいる場合 >> 消去テーブルに1を立てる
'-- ワークシート Config で設定する [1]であれば四角置きを許可する
'--
If Set_4kak = 1 Then
For X = 0 To 2
For Y = 0 To 2
If gDat(X, Y) > 0 Then
If gDat(X, Y) = gDat(X + 1, Y) And _
gDat(X, Y) = gDat(X, Y + 1) And _
gDat(X, Y) = gDat(X + 1, Y + 1) Then
cTbl(X, Y) = 1
cTbl(X + 1, Y) = 1
cTbl(X, Y + 1) = 1
cTbl(X + 1, Y + 1) = 1
End If
End If
Next Y
Next X
End If
'--
'-- 消えるパネルを数えて点数を算出
'-- 消去テーブル内の1を数えると同時に内容と画像を何もない状態にする
'--
For Y = 0 To 3
For X = 0 To 3
If cTbl(X, Y) > 0 Then
cDel = cDel + cTbl(X, Y)
gDat(X, Y) = 0
gImg(X, Y).Picture = bImg(0).Picture
End If
Next X
Next Y
'--
'-- 消去されるパネル数に応じて点数を加算する
'--
DelCnt = DelCnt + cDel ' ゲーム全体で消去されたパネルの数をカウント
If cDel = 3 Then dScore = dScore + 30 ' 消去されるパネル数が3の場合は 1パネルあたり10点
If cDel = 4 Then dScore = dScore + 60 ' 消去されるパネル数が4の場合は 1パネルあたり15点
If cDel = 5 Then dScore = dScore + 100 ' 消去されるパネル数が4の場合は 1パネルあたり20点
If cDel = 6 Then dScore = dScore + 180 ' 消去されるパネル数が4の場合は 1パネルあたり30点
If cDel > 6 Then dScore = dScore + (cDel * 50) ' 7個以上の場合は1パネルあたり50点
NowScore.Caption = dScore ' スコアの画面表示
NowStep.Caption = StepCnt ' ステップ数の画面表示
If cDel = 3 Then SEPlaySW = 3 ' [ADD] パネル消去時のSE再生SW 3個
If cDel = 4 Then SEPlaySW = 4 ' [ADD] パネル消去時のSE再生SW 4個
If cDel > 4 Then SEPlaySW = 5 ' [ADD] パネル消去時のSE再生SW 5個以上
End Sub
'------------------------------------------------------------
' ゲームオーバーチェック処理
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub GameOverCheckProc()
Dim X As Integer ' グリッドx方向の添え字
Dim Y As Integer ' グリッドy方向の添え字
Dim zCnt As Integer ' グリッド内容がZeroをカウントする
'--
'-- メイングリッドの全件チェック
'--
For Y = 0 To 3 ' メイングリッド全件探索の二重ループ
For X = 0 To 3 ' メイングリッド全件の内容を確認し
If gDat(X, Y) <= 0 Then zCnt = zCnt + 1 ' 内容がZero(パネルが置かれていない)をカウント
Next X '
Next Y '
'--
'-- ゲームオーバーだった場合
'--
If zCnt <= 0 Then ' 内容がZeroのグリッドがない場合(全部がパネルで埋まっている)
GameOverLbl.ZOrder fmZOrderFront ' ゲームオーバーラベルを前面にする
GameOverLbl.Visible = True ' ゲームオーバーラベルを表示
StartButton.Enabled = True ' スタートボタンを使用可能にする
StartButton.Caption = "Restart" ' スタートボタンのキャプションを"Restart"に変更
NowSeed.Enabled = True ' 乱数シードを変更可能にする
GameSW = False ' ゲーム中ではない
Call SoundEffectPlay(9) ' [ADD] ゲームオーバー時の効果音
End If
End Sub
'------------------------------------------------------------
' 乱数範囲取得
'
' 引数 :dMax 乱数範囲の最大値
' :dMin 乱数範囲の最小値
' 戻り値 :範囲内の値
'------------------------------------------------------------
Function fRandom(dMax As Integer, dMin As Integer) As Integer
fRandom = Int((dMax - dMin + 1) * Rnd + dMin)
End Function
'------------------------------------------------------------
' [ADD] WMP1 再生状態の変化時
'
' 引数 :NewState
' 戻値 :なし
'------------------------------------------------------------
Private Sub WMP1_PlayStateChange(ByVal NewState As Long)
If SudStpSW = 0 Then Exit Sub ' SudStpSWが[0]停止する の場合 >> このサブルーチンを抜ける
If NewState = 1 Or NewState = 8 Then WMP1.Controls.Play ' 再生状態の変化による戻値が 1(停止) or 8(音楽終了) の場合 >> 再び再生する
End Sub
'------------------------------------------------------------
' [ADD] サウンドエフェクト発生処理
'
' 引数 :SENo [1]爆弾 [2]パネル配置
' [3]3つ消し [4]4つ消し [5]5以上消し
' [6]Hold欄 [8]Start [9]ゲームオーバー
' 戻値 :なし
'------------------------------------------------------------
Private Sub SoundEffectPlay(SENo As Integer)
If SENo = 0 Then Exit Sub ' 効果音SWが0の場合は処理せず抜ける
Dim SEPath As String ' 効果音のパス
SEPath = ThisWorkbook.Path & "\sounds\SE" ' 効果音のパスの文字列編集
SEPath = SEPath & SENo & ".mp3" ' 効果音のパスの文字列編集(SE番号を付加)
WMP2.Controls.stop ' WindowsMediaPlayer2 停止
WMP2.Url = SEPath ' WindowsMediaPlayer2 SEのファイルパスを入れる
WMP2.Controls.Play ' WindowsMediaPlayer2 再生
End Subアプデ作業としてはこれで終了です。おつかれさまでした。
コードの中身については次節をご覧ください。
とりあえず難しいことを考えたくない方は読み飛ばして構いません。
必要になった時(改めて勉強しようと思った時)に読み直してくださいね。
コードを軽く説明!
ご覧の通りクッソ長いコードなので中身を詳しく説明すると、多分みなさま眠くなっちゃうと思うんですよ。授業でも長々と説明するよりは早く実習した方が楽しいのと同じです。
というわけで軽く説明するに留めようと思った次第。
面倒臭い、難しいと思ったら読み飛ばしても構いません…
前回の同テーマ記事で貼り付けたコードと変わったところからお話しますと、コード内で[ADD]とコメントが付けられているプロシージャや行が追加されたものです。
また、[DEL]とコメントがついている行は前回までは使用されていたもののコメントアウトして、それに代わる行が[ADD]されています。
前回のコードと比較して解析してみると良い勉強になると思います。
【各プロシージャの説明】
少し経験を積んだ方であればクソ長コードですが、解りやすいように関数化されていて、後々メンテしやすくなっていることに気づくと思います。
まだ慣れていない方だとアッチコッチに処理が飛んでいるので難しく感じると思います。なので、プロシージャで何しているかをお話します。
これがわかれば、大まかに何をしているかが理解できると思います。
1行毎の説明についてはコード内コメントをご覧ください。
・UserForm_Initialize()
これはユーザーフォーム初期化時に動くプロシージャです。
ゲーム内で使用する画像を予めロードし、プレイヤーには見えない画面外に置いて、それを複製していたり、メイングリッドやNext欄などをコードで生成しています。
つまり、ゲームの初期設定を行っているプロシージャってことですね。
更に、大幅アプデによってワークシートConfigからゲーム設定を読み込む機能が追加されています。
・UserForm_QueryClose()
アプデで追加されたプロシージャです。
フォームが閉じた時に再生されている音楽を停止させています。
・GridClickChk_MouseDown()
メイングリッドの上に配置されているイメージオブジェクトの上でマウスボタンを押下した際に動きます。ここでは単純にパネルを置ける場所かを判断してNext欄の一番上のパネルを指定位置に配置しています。
爆弾であればどのグリッドにでも置けますが、通常のパネルであれば、既にパネル配置されているグリッドには置けません。無事にパネルを置けた場合はNext欄を更新しています。
・GridClickChk_MouseUp()
先程のプロシージャと対になるもので、マウスボタンから指を離した際(マウスボタンが元に戻った際)に動きます。
ここで初めてグリッド上のパネルが消えるかチェックするプロシージャと、ゲームオーバーをチェックするプロシージャを読んでいます。
・HoldClickChk_MouseDown()
Hold欄をクリックした際に動きます。
ここでは単純にNext欄の一番上のパネルをHold欄に保持しています。
既にHold欄に何らかのパネルを保持している場合は、Next欄の一番上のパネルと入れ替えています。
・StartButton_Click()
スタートボタンをクリックした際に動きます。
既にゲームをしていた場合はリスタートボタンとしても利用します。
スタートボタンですのでゲームの各数値、つまり点数やステップ数などを初期化しています。また、フォーム内のSeed値を見て、グリッド内とNext欄に配置されるパネルを用意しています。
ゲームを作る際に、結構面倒くさいのが一連のゲームサイクルです。
(1)スタートボタンを押してゲームをする。
(2)ゲームオーバーになる。
(3)ゲームを再スタートする。
このような一連の流れを完成させるのが大事だったりします。
・NextWindowUpdate()
Next欄の更新処理です。グリッドにパネルを置いた後に動作し、Next欄の各パネルを1つ押し上げます。Next欄の一番下に表示されるパネルは乱数によって変化します。
このプロシージャそのものは短いのですが、実はゲームのコアの部分です。
ゲームを進めると徐々に難易度が上がっていく仕組みが実装されているのです。そのためにアプデ処理でもパッチがあてられています。
この処理の工夫については次節の【ゲーム進行による難易度上昇】に詳しくあるので、お楽しみに!
・PointCheckProc()
このプロシージャではグリッドに置かれたパネルを見て、消去条件を満たしていればパネルを消去し、同時に点数を計算するという処理をしています。
斜め消し、四角消しとコンフィグ設定によってそれらが許可されるか切り替わるのでアプデで追加された部分が多いのですが、そこまでアプデは大変じゃなかったりします。
処理の流れとしては…
(1)爆弾が置かれていた場合の処理
(2)パネルが横に3~4つ並んでいるかチェック
(3)パネルが縦に3~4つ並んでいるかチェック
(4)パネルが斜めに3~4つ並んでいるかチェック
(5)パネルが四角形のように4つ並んでいるかチェック
(6)パネル消し処理
(7)消えたパネル数に応じて点数計算
という順番で行っています。
縦と横のように複数の条件を満たしている場合の処理を考えると、複雑なように感じますが、ちょっとした工夫で実現しています。
その方法ですが、グリッドと同じ形状の二次元配列を用意しておきます。
(1)~(5)で消えるパネルが判明したら、二次元配列の対応した場所に消去フラグを立てます。消去フラグが立っている件数を数えれば点数計算も楽になります。
実際に消えるのは(6)の時、点数を計算するのは(7)の時ですね。
このような考え方をしておくと、そこまで複雑じゃないハズです…
・GameOverCheckProc()
ここではグリッドがパネルで埋まってしまったらゲームオーバーの処理を行っています。
判定方法はグリッドにパネルが無い場合、カウントアップします。
全グリッドを探索し、このカウントがZeroであればすべて埋まっています。
・fRandom()
このファンクションプロシージャは、弊サークルのExcel(VBA)でゲームを作る記事に何度も登場しています。
乱数の範囲を引数に入れてファンクションを呼び出し、戻り値を乱数として取得しています。
ゲームの進行に伴い徐々に難易度が上がっていく仕組みなので、乱数範囲が指定できるファンクションはすごーく便利だったりします。
・WMP1_PlayStateChange()
BGMを鳴らしているWindowsMediaPlayerの状態が変化した時に動くプロシージャなんですけど、そのためユーザーからは認識されない処理ですね。BGMが最後まで再生された時に、再生しなおす処理をしています。
・SoundEffectPlay()
このプロシージャは引数で指定された効果音を再生するだけです。
【サウンドファイルの用意!】の節でファイル名を変更し、どのファイルが、どのタイミングに対応している効果音かを明確にした理由がこれです。
ゲーム進行による難易度上昇
コードを解析すると登場するパネルの種類が増えて行き、そして爆弾の出現率が徐々に低下しているのがわかります。
ゲームの難易度が徐々に上がっていく仕組みですね。
コンフィグ設定を変更せず、初期設定で爆弾の出現率を考えてみますよ。
まず爆弾発生スイッチを算出します。爆弾発生スイッチがZeroの場合、パネル生成時に爆弾が発生する可能性が生じます。
爆弾発生スイッチ = 乱数(0 ~ (3 + (Step数 \ 50))次にNext欄の一番下にパネルを生成します。
以下は発生するパネル番号を算出する計算式です。
//// 爆弾発生スイッチが0の場合 ////
生成するパネル番号 = 乱数(0 ~ 登場するパネル番号の最大値)
//// 爆弾発生スイッチが0以外の場合 ////
生成するパネル番号 = 乱数(1 ~ 登場するパネル番号の最大値)登場するパネル番号、ゲームスタート時は6です。しかし75ステップになると7となり、150ステップになると8になります。
出現するパネルの種類が増えるっていうことになります。
その分だけ、やっぱり爆弾の出現率が低下していきます。
まとめると、こんな感じになるのかな?

爆弾が出過ぎると簡単になってしまうので、こういった仕様が仕込まれていたっていうお話でした!
おわりに
一度にここまでの仕様を実装しようとすると、どうしても記事が長くなってしまうので2回に分けて実装しましたが、いかがでしたでしょうか?
前回の仕様だと、かなりシンプルなゲームでしたが今回のアプデで、結構なゲームっぽくなったと思いません?
実際のところ、前回の記事を書く前からサウンドの追加、斜め消し、四角消し、コンフィグ追加を考えていたので、まずは小さく作って、徐々に機能を追加していく手法を説明できるな~と思っていたんですよね。
長い記事を読んでくださりありがとうございます。
そして実作業された方はお疲れ様でした!
また別の記事でお会いしましょう!
ここからはオススメ記事の紹介です。
システム系の勉強したいなーって方にはコチラがオススメです。
関連記事を以下にまとめてます!(↓)
「読むとゲームができるマガジン」もオススメです。
Unityのお話もありますが、Excelである程度のゲームは作れますよ(↓)