
Excel(VBA)でパズルゲームを作る!
こんにちは「つけらっとゲームス」プログラム担当のとちです。
今回はExcel(VBA)でちょっとしたパズルゲームを作ります!
Excel単体で動くゲームを発信するのは実は久しぶりなんですね。
お正月あたりに干支タイピングを作る記事を公開して以来です。
んで、今回作るゲームはこんな感じ!
下のスクショのような画面が表示されます。

Seed欄は乱数シードの値になるので再現性があったりします。
スタートボタンをクリックすると…こんな画面になります。

引き続き、下のスクショをご覧ください。
4×4のグリッドの左上をクリックすると、Next欄の一番上の青いパネルが表示されましたね。Next欄がひとつ上にせり上がりました。
更に、先程クリックしたマス目の下をクリックすると、またNext欄の一番上の青いパネルが表示されました。

同じ絵柄のパネルが3~4個、縦もしくは横に並ぶと消える。
どこかで聞いたことのあるような、そんなパズルが動くようになります。
さらに、このパネルの画像ファイルは皆さんの好みの画像を使えるので、貴方だけのパズルゲームができてしまうという…作業量はそんなに多くありませんし、皆さんも一緒に作ってみませんか!?
いつものようにユーザーフォームを挿入、各オブジェクトを作っていき最後にソースを丸ごとコピーする流れで作成していきます。
なお、この記事のスクショについて、わたしのPCに入っているMicrosoft office Home and Business 2016でスクショを撮りました。
なので表示が微妙に異なる可能性があります。しかしデスクトップ版のExcelであれば、開発に使用するVBA(Microsoft Visual Basic for Applications)は同じです。作業内容も変わりません。Microsoft365のExcelでも動作します。
それと、開発前に環境を整える必要があります。
以前の同テーマ記事「Excel(VBA)で簡単なゲームを作る」の「Excelの準備」を参照してVBAを使えるようにしておきましょう。
また「Excel(VBA)で〇〇を作る」記事は以下のマガジンにまとめています。
他のゲームの解説もあるので、マガジンの中からお好みのゲームを探してくださいね!
開発環境を準備する
「Excelの準備」を参照してVBAを使えるようにできましたか?
それでは任意のフォルダに拡張子「xlsm」のファイルを作りましょう。

上のスクショでは「ExcelPuzzle.xlsm」という名前で作っていますが、名前は他のモノでも構いません。ただし拡張子は「xlsm」です。
その他に「images」というフォルダを作っておきましょう。
こちらにはゲーム内で使用する画像ファイルを入れます。
用意する画像は10種類、下のスクショをご覧のください。
画像ファイル名には規則性があります。

「pImage_0.jpg」からはじまって「pImage_9.jpg」と数字の部分が0~9まであります。わたしが用意したのはいつもお世話になっているKENNEYさんのものを使いやすいように自分で編集しました。
サイズは32x32ですが、皆さんの好みのサイズで構いません。
見た目的に正方形の画像を推奨しますが、多少なら長方形でも大丈夫かな…
というのも、ゲーム内で画像を引き延ばして(画像サイズによっては縮小して)幾つかのサイズで表示しているので、多少のサイズ違いでも大丈夫だったりするのです。

この10個の画像ファイルですが、大きく意味が異なる画像が2つあります。
「pImage_0.jpg」は何もないパネルを意味するので真っ黒にしました。
「pImage_9.jpg」は他のパネルを壊す意味を持ちます。爆弾にしました!
それ以外は単純に3つ並べたら消える絵合わせパネルです。
【 ※注意 】
Excel(VBA)でユーザーフォームを使う際は、jpeg形式の画像ファイルを使用します。お使いになりたい画像ファイルが他形式の場合、Photoshop、Gimpあたりの画像編集ソフトを使用できる方はそちらで編集していただいて構いません。
Windows付属のペイントでも十分可能ですが、やったこと無い方や、自信が無い方は以前の記事にある「必要な素材を準備する」をご覧くださいね。
【 コラム:png形式を使わない理由 】
Excel(VBA)でのユーザーフォーム、標準では透過pngは対応していません。
後述するプロパティ欄から指定しようにも、そもそも選択肢が表示されてないんです。
画面作成の下準備
開発を始める前にちょっとだけ注意。開発中はマメに保存することをオススメします!意外と授業中はセーブしていなくて、やり直しという学生を見かけるので…
では、先程作ったExcelファイル(マクロ有効ワークシート)を開きます。
そして、メニューバーの「開発」→ 「Visual Basic」を選びます。

VBAのエディタ画面が表示されます。
画面を作る際に最初にやるべきことは下のスクショの様に「挿入」→「ユーザーフォーム」でまっさらなユーザーフォームを準備することです。

すると、下のスクショのようになるハズです。

もし、UserForm1が表示されない場合はスクショ内の赤文字のとおり操作。
もし、ツールボックスが表示されない場合は青文字のとおり操作します。
挿入されたUserForm1はオレンジ文字のとおり、大きくすると作業が少し楽になると思います。
これが終わったら画面左下の緑枠、プロパティ欄を修正していきますよ!
おそらく違いがあるとすれば下のオレンジ枠の部分。
大体あっていればOKなんですが、気になる方は揃えておくと良いでしょう。

画面作成
ではユーザーフォームに各種コントロールを配置していきます。
実際の位置は後で修正できますし、プロパティ欄でも動かすことができますので、大体の位置に配置していけばOKです!
ツールボックスのコントロールをクリックして選択します。
ユーザーフォームの上でドラッグすると対応したオブジェクトができます。
ここでは「イメージ」「コマンドボタン」「テキストボックス」を作りましょう。オブジェクトを作ったらプロパティ欄のオブジェクト名を、下の画像を参考に名前を付けます。
プロパティ欄は後で詳細をお見せします。

次にラベルを配置します。
下の画像のオブジェクトは全て「ラベル」コントロールです。
こちらも、画像を参考にオブジェクトを作りオブジェクト名を付けます。

各オブジェクトのプロパティ
基本的にプロパティ欄は同じような設定にしておきます。
文字が小さくなってしまったので画像をクリックし拡大してご覧ください。
まずは「イメージ」2つのプロパティ欄です。
「BorderColor」を赤にしているのは開発時にクリック範囲をわかりやすくするためで、実行時はプログラム側で非表示にしています。

次はコマンドボタン「StartButton」とテキストボックス「NowSeed」です。
これらには、Fontプロパティがありますね。
フォントに関しては皆様のお好みのフォントで構いません!

ここからは全てラベルです。もちろんフォントはお好みで構いません。



コードをコピペする!
ここまで来たらあと少しです。最後にコードをコピペします!
まずは下の画像のオレンジ枠をダブルクリックしてフォームを表示します。
フォームが表示されたら、Startボタンをダブルクリックしましょう!
するとコード入力画面になります。

コード入力画面には自動で追加されたコードがあります。
これを一旦、全て削除してください。

削除したまっさらな場所に以下のコードをコピペします。
コードについて、また別の記事で改めて解説したいと思いますので、今はとりあえず何も考えずにコピペでOKです。
Option Explicit
Dim GameSW As Boolean ' True:ゲーム中
Dim pPutSW As Boolean ' True:パネルをグリッドに置いた
Dim bImg(9) As MSForms.Image ' 複写元のベースイメージ(画像)
Dim gImg(3, 3) As MSForms.Image ' メイングリッドイメージ(画像)
Dim nImg(3) As MSForms.Image ' Next欄のイメージ(画像)
Dim hImg As MSForms.Image ' Hold欄のイメージ(画像)
Dim gDat() As Integer ' メイングリッドの内容
Dim nDat(3) As Integer ' Next欄の内容
Dim hDat As Integer ' Hold欄の内容
Dim StepCnt As Integer ' Stepカウント パネルをグリッド配置した時に+1
Dim DelCnt As Long ' 消去パネルカウント
Dim dScore As Long ' スコア
'------------------------------------------------------------
' ユーザーフォーム初期化時
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub UserForm_Initialize()
Dim folderPath As String ' 画像フォルダのパス
Dim ImagePath As String ' 画像ファイルのパス
Dim cNm As String ' オブジェクト名生成用 文字列変数
Dim X As Integer ' グリッドx方向の添え字
Dim Y As Integer ' グリッドy方向の添え字
'--
'-- 複製元 ベースとなる画像データ
'--
folderPath = ThisWorkbook.Path & "\Images\pImage_"
For X = 0 To 9
ImagePath = folderPath & X & ".jpg"
Set bImg(X) = Me.Controls.Add("Forms.image.1", "bImg_" & X)
bImg(X).Picture = LoadPicture(ImagePath)
bImg(X).Left = -500
Next X
'--
'-- メイングリッド 作成
'--
For Y = 0 To 3
For X = 0 To 3
cNm = "Grid_" & X & "_" & Y
Set gImg(X, Y) = Me.Controls.Add("Forms.image.1", cNm)
gImg(X, Y).Picture = bImg(0).Picture
gImg(X, Y).Left = X * 54 + 12 ' グリッド1マスの横座標
gImg(X, Y).Top = Y * 54 + 12 ' グリッド1マスの縦座標
gImg(X, Y).Width = 54 ' グリッド1マスの横サイズ
gImg(X, Y).Height = 54 ' グリッド1マスの縦サイズ
gImg(X, Y).PictureSizeMode = 1
Next X
Next Y
'--
'-- Next欄 作成
'--
For X = 0 To 3
Set nImg(X) = Me.Controls.Add("Forms.image.1", "nImg_" & X)
nImg(X).Picture = bImg(0).Picture
nImg(X).Left = 252 ' Next欄1個の横座標
nImg(X).Top = X * 36 + 48 ' Next欄1個の縦座標
nImg(X).Width = 36 ' Next欄1個の横サイズ
nImg(X).Height = 36 ' Next欄1個の縦サイズ
nImg(X).PictureSizeMode = 3
Next X
'--
'-- Hold欄 作成
'--
Set hImg = Me.Controls.Add("Forms.image.1", "hImg_f")
hImg.Picture = bImg(0).Picture
hImg.Left = 246 ' Hold欄の横座標
hImg.Top = 234 ' Hold欄の縦座標
hImg.Width = 48 ' Hold欄の横サイズ
hImg.Height = 48 ' Hold欄の縦サイズ
hImg.PictureSizeMode = 3
'--
'-- グリッド全体のマウス入力受取を行うイメージコントロール
'--
GridClickChk.Left = 12 ' 横座標
GridClickChk.Top = 12 ' 縦座標
GridClickChk.Width = 300 ' 横サイズ
GridClickChk.Height = 216 ' 縦サイズ
GridClickChk.BorderStyle = 0 ' 境界線の非表示
GridClickChk.ZOrder fmZOrderFront ' 最前面表示
'--
'-- Hold欄のマウス入力受取を行うイメージコントロール
'--
HoldClickChk.Left = 246 ' 横座標
HoldClickChk.Top = 234 ' 縦座標
HoldClickChk.Width = 48 ' 横サイズ
HoldClickChk.Height = 48 ' 縦サイズ
HoldClickChk.BorderStyle = 0 ' 境界線の非表示
HoldClickChk.ZOrder fmZOrderFront ' 最前面表示
End Sub
'------------------------------------------------------------
' ゲーム中にメイングリッドをクリック(Down)した時
'
' 引数 :imageコントロール MouseDown
' 戻り値 :なし
'------------------------------------------------------------
Private Sub GridClickChk_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
If GameSW = False Then Exit Sub ' ゲーム中以外の場合は処理を抜ける
Dim gX As Integer ' グリッド座標x
Dim gY As Integer ' グリッド座標y
'--
'-- クリック座標を54で除算し対象グリッドを算出
'-- メイングリッド外の場合は処理を抜ける
'--
gX = X \ 54 ' メイングリッドの一辺の大きさが54x54なので、
gY = Y \ 54 ' 54で除算するとグリッド座標が算出できる
If gX <= -1 Or gX >= 4 Then Exit Sub ' もしグリッド座標外の値が算出された場合は
If gY <= -1 Or gY >= 4 Then Exit Sub ' この処理を抜ける
pPutSW = False ' パネル配置スイッチの初期化(False)
'--
'-- Next欄の一番上がパネル1~8の場合
'-- パネルが既に設置されていると置けない
'--
If nDat(0) >= 1 And nDat(0) <= 8 Then ' Next欄の一番上が通常パネルだった場合
If gDat(gX, gY) = 0 Then ' パネルが既に設置されている場合は置けない
gImg(gX, gY).Picture = bImg(nDat(0)).Picture ' グリッドにパネル表示
gDat(gX, gY) = nDat(0) ' グリッド内容にパネル番号(1~8)を格納
pPutSW = True ' パネル配置スイッチをTrueにする
End If
End If
'--
'-- Next欄の一番上がパネル9(爆弾)の場合
'-- パネルが既に設置してあっても置ける
'--
If nDat(0) = 9 Then ' Next欄の一番上が爆弾パネルだった場合
gImg(gX, gY).Picture = bImg(nDat(0)).Picture ' グリッドに爆弾表示
gDat(gX, gY) = nDat(0) ' グリッド内容に9:爆弾を格納
pPutSW = True ' パネル配置スイッチをTrueにする
End If
'--
'-- メイングリッドにパネルを置けた場合
'--
If pPutSW = True Then ' ここまででグリッドにパネルを置けた場合
StepCnt = StepCnt + 1 ' Stepカウント+1
Call NextWindowUpdate ' Next欄を更新
End If
End Sub
'------------------------------------------------------------
' ゲーム中にメイングリッドをクリック(Up)した後
'
' 引数 :imageコントロール MouseDown
' 戻り値 :なし
'------------------------------------------------------------
Private Sub GridClickChk_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
If GameSW = False Then Exit Sub ' ゲームプレイ中以外の場合は処理を抜ける
If pPutSW = False Then Exit Sub ' パネル配置されていない場合は処理を抜ける
Call PointCheckProc ' スコア計算
Call GameOverCheckProc ' ゲームオーバーチェック処理
End Sub
'------------------------------------------------------------
' Hold欄をクリック(Down)した時
'
' 引数 :imageコントロール MouseDown
' 戻り値 :なし
'------------------------------------------------------------
Private Sub HoldClickChk_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
If GameSW = False Then Exit Sub ' ゲーム中以外の場合は処理を抜ける
'--
'-- Hold欄に何も入っていない場合
'-- Next欄の一番上をHoldする
'--
If hDat <= 0 Then ' Hold欄の内容が0以下(入っていない場合)
hDat = nDat(0) ' Next欄の一番上の内容を保持
hImg.Picture = nImg(0).Picture ' Next欄の一番上の画像を保持
Call NextWindowUpdate ' Next欄を更新する
Exit Sub ' 処理を抜ける
End If
'--
'-- Hold欄に何か入っていた場合
'-- Next欄の一番上とHold欄を入れ替える
'--
Dim sv As Integer ' 入替時に使用する変数
sv = hDat ' Hold欄を入替用変数に格納
hDat = nDat(0) ' Hold欄にNext欄の一番上の内容を格納
hImg.Picture = nImg(0).Picture ' Hold欄の画像を更新
nDat(0) = sv ' 入替用変数をNext欄の一番上に格納
nImg(0).Picture = bImg(sv).Picture ' Next欄の一番上の画像を更新
End Sub
'------------------------------------------------------------
' スタートボタン クリック時
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub StartButton_Click()
Dim i As Integer ' 配列全件ループ用添え字
Dim j As Integer ' グリッドに対する初期配置パネル数をランダム取得
Dim X As Integer ' グリッドx方向の添え字
Dim Y As Integer ' グリッドy方向の添え字
Rnd -1 ' 乱数系列の初期化
Randomize CLng(NowSeed.Value) ' 乱数種の取得
ReDim gDat(3, 3) As Integer ' グリッド内容配列を再定義
'--
'-- 押したボタンのキャプションが"Restart"の場合
'--
If StartButton.Caption = "Restart" Then
For Y = 0 To 3 ' メイングリッドの全件ループ
For X = 0 To 3 ' メイングリッドの画像を全てない状態にする
gImg(X, Y).Picture = bImg(0).Picture
Next X
Next Y
hImg.Picture = bImg(0).Picture ' Hold欄をない状態にする
hDat = 0 ' Hold欄の内容を初期化
GridClickChk.ZOrder fmZOrderFront ' グリッドクリック用のImageコントロールを前面にする
HoldClickChk.ZOrder fmZOrderFront ' Hold欄クリック用 のImageコントロールを前面にする
End If
'--
'-- Next欄の全件ループ
'--
For i = 0 To 3
nDat(i) = fRandom(6, 1) ' Next欄の内容をランダム取得
nImg(i).Picture = bImg(nDat(i)).Picture ' Next欄の画像を画面反映
Next i
'--
'-- グリッド欄の初期配置(パネルを幾つか配置)
'--
j = fRandom(4, 1) ' グリッドの配置する初期パネル数(1~4個)
For i = 0 To j ' 初期配置パネル数に達するまでループ
X = fRandom(3, 0) ' 初期配置パネルx座標 取得
Y = fRandom(3, 0) ' 初期配置パネルy座標 取得
gDat(X, Y) = fRandom(6, 1) ' ランダム取得した座標に内容を格納
gImg(X, Y).Picture = bImg(gDat(X, Y)).Picture ' ランダム取得した座標に内容に対応した画像を反映
Next i
'--
'-- その他・ゲーム開始の準備処理
'--
GameOverLbl.Visible = False ' ゲームオーバーのラベルを非表示化
StartButton.Enabled = False ' このボタンを押せないようにする
NowSeed.Enabled = False ' 乱数シード入力欄を使用不可にする
GameSW = True ' ゲーム開始
dScore = 0 ' スコアの初期化
StepCnt = 0 ' ステップ数の初期化
NowScore.Caption = dScore ' スコアの画面表示
NowStep.Caption = StepCnt ' ステップ数の画面表示
End Sub
'------------------------------------------------------------
' Next欄の変更
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub NextWindowUpdate()
Dim i As Integer ' Next欄を探索する添え字
Dim BombSW As Integer ' 爆弾の発生スイッチ 0:爆弾発生
Dim BombMx As Integer ' 爆弾が発生する確率を変動させるための乱数上限値
Dim PanelMx As Integer ' ランダム発生するNext欄の発生するパネル種類数
For i = 0 To 2 ' Next欄の全件探索
nDat(i) = nDat(i + 1) ' Next欄の下の内容をひとつ上に転記する
nImg(i).Picture = bImg(nDat(i)).Picture ' Next欄の下の画像をひとつ上に転記する
Next i
BombMx = 3 + (StepCnt \ 50) ' ボムの発生確率時に使う乱数上限値を算出 Step:50毎に徐々に爆弾は出なくなる
BombSW = fRandom(BombMx, 0) ' 爆弾発生スイッチを取得 0:爆弾発生
PanelMx = 6 ' Next欄に発生する通常パネル種 6種類
If StepCnt >= 75 Then PanelMx = 7 ' ステップ数が 75以上の場合 7種類
If StepCnt >= 150 Then PanelMx = 8 ' ステップ数が150以上の場合 8種類
If BombSW = 0 Then ' 爆弾発生の場合
i = fRandom(PanelMx, 0) ' 0を含めたパネルのランダム発生値を取得
Else ' 爆弾発生しない場合
i = fRandom(PanelMx, 1) ' 0を含めないパネルのランダム発生値を取得
End If
If i = 0 Then i = 9 ' パネルのランダム発生値が0の場合 パネル番号を9:爆弾とする
nDat(3) = i ' パネルのランダム発生値をNext欄の一番下に入れる
nImg(3).Picture = bImg(i).Picture ' 対応したパネル画像をNext欄の一番下に入れる
End Sub
'------------------------------------------------------------
' メイングリッドの状況を見て点数を算出
' 同時にグリッドの表示変更
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub PointCheckProc()
Dim X As Integer ' グリッドx方向の添え字
Dim Y As Integer ' グリッドy方向の添え字
Dim cDel As Integer ' 消去カウント >> この処理で消去されるパネル数
Dim cTbl(3, 3) As Integer ' 消去テーブル >> この処理で消去されるパネル位置に1を立てる
'--
'-- 爆弾チェック
'--
For Y = 0 To 3 ' グリッド内容を全件チェックする二重ループ
For X = 0 To 3 ' グリッド内容が9:爆弾の場合
If gDat(X, Y) = 9 Then ' グリッド内容を0:何も無い状態にする
gImg(X, Y).Picture = bImg(0).Picture ' グリッド画像も何も無い状態に更新する
gDat(X, Y) = 0 ' ※ 爆弾の場合はパネルを消したことにしない
End If
Next X
Next Y
'--
'-- 横チェック
'-- 同じパネルが横に3または4並んでいる場合 >> 消去テーブルに1を立てる
'--
For Y = 0 To 3
If gDat(0, Y) > 0 And _
gDat(0, Y) = gDat(1, Y) And _
gDat(0, Y) = gDat(2, Y) And _
gDat(0, Y) = gDat(3, Y) Then
cTbl(0, Y) = 1: cTbl(1, Y) = 1
cTbl(2, Y) = 1: cTbl(3, Y) = 1
ElseIf gDat(0, Y) > 0 And _
gDat(0, Y) = gDat(1, Y) And _
gDat(0, Y) = gDat(2, Y) Then
cTbl(0, Y) = 1: cTbl(1, Y) = 1: cTbl(2, Y) = 1
ElseIf gDat(1, Y) > 0 And _
gDat(1, Y) = gDat(2, Y) And _
gDat(1, Y) = gDat(3, Y) Then
cTbl(1, Y) = 1: cTbl(2, Y) = 1: cTbl(3, Y) = 1
End If
Next Y
'--
'-- 縦チェック
'-- 同じパネルが縦に3または4並んでいる場合 >> 消去テーブルに1を立てる
'--
For X = 0 To 3
If gDat(X, 0) > 0 And _
gDat(X, 0) = gDat(X, 1) And _
gDat(X, 0) = gDat(X, 2) And _
gDat(X, 0) = gDat(X, 3) Then
cTbl(X, 0) = 1: cTbl(X, 1) = 1
cTbl(X, 2) = 1: cTbl(X, 3) = 1
ElseIf gDat(X, 0) > 0 And _
gDat(X, 0) = gDat(X, 1) And _
gDat(X, 0) = gDat(X, 2) Then
cTbl(X, 0) = 1: cTbl(X, 1) = 1: cTbl(X, 2) = 1
ElseIf gDat(X, 1) > 0 And _
gDat(X, 1) = gDat(X, 2) And _
gDat(X, 1) = gDat(X, 3) Then
cTbl(X, 1) = 1: cTbl(X, 2) = 1: cTbl(X, 3) = 1
End If
Next X
'--
'-- 消えるパネルを数えて点数を算出
'-- 消去テーブル内の1を数えると同時に内容と画像を何もない状態にする
'--
For Y = 0 To 3
For X = 0 To 3
If cTbl(X, Y) > 0 Then
cDel = cDel + cTbl(X, Y)
gDat(X, Y) = 0
gImg(X, Y).Picture = bImg(0).Picture
End If
Next X
Next Y
'--
'-- 消去されるパネル数に応じて点数を加算する
'--
DelCnt = DelCnt + cDel ' ゲーム全体で消去されたパネルの数をカウント
If cDel = 3 Then dScore = dScore + 30 ' 消去されるパネル数が3の場合は 1パネルあたり10点
If cDel = 4 Then dScore = dScore + 60 ' 消去されるパネル数が4の場合は 1パネルあたり15点
If cDel = 5 Then dScore = dScore + 100 ' 消去されるパネル数が4の場合は 1パネルあたり20点
If cDel = 6 Then dScore = dScore + 180 ' 消去されるパネル数が4の場合は 1パネルあたり30点
If cDel > 6 Then dScore = dScore + (cDel * 50) ' 7個以上の場合は1パネルあたり50点
NowScore.Caption = dScore ' スコアの画面表示
NowStep.Caption = StepCnt ' ステップ数の画面表示
End Sub
'------------------------------------------------------------
' ゲームオーバーチェック処理
'
' 引数 :なし
' 戻り値 :なし
'------------------------------------------------------------
Private Sub GameOverCheckProc()
Dim X As Integer ' グリッドx方向の添え字
Dim Y As Integer ' グリッドy方向の添え字
Dim zCnt As Integer ' グリッド内容がZeroをカウントする
'--
'-- メイングリッドの全件チェック
'--
For Y = 0 To 3 ' メイングリッド全件探索の二重ループ
For X = 0 To 3 ' メイングリッド全件の内容を確認し
If gDat(X, Y) <= 0 Then zCnt = zCnt + 1 ' 内容がZero(パネルが置かれていない)をカウント
Next X '
Next Y '
'--
'-- ゲームオーバーだった場合
'--
If zCnt <= 0 Then ' 内容がZeroのグリッドがない場合(全部がパネルで埋まっている)
GameOverLbl.ZOrder fmZOrderFront ' ゲームオーバーラベルを前面にする
GameOverLbl.Visible = True ' ゲームオーバーラベルを表示
StartButton.Enabled = True ' スタートボタンを使用可能にする
StartButton.Caption = "Restart" ' スタートボタンのキャプションを"Restart"に変更
NowSeed.Enabled = True ' 乱数シードを変更可能にする
GameSW = False ' ゲーム中ではない
End If
End Sub
'------------------------------------------------------------
' 乱数範囲取得
'
' 引数 :dMax 乱数範囲の最大値
' :dMin 乱数範囲の最小値
' 戻り値 :範囲内の値
'------------------------------------------------------------
Function fRandom(dMax As Integer, dMin As Integer) As Integer
fRandom = Int((dMax - dMin + 1) * Rnd + dMin)
End Function
お疲れ様です! これで完成です! しっかり保存しましょう!
コピペが終わったら下の画像のとおり、
①フォームをダブルクリックして、②再生ボタンをクリックするとゲームが動き出します!

プログラムを止める場合は表示されているゲーム画面右上の✕ボタンまたは、②再生ボタンの隣の隣、■の停止ボタンを押します。
うまく動かない場合でも落ち着いて…
以前の記事の「動かないんだけど!?(怒)」を参照してください。
原因のほとんどは「オブジェクト名が間違っている」だと思います。
改めて「あそびかた」
4×4のグリッド、何も置かれていないマスをクリックするとNext欄の一番上のパネルが置かれます。これを利用して3つ、または4つ同じパネルを縦または横に並べると、同じパネルが消えて点数が入ります。
1度に多くのパネルを消すことができれば、その分だけ獲得できる点数が多くなります。

Hold欄をクリックすると、Next欄の一番上のパネルを保持することができます。もう一度Hold欄をクリックするとNext欄のパネルと入れ替わります。
これを上手く使ってゲームを進めましょう!
爆弾のパネルは既に置かれた他のパネルを壊せる便利なパネルです。
大事に使いましょう。ただしステップ回数が増えると爆弾の出る確率が落ちていきます。
さらに、ステップ回数が増えると最初は6種類しか出なかったパネルが、7種類に、そして更に進むと8種類になります。つまり徐々に難しくなっていくんですね。
4×4のグリッドが全てパネルで埋まってしまったらゲームオーバーです!
続きます!
これで簡単ではありますが、ゲームそのものは動いているハズです。
単純ですがゲームとして成り立っていると思います。
ただ、ちょっとしたところが気になります。
やっぱり音ですよね、最低でも効果音くらいは欲しいです。
その想いはプログラムコードを書き換えると実装可能です。しかし、書き換えるためにはプログラムの中身を理解しないといけません。
というわけで次回は応用編として機能追加するか、もしくはコードの解説をするか…とにかく、もうちょっとだけ続きます。
長い記事を読んでくださりありがとうございます。
そして実作業された方はお疲れ様でした!
また次の記事でお会いしましょう!
▼【2026.7.15 公開】続きはコチラの記事です!
ここからはオススメ記事の紹介です。
システム系の勉強したいなーって方にはコチラがオススメです。
関連記事を以下にまとめてます!(↓)
「読むとゲームができるマガジン」もオススメです。
Unityのお話もありますが、Excelである程度のゲームは作れますよ(↓)